Серый форум — AHK: при активном CapsLock периодически нажималась левая клавиша мышки

Re: AHK: при активном CapsLock периодически нажималась левая клавиша мышки

null@example.com (Vasiliy_Andr) — Sun, 15 May 2011 10:24:46 +0000

СПАСИБО!!!

Re: AHK: при активном CapsLock периодически нажималась левая клавиша мышки

null@example.com (Grey) — Sat, 14 May 2011 21:43:05 +0000

Vasiliy_Andr пишет:

...Почему перед капслоком стоит ~

Это символ - префикс, для того, чтобы горячая клавиша могла сквозь действие скрипта при нажатии исполнять свою функцию/назначение (подробнее тут).

Vasiliy_Andr пишет:

Что это такое?
Suspend

Это параметр эквивалентный комманде в контекстном меню/трее (Suspend Hotkeys) запущенного скрипта, т.е. при наличии этого параметра в верхней части любого скрипта, запуск происходит в неактивном состоянии (Suspend).

Vasiliy_Andr пишет:

Что за системная переменная, где смотреть полный список?
(A_IsSuspended)

Переменные и выражения (Спасибо добрым людям за перевод )

Re: AHK: при активном CapsLock периодически нажималась левая клавиша мышки

null@example.com (Vasiliy_Andr) — Sat, 14 May 2011 20:19:55 +0000

Спасибо!!!:D

Поясние, если не сложно
1. Что это такое???Почему перед капслоком стоит ~

~CapsLock

2. Что это такое???

Suspend

3. Что за системная переменная, где смотреть полный список

(A_IsSuspended)

Re: AHK: при активном CapsLock периодически нажималась левая клавиша мышки

null@example.com (Grey) — Sat, 14 May 2011 19:28:59 +0000

Сделано по аналогии:

Suspend, On ; запуск в отключенном состоянии
SetCapsLockState, Off ; если включен капс/горит индикатор - отключаем
ToolTip, ENTER, 640, 512 ; тултип можно убрать - это для наглядности
Sleep, 250 ; время отображения тултипа
Tooltip
Return

~CapsLock::
Suspend
   If (A_IsSuspended)
      {
         SetTimer, spawn_clicks, Off
         ToolTip, OFF, 640, 512
         Sleep, 250
         Tooltip
         SoundBeep, 2500, 250 ; звуковой сигнал тоже при желании можно убрать
         Sleep, 50
         SoundBeep, 2500, 250
      }
   Else
      {
         SetTimer, spawn_clicks, 1000 ; время частоты интераций подбираеться по вкусу (в данном случае 1сек.)
         ToolTip, ON, 640, 512
         Sleep, 250
         Tooltip
         SoundBeep, 2500, 250
      }
   Return

spawn_clicks:
   MouseClick, L
   Return

F12:: ; клавиша завершения работы скрипта.
   Suspend, Off
   SetCapsLockState, Off
   ToolTip, EXIT, 640, 512
   Sleep, 250
   Tooltip
   ExitApp

AHK: при активном CapsLock периодически нажималась левая клавиша мышки

null@example.com (Vasiliy_Andr) — Sat, 14 May 2011 08:21:30 +0000

Идея такая.

Написать скрипт, чтобы при активном CapsLock периодически нажималась левая клавиша мышки, соответсвенно при выключенном капсе мышка не нажималась...

Пытался нечто подобное реализовать на LCtrl

LCtrl::                                            
Sleep, 100
loop
{    
    GetKeyState, state, LCtrl, P
    ;msgbox %state% 
           Sleep, 10
        if state = D            
            {
            break
            return
            }
        else
                     {
            SoundBEEP 30, 50
            MouseClick, left            
            }