Серый форум — VBS Скрипт переименования файла в кол-во дней с последней модификации

Re: VBS Скрипт переименования файла в кол-во дней с последней модификации

null@example.com (alexii) — Sun, 25 Nov 2012 18:00:42 +0000

Milena пишет:

Помогите, пожалуйста, написать скрипт.

Это называется — сделайте за меня. Что было сделано с Вашей стороны для решения задачи?

Re: VBS Скрипт переименования файла в кол-во дней с последней модификации

null@example.com (Milena) — Sun, 25 Nov 2012 16:48:38 +0000

Добрый вечер!

Помогите, пожалуйста, написать скрипт.
Задание: переименование файлов с определенным расширением.

Re: VBS Скрипт переименования файла в кол-во дней с последней модификации

null@example.com (IrinaVZ) — Thu, 13 Jan 2011 10:12:18 +0000

СПАСИБО ОГРОМНОЕ!!!

Re: VBS Скрипт переименования файла в кол-во дней с последней модификации

null@example.com (alexii) — Wed, 12 Jan 2011 01:17:05 +0000

Например, так:

Option Explicit

Dim strPath

Dim objFSO
Dim objFolder
Dim objFile


strPath = Trim(InputBox("Введите путь:"))

If Len(strPath) <> 0 Then
    Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
    
    If objFSO.FolderExists(strPath) Then
        Set objFolder = objFSO.GetFolder(strPath)
        
        For Each objFile In objFolder.Files
            If UCase(objFSO.GetExtensionName(objFile.Name)) = UCase("txt") Then
                objFile.Name = DateDiff("d", objFile.DateLastModified, Now) & "_" & objFile.Name
            End If
        Next
        
        Set objFolder = Nothing
    Else
        WScript.Echo "Folder [" & strPath & "] not found."
    End If
    
    Set objFSO = Nothing
End If

WScript.Quit

Или так:

Option Explicit

Dim strPath

Dim objFSO
Dim objFolder
Dim objFile


strPath = Trim(BrowseForFolder("shell:Desktop"))

If Len(strPath) <> 0 Then
    Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
    
    If objFSO.FolderExists(strPath) Then
        Set objFolder = objFSO.GetFolder(strPath)
        
        For Each objFile In objFolder.Files
            If UCase(objFSO.GetExtensionName(objFile.Name)) = UCase("txt") Then
                objFile.Name = DateDiff("d", objFile.DateLastModified, Now) & "_" & objFile.Name
            End If
        Next
        
        Set objFolder = Nothing
    Else
        WScript.Echo "Folder [" & strPath & "] not found."
    End If
    
    Set objFSO = Nothing
End If

WScript.Quit

Function BrowseForFolder(strRootFolder)
    Const BIF_RETURNONLYFSDIRS    = &H0001
    Const BIF_USENEWUI            = &H0050
    Const BIF_UAHINT              = &H0100
    
    Dim objShell
    Dim objRootFolder
    Dim objSelectedFolder
    
    Dim intOptions
    
    
    Set objShell      = WScript.CreateObject("Shell.Application")
    Set objRootFolder = objShell.NameSpace(strRootFolder)
    
    intOptions        = BIF_RETURNONLYFSDIRS Or BIF_USENEWUI Or BIF_UAHINT
    
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Укажите папку:", intOptions, objRootFolder)
    
    If Not objSelectedFolder Is Nothing Then
        BrowseForFolder = objSelectedFolder.Self.Path
        
        Set objSelectedFolder = Nothing
    End If
    
    Set objRootFolder        = Nothing
    Set objShell             = Nothing
End Function

Re: VBS Скрипт переименования файла в кол-во дней с последней модификации

null@example.com (IrinaVZ) — Mon, 10 Jan 2011 14:00:25 +0000

Option Explicit
Dim fso, folder, file, newname, katalog
inputBOX katalog
Set fso = CreateObject("Scripting.FileSystemObject")
Set folder = fso.GetFolder(".")
for each file in folder.files
if LCase(fso.GetExtensionName(file.name)) = "txt" Then
newname =int(Date-file.DateLastModified) & fso.GetBaseName(file.name) & ".txt"
if file.name <> newname Then file.name = newname

End if
next

Вот скрипт, но перебор файлов идет в том каталоге, в котором находится сам скрипт, а необходимо, чтобы перебор файлов происходил в том каталоге, который мы вводим. Я не могу понять как это сделать.

Re: VBS Скрипт переименования файла в кол-во дней с последней модификации

null@example.com (alexii) — Sun, 09 Jan 2011 19:27:23 +0000

IrinaVZ, можно. Что у Вас не получается?

Re: VBS Скрипт переименования файла в кол-во дней с последней модификации

null@example.com (IrinaVZ) — Wed, 05 Jan 2011 09:26:46 +0000

А можно ли в этом коде сделать так, чтобы при помощи ввода конкретного каталога (команда inputbox как я поняла из прочитанного в интернете) перебор файлов происходил именно в этом каталоге?

Re: VBS Скрипт переименования файла в кол-во дней с последней модификации

null@example.com (IrinaVZ) — Mon, 27 Dec 2010 15:26:00 +0000

Пока всё получается, спасибо большое.

Re: VBS Скрипт переименования файла в кол-во дней с последней модификации

null@example.com (Xameleon) — Mon, 27 Dec 2010 14:32:43 +0000

Option Explicit
Dim fso, folder, file, newname
Set fso = CreateObject("Scripting.FileSystemObject")
Set folder = fso.GetFolder(".")
for each file in folder.files
    if LCase(fso.GetExtensionName(file.name)) = "txt" Then
        newname = DatePart("d",now-file.DateLastModified) & fso.GetBaseName(file.name) & ".txt"
        file.name = newname
    End if
next

Если я правильно понял, то как то так.

VBS Скрипт переименования файла в кол-во дней с последней модификации

null@example.com (IrinaVZ) — Mon, 27 Dec 2010 14:12:55 +0000

Добрый день!

Я полный новичок в написании скриптов VBS. Возникла задача написать скрипт, который в каталоге для файла, например, 2.txt переименует его в файл (количество дней от текущей даты - дата последней модификации этого файла)2.txt.

Вот мои попытки, но что-то не получается, прошу помочь.

set FSO = CreateObject("Scripting.FileSystemObject")
Set Folder = FSO.GetFolder("C:\Logs\")

For Each eFile in Folder.Files=".txt"

Dim d1
Dim d2
Dim razn
d1 = DateLastModifed
d2=Date
razn = d2 - d1
FSO.MoveFile "2.txt", razn&"2.txt"