Серый форум — WSH: Поиск и извлечение текста из XML

Re: WSH: Поиск и извлечение текста из XML

2011-11-03T09:37:47Z

Разобрался. Спасибо. Сделал вот так :


firm = Replace(firm,"'","")
firm = Replace(firm,"""", "")
firm = Replace(firm,"»", "")
firm = Replace(firm,"«", "")

Корректировка не нужна?

Re: WSH: Поиск и извлечение текста из XML

2011-11-03T09:25:50Z

Ну если замен не очень много, то можно и обычным Replace() обойтись.

А если нужно отсеить только разрешённые символы, то наверное и так можно:


Const ValidChars = "0123456789abcdefghijklmnopqrstuvwxyz абвгдеёжзийклмнопрстуфхцчшщъыьэюя"
'Без учёта регистра
MsgBox GetOnlyValidChars("Фирма ООО ЗАО ""ХРЕНТУДЫСЬ"" ###", ValidChars, 1)
'С учётом регистра
MsgBox GetOnlyValidChars("фирма ООО ЗАО ""ХРЕНТУДЫСЬ"" ###", ValidChars, 0)

Function GetOnlyValidChars(sString, ValidChars, Compare)
    Dim i, char
    For i = 1 To Len(sString)
        char = Mid(sString, i, 1)
        If InStr(1, ValidChars, char, Compare) > 0 Then GetOnlyValidChars = GetOnlyValidChars & char
    Next
End Function

Re: WSH: Поиск и извлечение текста из XML

2011-11-03T08:39:43Z

Благодарю. Вот что получилось у меня. Но есть вопрос:

Dim DOMDocument, Node, tmpStr 
Set DOMDocument = CreateObject("MSXML2.DOMDocument") 
With DOMDocument 
    .Load "C:\XML\" & basename 
    if .parseError.reason <> "" Then 
        MsgBox .parseError.reason,vbCritical 

        WScript.Quit 

    End if 
    With .documentElement.SelectSingleNode("списокСубъектов") 
        tmpStr = "" 
        For Each Node in .SelectNodes("субъект") 
            sNomer = Node.GetAttribute("идентификаторСубъекта") 
             firm = Node.GetAttribute("имя")           
    MsgBox sNomer 
   MsgBox firm 
  Next 
 End With 
End With

В поле имя иногда могут быть кавычки. А мне надо, что там были только буквы безо всяких кавычек.
Как мне сделать замену символов(коротко - удалить):
'
"
»
«

Re: WSH: Поиск и извлечение текста из XML

2011-11-02T15:36:01Z

Любую задачу можно решить несколькими путями. Вариации на тему решения Xameleon


Option Explicit

Dim DOMDocument, Subjs, Subj, I, tmpStr
Set DOMDocument = CreateObject("MSXML2.DOMDocument")

With DOMDocument
    .Load "1.xml"
    if .parseError.reason <> "" Then
        MsgBox .parseError.reason,vbCritical
        WScript.Quit
    End if

    Set Subjs = .GetElementsByTagName("субъект")

    For I = 0 To Subjs.Length - 1
        tmpStr = ""
        tmpStr = tmpStr & "Идентификатор субъекта: " & Subjs(I).GetAttribute("идентификаторСубъекта") & vbCrlf
        tmpStr = tmpStr & "Тип субъекта: " & Subjs(I).GetAttribute("типСубъекта") & vbCrlf
        tmpStr = tmpStr & "имя: " & Subjs(I).GetAttribute("имя") & vbCrlf
        WScript.Echo tmpStr
    Next
End With


Option Explicit

Dim DOMDocument, Subjs, Subj, I, tmpStr
Set DOMDocument = CreateObject("MSXML2.DOMDocument")

With DOMDocument
    .Load "1.xml"
    if .parseError.reason <> "" Then
        MsgBox .parseError.reason,vbCritical
        WScript.Quit
    End if

    Set Subjs = .GetElementsByTagName("субъект")

    For Each Subj In Subjs
        tmpStr = ""
        tmpStr = tmpStr & "Идентификатор субъекта: " & Subj.GetAttribute("идентификаторСубъекта") & vbCrlf
        tmpStr = tmpStr & "Тип субъекта: " & Subj.GetAttribute("типСубъекта") & vbCrlf
        tmpStr = tmpStr & "имя: " & Subj.GetAttribute("имя") & vbCrlf
        WScript.Echo tmpStr
    Next

Re: WSH: Поиск и извлечение текста из XML

2011-11-02T12:52:33Z

Хм... ну т.к Вы привели не полное содержимое XML, то мне пришлось догадываться о том где закрываются тэги.

В итоге предположил, что так


 
<регистрационнаяИнформация> 
<датаВремяФормирования>2011-10-31T15:49:58 
<списокСубъектов> 
<субъект идентификаторСубъекта="002-871-100318" типСубъекта="АбонентСЭД" имя="ООО 'Компенсатор'">
<списокСертификатов типПодписанта="руководитель"> 
<сертификат активный="true">

В кратце можно дёрнуть как то так наверное.


Option Explicit
Dim DOMDocument, Node, tmpStr
Set DOMDocument = CreateObject("MSXML2.DOMDocument")
With DOMDocument
	.Load "1.xml"
	if .parseError.reason <> "" Then
	    MsgBox .parseError.reason,vbCritical
	    WScript.Quit
	End if
	With .documentElement.SelectSingleNode("списокСубъектов")
        tmpStr = ""
        For Each Node in .SelectNodes("субъект")
            tmpStr = tmpStr & "Идентификатор субъекта: " & Node.GetAttribute("идентификаторСубъекта") & vbCrlf
            tmpStr = tmpStr & "Тип субъекта: " & Node.GetAttribute("идентификаторСубъекта") & vbCrlf
            tmpStr = tmpStr & "имя: " & Node.GetAttribute("имя") & vbCrlf
            MsgBox tmpStr
        Next
    End With
End With

WSH: Поиск и извлечение текста из XML

2011-11-02T11:50:21Z

Ребята. Вопрос.
Есть строка в XML файле :

<субъект идентификаторСубъекта="002-871-100318" типСубъекта="АбонентСЭД" имя="ООО 'Компенсатор'">

Как вытащить идентификатор субъекта и имя компании?
Имеется ввиду присвоить эти данные в какие нить переменные, откуда я потом их смогу использовать.

С самого начала идентификатор субъекта вытаскивал при помощи позиции символа:

Set objFSO= WScript.CreateObject("Scripting.FileSystemObject") 
  Set txtFile = objFSO.OpenTextFile("C:\XML\" & basename) 
  Do While Not txtFile.AtEndOfStream 
ReadLineTXT = txtFile.ReadLINE 
   If InStr(ReadLineTXT, "идентификаторСубъекта=""") Then 
     sNomer = mid(readlinetxt, 37, 14) 
wscript.echo sNomer 
      Exit Do 
    End If 
  Loop 
  txtFile.Close

А вот с компании стало потруднее, поскольку каждый раз имя компании по длине менялось.

Помогите пожалуйста.

P.S.
Сама XML с начала выглядит так:

 
<регистрационнаяИнформация> 
<датаВремяФормирования>2011-10-31T15:49:58 
<списокСубъектов> 
<субъект идентификаторСубъекта="002-871-100318" типСубъекта="АбонентСЭД" имя="ООО 'Компенсатор'"> 
<списокСертификатов типПодписанта="руководитель"> 
<сертификат активный="true">