Серый форум — VBS: Замена строк в Файле

Re: VBS: Замена строк в Файле

null@example.com (andreyua) — Thu, 21 Apr 2011 03:13:00 +0000

Спасибо
Сработало и довольно бысто ...

Re: VBS: Замена строк в Файле

null@example.com (Rumata) — Thu, 21 Apr 2011 02:54:05 +0000

Как вариант


Do Until WScript.StdIn.AtEndOfStream
    WScript.StdOut.WriteLine Replace(WScript.StdIn.ReadLine(), ",", ";", 1, 1)
Loop

Пример использования

cscript.exe //nologo 0001.vbs < "E:\Песочница\0052\In.txt" > "E:\Песочница\0052\Out.txt"

Re: VBS: Замена строк в Файле

null@example.com (alexii) — Thu, 21 Apr 2011 02:37:18 +0000

Ну, коли срочно…

Option Explicit

' IOMode Enum
Const ForReading   = 1
Const ForWriting   = 2
Const ForAppending = 8


Dim objFSO
Dim objTSIn
Dim objTSOut

Set objFSO   = WScript.CreateObject("Scripting.FileSystemObject")
Set objTSIn  = objFSO.OpenTextFile(WScript.Arguments.Item(0), ForReading)
Set objTSOut = objFSO.OpenTextFile(WScript.Arguments.Item(1), ForWriting, True)

Do Until objTSIn.AtEndOfStream
    objTSOut.WriteLine Replace(objTSIn.ReadLine(), ",", ";", 1, 1)
Loop

objTSOut.Close
objTSIn.Close

Set objTSOut = Nothing
Set objTSIn  = Nothing
Set objFSO   = Nothing

WScript.Quit 0

Входной и результирующий имена текстовых файлов указываете аргументами скрипта, наподобие:

cscript.exe //nologo 0001.vbs "E:\Песочница\0052\In.txt" "E:\Песочница\0052\Out.txt"

VBS: Замена строк в Файле

null@example.com (andreyua) — Thu, 21 Apr 2011 02:12:31 +0000

Необходимо сделать замену в текстовом файле всех символов "," на символ ";", но только в первом вхождении этого символа в строке .

Например, файл 1

подумайте сами,только вдумайтесь сами
порой,иногда
этот,данный
видный,образный,подобный
°снимите,°сшибите
1,один,одного,первого,одно,одну,одна
10,десять,десяти,десятого,десятый
100,сто

Нужно чтобы файл 2 после замены выгдел так

подумайте сами;только вдумайтесь сами
порой;иногда
этот;данный
видный;образный,подобный
°снимите;°сшибите
1;один,одного,первого,одно,одну,одна
10;десять,десяти,десятого,десятый
100;сто

P.S. Файл очень большой , TXT - 45 mb. Даже не знаю справится ли с ним скрипт ...
Помогите, нужно срочно