Спасибо, я что-то подобное подозревал.
Если дело именно в последнем item, доработка упрощается — если это папка, можно приложить условие к ней и так при необходимости по цепочке.
Но если не быть уверенным в "естественном" порядке добавления файлов в zip, то придётся использовать полноценную рекурсию или перебор в глубину.
Решение с проверкой .Items.Count я подсмотрел на этом форуме (см. Коллекцию, автор примера - Xameleon:

'...
    Function CopyFolderToArchive(FolderPath)
        If (ArchiveFolder Is Nothing) Then Exit Function
        ArchiveFolder.CopyHere FolderPath
        ItemsCount = ItemsCount + 1
    End Function 

    Function CloseArchive
        If (ArchiveFolder is Nothing) Then Exit Function
        Set WsriptShell = CreateObject("Wscript.Shell")
        If IsObject(Wscript) Then
            Do
                Wscript.Sleep 100
            Loop Until ArchiveFolder.Items.Count => ItemsCount
        Else
            ServerSleep
        End if
        ItemsCount = 0
    End Function
'...

) - сам бы к своему стыду до него, вероятно, не додумался,
а через небольшие промежутки времени проверял бы размер создаваемого ZIP до тех пор пока он не перестал бы увеличиваться - не знаю, насколько это надёжно...

А должен ?

Ну... Про ZIP речь вроде не шла
Сорри, становится не видно смысла данной темы

А должен ?

Это не научный подход - гадать с WScript.Sleep .
По-моему, будет правильнее (хотя возможно, и потребуется доработка...

По-моему форум для того и создан...
Вот Вы уже и сами предложили более рациональное решение.
Меня всего лишь заинтересовал вопрос как зазиповать с помощью скрипта - что нагуглил - трансформировал в ответ на Ваш пост
Наверняка, захотите - решите.
Уважаемый alexii, как повелось, может возразить - кто упоминал про zip?

По-моему, будет правильнее (хотя возможно, и потребуется доработка

Доработка потребуется: если последний item — папка с большим количеством папок и файлов — скрипт опять не успеет. Но подход, конечно, более разумный, нежели «на авось».

' ...
objShell.NameSpace(strZipPath).CopyHere objFolder.Items
 
Set objFolder = Nothing
Set objShell = Nothing
'если размер каталога большой - добавьте секунд
WScript.Sleep 1000

В коде читаем коммент: "'если размер каталога большой - добавьте секунд"
Попробуйте WScript.Sleep 5000, или даже 10000 - наверняка .

Это не научный подход - гадать с WScript.Sleep .
По-моему, будет правильнее (хотя возможно, и потребуется доработка
+ добавте объявление objZipFolder и intCount):

' ...
intCount = objFolder.Items.Count
Set objZipFolder = objShell.NameSpace(strZipPath)
objZipFolder.CopyHere objFolder.Items
While objZipFolder.Items.Count < intCount
  WScript.Sleep 500
Wend

Set objFolder = Nothing
Set objShell = Nothing

как ни странно но архив получается пустым

В коде читаем коммент: "'если размер каталога большой - добавьте секунд"
Попробуйте WScript.Sleep 5000, или даже 10000 - наверняка .

Option Explicit
Dim fso, objShell, wshShell
Dim strZipPath
Dim objFolder

Set wshShell = CreateObject("WScript.Shell")
'путь к zip-файлу
strZipPath = wshShell.CurrentDirectory & ".zip"

Set fso = CreateObject("Scripting.FileSystemObject")
'создаем пустой zip-файл
fso.CreateTextFile(strZipPath, True).Write "PK" & Chr(5) & Chr(6) & String(18, vbNullChar)
Set fso = Nothing

Set objShell = CreateObject("Shell.Application")
Set objFolder = objShell.NameSpace(wshShell.CurrentDirectory)
Set wshShell = Nothing

objShell.NameSpace(strZipPath).CopyHere objFolder.Items

Set objFolder = Nothing
Set objShell = Nothing
'если размер каталога большой - добавьте секунд
WScript.Sleep 1000

Скрипт пакует содержание текущего каталога.
Распаковать можно так:

Option Explicit
Dim fso, objShell, wshShell
Dim strZipPath

Set wshShell = CreateObject("WScript.Shell")
'путь к zip-файлу
strZipPath = wshShell.CurrentDirectory & ".zip"
Set fso = CreateObject("Scripting.FileSystemObject")
If fso.FileExists(strZipPath) Then	
	Set objShell = CreateObject("Shell.Application")
	objShell.NameSpace(wshShell.CurrentDirectory).CopyHere(objShell.NameSpace(strZipPath).Items)
	Set objShell = Nothing	
End If
Set fso = Nothing
Set wshShell = Nothing

Подобным образом можете резервировать/распаковывать каталоги:
- objShell.NameSpace(&H1a).Self.Path & "\Thunderbird"
- objShell.NameSpace(&H1c).Self.Path & "\Thunderbird"
или где там находятся файлы Вашей птицы

C:\Program Files\Mozilla Thunderbird

А это зачем?