Серый форум — CMD/BAT: Как удалить последние 6 символов из txt

Re: CMD/BAT: Как удалить последние 6 символов из txt

2012-11-02T17:16:11Z

mshta "about::" c:\temp\sample.txt

Re: CMD/BAT: Как удалить последние 6 символов из txt

2012-11-02T15:07:39Z

Помогите пожалуйста, как удалить последний символ, в конце файла (не строки)??

Re: CMD/BAT: Как удалить последние 6 символов из txt

2011-01-09T14:47:42Z

Первый пример из моего предыдущего поста.

Re: CMD/BAT: Как удалить последние 6 символов из txt

2011-01-09T14:45:12Z

Он в начало текста добавляет, мне надо в конец

Re: CMD/BAT: Как удалить последние 6 символов из txt

2011-01-09T13:58:45Z

echo %sLine:~0,-6%LAD>"%sTempFile%"

echo LAD%sLine:~0,-6%>"%sTempFile%"

Re: CMD/BAT: Как удалить последние 6 символов из txt

2011-01-09T13:56:17Z

Если делаю так, то текст добавляется с новой строки, а мне надо на первую.

echo LAD >>1.txt

Re: CMD/BAT: Как удалить последние 6 символов из txt

2011-01-09T13:49:07Z

Спасибо помогло, а если нужно ещё добавить текста, допустим "LAD"

Re: CMD/BAT: Как удалить последние 6 символов из txt

2011-01-08T10:12:57Z

Никак. Только созданием временного файла и замещением исходного. Например:

@echo off
setlocal

set sFile=0001.txt
set sTempFile=temp.tmp

<"%sFile%" set /p sLine=>nul
echo %sLine:~0,-6%>"%sTempFile%"
more +1 "%sFile%">>"%sTempFile%"
ren "%sFile%" "%sFile%.bak"
ren "%sTempFile%" "%sFile%"

endlocal
exit /b 0

Читаем первую строку исходного файла в переменную окружения «sLine»:

<"%sFile%" set /p sLine=>nul

Выводим все символы прочтённой первой строки, за исключением последних шести, в новый временный файл:

echo %sLine:~0,-6%>"%sTempFile%"

Добавляем все строки исходного файла, за исключением первой, в тот же временный файл:

more +1 "%sFile%">>"%sTempFile%"

Добавляем к исходному файлу расширение «.bak», меняем имя временного файла на имя исходного файла:

ren "%sFile%" "%sFile%.bak"
ren "%sTempFile%" "%sFile%"

CMD/BAT: Как удалить последние 6 символов из txt

2011-01-08T09:37:08Z

Здравствуйте, Как удалить последние 6 символов из первой строчки txt файла?