Серый форум — CMD/BAT: Цикл for с одной строкой

Re: CMD/BAT: Цикл for с одной строкой

null@example.com (Александр_foxware) — Wed, 28 Sep 2011 20:59:59 +0000

Большое спасибо

Re: CMD/BAT: Цикл for с одной строкой

null@example.com (alexii) — Wed, 28 Sep 2011 00:23:55 +0000

Александр_foxware, один вариант уже указал коллега shiz. Не забывайте про возможность изменения разделителя посредством замены, например: «%var:-= %».

Второй вариант — разбор посредством вызова процедуры:

@echo off
setlocal enableextensions enabledelayedexpansion

set extensionfind=dbf;cdx;dd;md

call :Parse %extensionfind:;= %

endlocal
exit /b 0

:Parse
    setlocal enableextensions enabledelayedexpansion
:Repeat
    set sValue=%~1

    if defined sValue (
        echo [%sValue%]
        shift
        goto :Repeat
    )

    echo Done

    endlocal
    exit /b 0

Использование процедуры даёт большие возможности в плане разбора. Например, можно в начале пропустить какие-то аргументы («shift /n» в начале), можно читать только чётные или нечётные аргументы («shift /2» внутри блока разбора) и т.п.

Re: CMD/BAT: Цикл for с одной строкой

null@example.com (Rumata) — Tue, 27 Sep 2011 22:32:35 +0000

Используйте шаблон-звездочку для указания "всего остального":
либо так


for /f "tokens=* delims=," ...

либо так


for /f "tokens=1* delims=," ...

Re: CMD/BAT: Цикл for с одной строкой

null@example.com (shiz) — Tue, 27 Sep 2011 21:38:20 +0000

Попробуй просто

for %%a in (%extensionfind%) do echo %%a

CMD/BAT: Цикл for с одной строкой

null@example.com (Александр_foxware) — Tue, 27 Sep 2011 15:23:21 +0000

Здраствуйте! Пытаюсь сладить с конструкцией for, что-то не получается.
Как сделать так чтобы в цикле перебрал значения из одной строки.

set extensionfind=dbf,cdx,dd,md
for /f "Tokens=1-10 delims=," %%a in ("%extensionfind%") do echo %%a >> 1.txt

Берет только первое значение в строке. Я понимаю что в следующих строчках %%b,%%c,%%d будут мои значения. Но количество значений меняется да и как то неудобно писать для каждого значения строчку.

set extensionfind=dbf,cdx,dd,md
for /f "Tokens=1-10 delims=," %%a in ("%extensionfind%") do (
	echo %%a >> finding.txt
	echo %%b >> finding.txt
	echo %%c >> finding.txt
	echo %%d >> finding.txt
	echo %%e >> finding.txt
)

И при таком варианте, когда пятого значения нет выдаст что режим отображения включен.