Серый форум — AHK: Чтение текста из контролов всех окон

Re: AHK: Чтение текста из контролов всех окон

null@example.com (Александр_) — Tue, 29 Nov 2011 17:05:22 +0000

Tatrin пишет:

Извините за невнимательность. Попробовал в работе этот скрипт на примере запущенного блокнота. Выводится класс и название блокнота, но текст который в нем записан не отображается. Не подскажите как его прочитать?

Нужно "WinGetText WindowText, ahk_id %cur%" заменить на "ControlGetText WindowText,, ahk_id %cur%". Но в общем случае нужно проверить, является ли окно контролом(свойство WS_CHILD) и вызвать соответствующую функцию.

Re: AHK: Чтение текста из контролов всех окон

null@example.com (Grey) — Tue, 29 Nov 2011 12:45:51 +0000

Tatrin пишет:

Выводится класс и название блокнота, но текст который в нем записан не отображается. ...как его прочитать?

Gui, Add, Edit, vControlText x12 y10 w450 h350
Gui, -MaximizeBox
Gui, Show, Center w474 h372, Test
ControlGetText, CText, Edit1, ahk_class Notepad ; Edit1 - название контрола содержащего текст
GuiControl,, ControlText, % CText ? CText:"Блокнот не запущен, или не имеет текста!"
Return

GuiClose:
   ExitApp

F5::Reload
Esc::ExitApp

Re: AHK: Чтение текста из контролов всех окон

null@example.com (Tatrin) — Mon, 28 Nov 2011 15:47:29 +0000

Извините за невнимательность. Попробовал в работе этот скрипт на примере запущенного блокнота. Выводится класс и название блокнота, но текст который в нем записан не отображается. Не подскажите как его прочитать?

Re: AHK: Чтение текста из контролов всех окон

null@example.com (Александр_) — Sat, 26 Nov 2011 15:04:03 +0000

Tatrin пишет:

В этом примере в файл записывается вся информация со всех окон

О_о
В этом примере записываются только имя класса и текст из всех окон указанного процесса.

Re: AHK: Чтение текста из контролов всех окон

null@example.com (Tatrin) — Sat, 26 Nov 2011 13:18:03 +0000

В этом примере в файл записывается вся информация со всех окон, а мне нужен текст только окна указанного процесса. Извините если чего-то не понимаю, я в AHK новичок. Как я понимаю нужно добавить проверку на PID для каждого полученного окна, или для каждого окна надо еще применять функцию ControlGetText?

Re: AHK: Чтение текста из контролов всех окон

null@example.com (Александр_) — Fri, 25 Nov 2011 17:16:54 +0000

Tatrin пишет:

Вот что мне нужно сделать:
приходит id процесса, мне нужно найти окно которое соответствует этому процессу и вытянуть из него весь текст включая текст контролов и записывать их в текстовый документ.
...
Может кто подсказать как это сделать?

так?

FindWindowEx(hwndParent, hwndChildAfter, ClassName, WindowName)
{
   return DllCall("FindWindowEx", "uint", hwndParent, "uint", hwndChildAfter, "uint", ClassName, "uint", WindowName, "uint")
}
EnumChild(hwndParent, byref str, byref prestr)
{
   cur:=FindWindowEx(hwndParent, 0, 0, 0)
   if (cur=0)
   {
      return
   }
   str:=str . prestr . "{`n"
   prestr:=prestr . "   "
   while (cur<>0)
   {
      WinGetClass ClassName, ahk_id %cur%
	  WinGetText WindowText, ahk_id %cur%
	  WindowText := RegExReplace(WindowText, "\r\n|\n|\r", "\n")
	  str:=str . prestr . "ClassName '" . ClassName . "', WindowName '" . WindowText . "'`n"
	  EnumChild(cur, str, prestr)
      cur:=FindWindowEx(hwndParent, cur, 0, 0)
   }
   prestr:=SubStr(prestr, 1 , StrLen(prestr)-3)
   str:=str . prestr . "}`n"
}

DetectHiddenWindows on
DetectHiddenText on
pid:=4848 ; идентификатор нужного процесса
WinGet id, list, ahk_pid %pid%
str:="" ; строка для записи в файл
prestr:="" ; пробелы для читабельности
Loop, %id%
{
    this_id := id%A_Index%
	WinGetClass, ClassName, ahk_id %this_id%
	WinGetTitle, WindowName, ahk_id %this_id%
	str:=str . "ClassName '" . ClassName . "', WindowName '" . WindowName . "'`n"
	EnumChild(id%A_Index%, str, prestr)
}
FileDelete %a_scriptdir%\1.txt 
FileAppend %str%, %a_scriptdir%\1.txt

Re: AHK: Чтение текста из контролов всех окон

null@example.com (ypppu) — Fri, 25 Nov 2011 15:48:13 +0000

Tatrin, прочитайте первую тему в этом разделе. Затем исправьте заголовок темы, отредактировав первое сообщение. Оформите код правильно.

AHK: Чтение текста из контролов всех окон

null@example.com (Tatrin) — Fri, 25 Nov 2011 15:20:13 +0000

Вот что мне нужно сделать:
приходит id процесса, мне нужно найти окно которое соответствует этому процессу и вытянуть из него весь текст включая текст контролов и записывать их в текстовый документ.

на данном этапе дошел до следующего скрипта:

DetectHiddenWindows,on
DetectHiddenText, on
WinGet, id, list,,, Program Manager
Loop, %id%
{
    this_id := id%A_Index%
    WinActivate, ahk_id %this_id%
    WinGet, ControlList, ControlList,A
    WinGetText,  this_text,  ahk_id %this_id%
 ;   ControlGet, List, List, Selected, SysListView321, WinTitle
    FileAppend, %this_text% `n, D:\1.txt
}

Может кто подсказать как это сделать?