Серый форум — VBS: Удаление в файлов корзину

Re: VBS: Удаление в файлов корзину

2011-12-28T06:37:59Z

Вспомнил еще один пример асинхронной работы методов Shell.Application с которым столкнулся ранее в процессе поиска решения задачи архивирования файлов:


sZipFolderPath = "c:\temp" 'каталог для zip-архивов

With CreateObject("Scripting.FileSystemObject")
	'путь к текущему каталогу
	sFolderPath = .GetParentFolderName(WScript.ScriptFullName)
	'путь к zip-архиву
	sZipPath = sZipFolderPath & "\" & .GetBaseName(sFolderPath) & ".zip"
	'создаем пустой zip-файл
	.CreateTextFile(sZipPath, True).Write "PK" & Chr(5) & Chr(6) & String(18, vbNullChar)
End With
'копируем файлы в архив
With CreateObject("Shell.Application")
	.NameSpace(sZipPath).CopyHere .NameSpace(sFolderPath).Items
End With
'без Sleep - никак, если размер каталога большой - добавляем секунд
WScript.Sleep 1000

Re: VBS: Удаление в файлов корзину

2011-12-27T17:58:28Z

alexii пишет:

VSVLAD, dab00 — так синхронно или асинхронно происходит?

Похоже асинхронно. Я сразу обозначил, что "для кого-то очевидно...", alexii как всегда на высоте .
Видимо, как отмечено в посте, "скрипт завершает свою работу, прежде чем методы успевают отработать".

smaharbA пишет:

дануна

Это не наш метод .

Re: VBS: Удаление в файлов корзину

2011-12-27T17:04:26Z

дануна

del /q %temp%\r.txt & fsutil file createnew %temp%\r.txt 1000000000 & start "" mshta "javascript:x=new ActiveXObject('shell.application').NameSpace('::{645FF040-5081-101B-9F08-00AA002F954E}');x.MoveHere('%temp:\=/%/r.txt');window.close()" & dir %temp%\r.txt

Re: VBS: Удаление в файлов корзину

2011-12-27T16:18:20Z

Проверил также в VBS, запускал без флагов... Заменил Sleep на MsgBox. Пока я не отменил перемещение, MsgBox не вылез, следовательно синхронно.

Re: VBS: Удаление в файлов корзину

2011-12-27T16:13:18Z

в вб работают флаги, в вбс нет

Re: VBS: Удаление в файлов корзину

2011-12-27T16:07:36Z

синхронно, я проверил у себя. Запускал в среде VB6/WScript XP SP3. Появляется стандартное окошко пермещения файла, которое показывает Explorer

Re: VBS: Удаление в файлов корзину

2011-12-27T15:43:29Z

VSVLAD, dab00 — так синхронно или асинхронно происходит?

Re: VBS: Удаление в файлов корзину

2011-12-27T15:35:20Z

2VSVLAD: для перемещения неважно, большой файл или мелкий.

dab00 пишет:

…и заметил одну особенность.

VBScript: запуск файлов ассоциированным приложением

Re: VBS: Удаление в файлов корзину

2011-12-27T15:30:24Z

Читать количество файлов в исходной папке, если уменьшилось - то перемещение завершено успешно и продолжать дальше по циклу For Each. Sleep 10 не хватит если файл большой.

--
В принципе можно и не читать, операция происходит синхронно, поэтому код приостановит своё выполнение пока файл не переместится

Re: VBS: Удаление в файлов корзину

2011-12-27T13:11:43Z

smaharbA пишет:

фишка не в слипе, читай содержимое корзины

Не могли бы Вы пояснить, зачем и куда читать? Со слипом прокатило...

Re: VBS: Удаление в файлов корзину

2011-12-27T12:13:05Z

фишка не в слипе, читай содержимое корзины

VBS: Удаление в файлов корзину

2011-12-27T11:48:02Z

Здравствуйте, уважаемые коллеги.
Сегодня решал задачу удаления файлов в корзину через VBS и заметил одну особенность. Потратил чуть больше времени, чем ожидал, надеюсь решение сэкономит ваше.
Фишка в WScript.Sleep. Без него никак. Наверное для кого-то очевидно... короче вот:


sFolderPath = "c:\temp\"
dDateDif = DateAdd("d", -7, Date)
sExt = "txt"

Set fso = CreateObject("Scripting.FileSystemObject")
Set recyclebin = CreateObject("Shell.Application").Namespace(10)

For Each oFile In fso.GetFolder(sFolderPath).Files
	If oFile.DateLastModified < dDateDif And LCase(fso.GetExtensionName(oFile.Name)) = LCase(sExt) Then			
		recyclebin.MoveHere(oFile.Path)
		WScript.Sleep 10 
	End If
Next

Вероятно в случае большого размера файлов количество миллисекунд надо будет увеличить.