Серый форум — AHK: удерживание курсора мыши в определенном окне

Re: AHK: удерживание курсора мыши в определенном окне

2011-02-13T09:15:14Z

Примеры прекрасно в ней работают под W7 64.

Re: AHK: удерживание курсора мыши в определенном окне

2011-02-13T08:42:42Z

Нет. Я имею ввиду basic версию.

Re: AHK: удерживание курсора мыши в определенном окне

2011-02-13T08:37:13Z

Я как раз сейчас на ней, они прекрасно работают. Или имеете в виду АНК_64?

Re: AHK: удерживание курсора мыши в определенном окне

2011-02-13T07:52:24Z

Как заставить работать код из поста #22 или #23 на Windows7 64 бит?
Достаточно ли будет просто поменять строку

 NumPut(WI, VarSetCapacity(WI, 60))

на

 NumPut(WI, VarSetCapacity(WI, 120))

или что-то еще надо исправлять?

Re: AHK: удерживание курсора мыши в определенном окне

2011-01-06T12:53:43Z

YMP пишет:

Вот немного упрощённый код для клиентской области.

В таком варианте функция

DllCall("ClipCursor", UInt, &WI + 20)

бесполезно выполняется много раз подряд. На самом деле всё ещё проще, если не предполагается менять положение и размеры окна во время клипирования курсора:

   OnExit, Exit

   Run, notepad.exe,,, PID
   WinWait, ahk_pid %PID%
   WinGet, hTargetWin, ID, ahk_pid %PID%

   NumPut(WI, VarSetCapacity(WI, 60))
   SetTimer, WinExist
   Gosub, WGP
   Return

WinExist:
   if !WinExist("ahk_id " hTargetWin)
      ExitApp
      
   WinGet, AID, ID, A
   if (AID != hTargetWin)
   {
      if !NotActiveTarget
         DllCall("ClipCursor", UInt, 0), NotActiveTarget := 1
      Return
   }
   Else if (!switch && NotActiveTarget)
      Gosub, WGP
   Return

WGP:
   NotActiveTarget =
   DllCall("GetWindowInfo", UInt, hTargetWin, UInt, &WI)
   DllCall("ClipCursor", UInt, &WI + 20)
   Return

F11::
   if (switch := !switch)
      DllCall("ClipCursor", UInt, 0)
   Else
      Gosub, WGP
   Return

Esc:: ExitApp

Exit:
   DllCall("ClipCursor", UInt, 0)
   ExitApp

Re: AHK: удерживание курсора мыши в определенном окне

2011-01-06T10:21:39Z

InFlames пишет:

И подскажите от куда вы берете числа 48 и 52 для W и H границ?
Тут описана структура Windowinfo, но там 10 параметров.
На каждый параметр отводится свое кол-во байт? Как это узнать?

Думаю, из интернета не проблема это узнать. DWORD = (U)INT = (U)LONG = 4 байта. WORD = ATOM = 2 байта. RECT — структура из 4 LONG, т.е. 16 байт.

Хэндлы и указатели имеют разную величину: для 32-битных программ они по 4 байта, для 64-битных по 8. Т.е. тут имеет значение разрядность версии AutoHotkey, которую Вы используете, а не операционной системы.

rcClient по идее как раз и содержит координаты клиентской области окна, так что заморачиваться с толщиной границ вроде незачем.

Вот немного упрощённый код для клиентской области.

   OnExit, Exit
   
   Run, notepad.exe,,, PID
   WinWait, ahk_pid %PID%
   WinGet, hTargetWin, ID, ahk_pid %PID%
   
   NumPut(WI, VarSetCapacity(WI, 60))
   
   SetTimer, WGP, 10
   SetTimer, WinExist
   Return
   
WinExist:
   if !WinExist("ahk_id " hTargetWin)
      ExitApp
   Return

WGP:
   IfWinNotActive, ahk_id %hTargetWin%
   {
      If !NotActiveTarget
        DllCall("ClipCursor", UInt, 0), NotActiveTarget := 1
      Return
   }
   NotActiveTarget =
   DllCall("GetWindowInfo", UInt, hTargetWin, UInt, &WI)
   DllCall("ClipCursor", UInt, &WI + 20)   
   Return
   
F11::
   if (switch := !switch)
   {
      SetTimer, WGP, Off
      DllCall("ClipCursor", UInt, 0)
   }
   Else
      SetTimer, WGP, On
   Return
   
Esc:: ExitApp

Exit:
   DllCall("ClipCursor", UInt, 0)
   ExitApp

Re: AHK: удерживание курсора мыши в определенном окне

2011-01-06T09:31:12Z

teadrinker, да, нужно всё, кроме заголовка и окантовки. Строки меню в игре нет.
Впринципе вариант из поста #17 устраивает.
Вопрос в одном у всех ли окантовка окон с трех сторон по 8, сверху 30?
Или лучше определять это через WINDOWINFO ?
И подскажите от куда вы берете числа 48 и 52 для W и H границ?
Тут описана структура Windowinfo, но там 10 параметров.
На каждый параметр отводится свое кол-во байт? Как это узнать?

Re: AHK: удерживание курсора мыши в определенном окне

2011-01-06T03:32:55Z

teadrinker
По моим подсчётам размер WINDOWINFO — 60 байт.
F11 отключает захват, но повторное нажатие — не включает, если положение окна за это время не изменилось.

Re: AHK: удерживание курсора мыши в определенном окне

2011-01-05T23:52:49Z

Это всё вряд ли.
Проще по горячей клавише останавливать таймер, высвобождать курсор, затем снова запускать. Тогда для слежения за существованием окна нужен отдельный таймер. Клавиша F11. Кстати, из предыдущего варианта две важных строчки выпали:

    if (X = XPrev && Y = YPrev && W = WPrev && H = HPrev)
        Return

   OnExit, Exit
   
   Run, notepad.exe,,, PID
   WinWait, ahk_pid %PID%
   WinGet, hTargetWin, ID, ahk_pid %PID%
   
   NumPut(WI, VarSetCapacity(WI, 56))
   DllCall("GetWindowInfo", UInt, hTargetWin, UInt, &WI)
   WBorder := NumGet(WI, 48)
   HBorder := NumGet(WI, 52)
   Border := WBorder > HBorder ? WBorder : HBorder
   
   VarSetCapacity(RECT, 16)
   SetTimer, WGP
   SetTimer, WinExist
   Return
   
WinExist:
   if !WinExist("ahk_id " hTargetWin)
      ExitApp
   Return

WGP:
   WinGet, AID, ID, A
   if (AID != hTargetWin)
   {
      if !NotActiveTarget
         DllCall("ClipCursor", UInt, 0), NotActiveTarget := 1, XPrev := ""
      Return
   }
   
   NotActiveTarget =
   WinGetPos, X, Y, W, H, ahk_id %hTargetWin%
   if (X = XPrev && Y = YPrev && W = WPrev && H = HPrev)
      Return
      
   NumPut(X + Border, RECT), NumPut(Y + Border + 22, RECT, 4)
   NumPut(X + W - Border, RECT, 8), NumPut(Y + H - Border, RECT, 12)
   DllCall("ClipCursor", UInt, &RECT)
   
   XPrev := X, YPrev := Y, WPrev := W, HPrev := H
   Return
   
F11::
   if (switch := !switch)
   {
      SetTimer, WGP, Off
      DllCall("ClipCursor", UInt, 0)
   }
   Else
      SetTimer, WGP, On
   Return
   
Esc:: ExitApp

Exit:
   DllCall("ClipCursor", UInt, 0)
   ExitApp

InFlames пишет:

К верхней границе прибавил 22 пикселя, что бы курсор перемещался только в рамках рабочей области, а границы не затрагивал.

Может, нужна клиентская область окна — всё кроме строки заголовка, строки меню и окантовки? Если да, то можно точно определить её границы, без всяких прибавлений с помощью функции GetWindowInfo.

Re: AHK: удерживание курсора мыши в определенном окне

2011-01-05T23:15:41Z

Понемногу начинаю разбираться в этих функциях WinAPI, но всё понять не могу.

В строке

NumPut(X + Border, RECT), NumPut(Y + Border, RECT, 4)

К верхней границе прибавил 22 пикселя, что бы курсор перемещался только в рамках рабочей области, а границы не затрагивал.

NumPut(X + Border, RECT), NumPut(Y + Border + 22, RECT, 4)

Пусть теперь невозможно перетащить окно, но мне оно и не надо, главное, что бы курсор находился в рабочей области окна.

Еще вопрос, можно ли сделать так:
1. Запустили скрипт (с замененной строкой +22) - курсор находится в рабочей области экрана.
2. Сделать альт-таб, что бы окно стало неактивным.
3. Перетащить окно за заголовок (обычный способ перетаскивания окон), не активируя окна
4. Активировать окно, нажав ЛКМ по рабочей области окна (не по границам или заголовкам)
5. Опять альт-таб
6. Пока окно неактивно иметь возможность нажать на крестик, что бы закрыть окно.

Проще говоря, что бы при неактивном окне, кликая по заголовку или хватаясь за границы окна, что бы его растянуть, окно не активировалось. А активировалось в том случае, когда нажимаю ЛКМ в рабочую область.

Если такие запросы невыполнимы или чрезмерно надоедливы так и напишите

Re: AHK: удерживание курсора мыши в определенном окне

2011-01-05T21:28:17Z

InFlames пишет:

при этом курсор удерживался бы именно внутри области окна, не заезжая на границы окна, которые позволяют его расягивать.

По второму алгоритму для блокнота:

   OnExit, Exit
   
   Run, notepad.exe,,, PID
   WinWait, ahk_pid %PID%
   WinGet, hTargetWin, ID, ahk_pid %PID%
   
   VarSetCapacity(WI, 56)
   DllCall("GetWindowInfo", UInt, hTargetWin, UInt, &WI)
   WBorder := NumGet(WI, 48)
   HBorder := NumGet(WI, 52)
   Border := WBorder > HBorder ? WBorder : HBorder
   
   VarSetCapacity(RECT, 16)
   SetTimer, WGP, 10
   Return

WGP:
   if !WinExist("ahk_id " hTargetWin)
      ExitApp
      
   WinGet, AID, ID, A
   if (AID != hTargetWin)
   {
      if !NotActiveTarget
         DllCall("ClipCursor", UInt, 0), NotActiveTarget := 1, XPrev := ""
      Return
   }
   
   NotActiveTarget =
   WinGetPos, X, Y, W, H, ahk_id %hTargetWin%
   NumPut(X + Border, RECT), NumPut(Y + Border, RECT, 4)
   NumPut(X + W - Border, RECT, 8), NumPut(Y + H - Border, RECT, 12)
   DllCall("ClipCursor", UInt, &RECT)
   
   XPrev := X, YPrev := Y, WPrev := W, HPrev := H
   Return
   
Esc:: ExitApp

Exit:
   DllCall("ClipCursor", UInt, 0)
   ExitApp

Окно можно двигать за строку заголовка. Можно переключать активное окно с помощью Alt + Tab. При этом курсор высвобождается, при обратном переключении снова клипируется. При закрытии целевого окна скрипт завершается, высвобождая курсор.

Re: AHK: удерживание курсора мыши в определенном окне

2011-01-05T16:52:49Z

Windows 7. Эта галка у меня не стояла. Включение/выключение этой опции никакого эффекта не дало.
Отскакивает только от левого и верхнего края окна.

Re: AHK: удерживание курсора мыши в определенном окне

2011-01-05T14:51:59Z

Отскакивает, похоже, просто при очень быстром движении, даже не доходя до края окна, от пустого места.

В настройках мыши (в ХР) есть галочка "Включить повышенную точность установки указателя". Вот когда я её убрал, отскоки прекратились. И что интересно — когда поставил обратно, они не вернулись. Даже перезагрузился для верности — не отскакивает. Больше вроде не менял ничего, так что странно.

Re: AHK: удерживание курсора мыши в определенном окне

2011-01-05T14:19:04Z

Попозже попробую переписать, используя второй алгоритм.

Re: AHK: удерживание курсора мыши в определенном окне

2011-01-05T13:59:50Z

У меня не отскакивает, ей-богу! Даже не понимаю, как такое может получаться, исходя из логики получения координат:

   x := x < XW ? XW : x > XW + WW ? XW + WW : x
   y := y < YW ? YW : y > YW + HW ? YW + HW : y