Аскет пишет:Это вы типа как бы намекаете комментировать каждую строчку?
Я говорю о том, что мне непонятно, чего Вы хотели, выкладывая Вашу разработку. Об этом Вы не написали в сопроводиловке.
Аскет пишет:Думаю скрипт достаточно откомментирован…
Раз возникли вопросы (и по поводу «On Error Resume Next» в частности) — очевидно, недостаточно.
Аскет пишет:Если вы опять же на что-то намекаете, то увы, отрабатывает корректно… А вы его вообще тестировали на работоспособность? Возьмите распакованный hxs/chm-документ … да натравите папку "html" на скрипт … а потом уже по факту кашляйте на "творение рук моих".
Пожалуйста.
Комментируем «On Error Resume Next». Запускаем скрипт. Выбираем папку с файлом *.htm. Получаем:
E:\Песочница\0036\0001.vbs(80, 9) Ошибка выполнения Microsoft VBScript: Недопустимое имя или номер
файла
Добавляю перед:
FSO.Movefile fileName, NewName & fileext
строку:
WScript.Echo fileName, NewName & fileext
Вижу:
author-patterns.htm \XPath Tutorial Application< - TITLE>.htm
Согласно стандарту HTML регистр символов в тэге «title» может быть произвольным. Браузер это понимает. Ваш скрипт:
str = replace (str,LCase("</title>"),"")
— нет.
Кашляю дальше. Ваш скрипт исправляет некоторые недопустимые символы «/», «\», «:» из формируемого заголовка. MSDN говорит о несколько большем числе: «/», «\», «:», «*», «#», «?», «"», «<», «>» и «|». Далеко ходить не надо — в том же упоминаемом MSDN большое число страниц с такими символами в тэге «title»:
<title>KB243298 - BUG: A "C2668: 'InlineIsEqualGUID'" error occurs when you try to build a default ATL project that contains a COM object in Visual C++</title>
<title>KB244232 - How To Add Context Help Button (? Button) to Title Bar of CPropertySheet</title>
<title>KB242527 - PRB: #import Wrapper Methods May Cause Access Violation</title>
Продолжать? Потрясающе в скрипте выглядит перебор строк файла — вплоть до конца строки:
Do While not (file_.AtEndOfLine) …
Обычно ограничение — конец файла.
Двигаемся дальше. Стандарт HTML предусматривает, что веб-страницы могут быть не только в ANSI и UTF-8, но и в других кодировках. «По факту» — Ваш скрипт об этом знать не знает и переименовывает такие страницы как есть — то бишь, в наличествующей кодировке. Например:
<meta http-equiv="Content-Type" content="text/html; charset=koi8-r">
<title>Серый форум / AHK: Помогите создать скрипт</title>
E:\Песочница\0036\уЕТЩК ЖПТХН - AHK рПНПЗЙФЕ УПЪДБФШ УЛТЙРФ.htm
А как насчёт того, что тэг «tile» не обязан располагаться на одной физической строке? Об этом скрипт тоже не в курсе. Итог — такое имя файла после работы скрипта:
Ну, как, коллега? Я насчитал пять мест, где Ваш скрипт чихать хотел на корректную работу и не делает того, что было заявлено.
Про использование недокументированных возможностей, типа «wsh.quit» вместо «WScript.Quit», полуописанные переменные (часть описана, часть нет), разный регистр в одних и тех же ключевых словах и общий внешний вид скрипта говорить после такого уже не хочется, хотя и это является необходимым требованием для помещения скрипта в Коллекцию.
Я бы вместо TextStream работал непосредственно c DOM или DHTML — сразу уйдут многие ошибки с некорректным определением «title». Наподобие:
Option Explicit
Dim objHTMLDocument
Dim objRegExp
Dim strTitle
Set objHTMLDocument = GetDocumentFromURL("file://E:\Песочница\0036\qww.htm")
Set objRegExp = WScript.CreateObject("VBScript.RegExp")
strTitle = objHTMLDocument.title
With objRegExp
.IgnoreCase = True
.Global = True
.Pattern = "[/|\\|:|\*|#|\?|""|<|>|\|]"
WScript.Echo .Replace(strTitle, "_")
End With
Set objRegExp = Nothing
Set objHTMLDocument = Nothing
WScript.Quit 0
'=============================================================================
'=============================================================================
'Set objHTMLDocument = DocumentFromURL(url)
' http://forum.script-coding.com/viewtopic.php?pid=34580#p34580
' http://forum.script-coding.com/viewtopic.php?pid=7920#p7920
Function GetDocumentFromURL(strURL)
Dim objHTMLDocument
Dim arrHtmlText
Set objHTMLDocument = WScript.CreateObject("HTMLFile")
With WScript.CreateObject("MSXML2.XMLHTTP")
.open "GET", strURL, False
.send
arrHtmlText = .responseBody
End With
With WScript.CreateObject("ADODB.Stream")
.Type = 1
.Open
.Write arrHtmlText
.Position = 0
.Type = 2
.Charset = "windows-1251"
objHTMLDocument.write .ReadText
End With
Set GetDocumentFromURL = objHTMLDocument
Set objHTMLDocument = Nothing
End Function
'=============================================================================
…
<title>
Серый форум / AHK: Помогите
создать скрипт =/=\=:=\=*=#=?="=<=>=|=
</title>
…
Серый форум _ AHK_ Помогите создать скрипт =_=_=_=_=_=_=_=_=_=_=_=
