У меня тоже не всегда (Win 7).

Подтверждаю баг. Пытались коллективно определить его причину - не смогли.
Можете попробовать увеличить SetKeyDelay до 50-100.

Вот другая версия этого же скрипта.
В ней можно переключаться между окнами внутри групп окон (если у вас включена группировка схожих задач).
Немного кривоватый скрипт, нуждается в множестве мелких доработок, но как основа - прекрасен.

Count=0
SetKeyDelay,20
IsActive() {        
   MouseGetPos, , , id
   return id=WinExist("ahk_class Shell_TrayWnd") ? 1 : 0
}
TaskBarPos() {
    WinGetPos,X,Y,W,H,ahk_class Shell_TrayWnd
    return x=0 ? y=0 ? h<w ? "Top" : "Left" : "Bottom" : "Right"
}
#If IsActive()
WheelDown::
WheelUp::
Max := Num()
Count := Count <= 1 ? Max : Count -1
if (Count<=Max&& Count>1)
ControlSend, , % (A_ThisHotkey="WheelDown" ? TaskBarPos()="Top" || TaskBarPos()="Bottom" ? "{Right}" : "{Down}" : TaskBarPos()="Top" || TaskBarPos()="Bottom" ? "{Left}" : "{Up}" ) ,ahk_class TaskListThumbnailWnd
else
ControlSend, MSTaskListWClass1, % "{PGND}" (A_ThisHotkey="WheelDown" ? TaskBarPos()="Top" || TaskBarPos()="Bottom" ? "{Right}{Up}" : "{Down}{Left}" : TaskBarPos()="Top" || TaskBarPos()="Bottom" ? "{Left}{Up}" : "{Up}{Left}" ) ,ahk_class Shell_TrayWnd
SetTimer, Check, 50
return
#If
Check:
    If !IsActive() {
       ControlSend, , {Enter}, ahk_class TaskListThumbnailWnd
        SetTimer, Check, Off
    }
return
F3::ExitApp
Num() {
  return Acc_ObjectFromWindow(WinExist("ahk_class TaskListThumbnailWnd")).accChildCount//3
}
Acc_ObjectFromWindow(hWnd, idObject = -4){
    Static  h
    If Not  h
        h:=DllCall("LoadLibrary","Str","oleacc","Ptr")
    If  DllCall("oleacc\AccessibleObjectFromWindow", "Ptr", hWnd, "UInt", idObject&=0xFFFFFFFF, "Ptr", -VarSetCapacity(IID,16)+NumPut(idObject==0xFFFFFFF0?0x46000000000000C0:0x719B3800AA000C81,NumPut(idObject==0xFFFFFFF0?0x0000000000020400:0x11CF3C3D618736E0,IID,"Int64"),"Int64"), "Ptr*", pacc)=0
    Return  ComObjEnwrap(9,pacc,1)
}

Upd: Не всегда срабатывает переключение - к примеру, активна Опера, колесом выбираю ТС, но при возвращении курсора за пределы таскбара опять активой становится Опера.

У меня тоже не всегда (Win 7).

Upd: Не всегда срабатывает переключение - к примеру, активна Опера, колесом выбираю ТС, но при возвращении курсора за пределы таскбара опять активой становится Опера.

В последней части скрипта имеется:

Check:
If !IsClassUnderMouse("Shell_TrayWnd") {
ControlSend MSTaskListWClass1, {LButton}{enter}, ahk_class Shell_TrayWnd
SetTimer, Check, Off
} return

Вопрос 1: зачем вообще там сначала посылается {LButton}?
Вопрос 2: если {LButton} заменить (или просто добавить после него) на {Left} (который по идее ничего не должен сломать ни для 1 из случаев) - скрипт всё равно не срабатывает на группах окон. Почему?

IsClassUnderMouse(class) {
   MouseGetPos, , , id
   WinGetClass, this_class, ahk_id %id%
   return this_class=class
}

#IF IsClassUnderMouse("Shell_TrayWnd")

WheelUp::
   WinGetPos,,, W, H, ahk_class Shell_TrayWnd
   ControlSend, MSTaskListWClass1, % W>H ? "{Right}":"{Up}", ahk_class Shell_TrayWnd
   SetTimer, Check, 50
   Return
 
WheelDown::
   WinGetPos,,, W, H, ahk_class Shell_TrayWnd
   ControlSend, MSTaskListWClass1, % W>H ? "{Left}":"{Down}", ahk_class Shell_TrayWnd
   SetTimer, Check, 50
   Return

#IF

Check:
If !IsClassUnderMouse("Shell_TrayWnd") {
ControlSend MSTaskListWClass1, {LButton}{enter}, ahk_class Shell_TrayWnd
SetTimer, Check, Off
} return

Пробовал и так:

IsClassUnderMouse(class) {
   MouseGetPos, , , id
   WinGetClass, this_class, ahk_id %id%
   return this_class=class
}

#IF IsClassUnderMouse("Shell_TrayWnd")

WheelUp::
   WinGetPos,,, W, H, ahk_class Shell_TrayWnd
if W>H
{
ControlSend MSTaskListWClass1, {Up}, ahk_class Shell_TrayWnd
SetTimer, Check, 50
return
}
else
{
ControlSend MSTaskListWClass1, {Right}, ahk_class Shell_TrayWnd
SetTimer, Check, 50
return
}

WheelDown::
   WinGetPos,,, W, H, ahk_class Shell_TrayWnd
if W>H
{
ControlSend MSTaskListWClass1, {Down}, ahk_class Shell_TrayWnd
SetTimer, Check, 50
return
}
else
{
ControlSend MSTaskListWClass1, {Left}, ahk_class Shell_TrayWnd
SetTimer, Check, 50
return
}

#IF

Check:
If !IsClassUnderMouse("Shell_TrayWnd") {
ControlSend MSTaskListWClass1, {LButton}{enter}, ahk_class Shell_TrayWnd
SetTimer, Check, Off
} return

Тоже перестаёт работать.

IsClassUnderMouse(class) {
   MouseGetPos, , , id
   WinGetClass, this_class, ahk_id %id%
   return this_class=class
}

#IF IsClassUnderMouse("Shell_TrayWnd")

WheelUp::
ControlSend MSTaskListWClass1, {Up}, ahk_class Shell_TrayWnd
SetTimer, Check, 50
return

WheelDown::
ControlSend MSTaskListWClass1, {Down}, ahk_class Shell_TrayWnd
SetTimer, Check, 50
return

#IF

Check:
If !IsClassUnderMouse("Shell_TrayWnd") {
ControlSend MSTaskListWClass1, {LButton}{enter}, ahk_class Shell_TrayWnd
SetTimer, Check, Off
} return

Но он настроен под вертикальный таскбар, для горизонтального вместо Up надо посылать Right, а вместо Down - Left.
Хотелось бы авто-определения позиции таскбара:
мне думается, что это проще всего сделать добавив WinGetPos Shell_TrayWnd определив его width и height, а затем сравнив их: если height больше width - то таскбар вертикален, если наоборот - то горизонтален.

#SingleInstance, Force
CoordMode, Mouse
VarSetCapacity(IID, 16)
NumPut(0x11CF3C3D618736E0, IID, 0, "Int64")
NumPut(0x719B3800AA000C81, IID, 8, "Int64")
DllCall("kernel32\LoadLibrary","Str","oleacc")
ControlGet, hWnd, Hwnd,, MSTaskListWClass1, ahk_class Shell_TrayWnd
ControlGet, hWnd2, Hwnd,,, ahk_class Button
ppTaskList:=COM_AccessibleObjectFromWindow(hWnd)
TaskList:=ComObjEnwrap(ppTaskList)
TCount:=GetSelection()
#If MouseIsOver()

MButton::
   If % WinID=hWnd2
      PostMessage, 0x10,,,, ahk_class Progman
   Else
      WinClose, % "ahk_id"GetTaskInfo()
   Return
WheelUp::SelectStuff(1)
WheelDown::SelectStuff(0)

GetSelection()
{
   global
   Loop, % TaskList.accChildCount
   {
      TaskList.accLocation(ComObjParameter(0x4003, &L:=0)
                         , ComObjParameter(0x4003, &T:=0)
                         , ComObjParameter(0x4003, &W:=0)
                         , ComObjParameter(0x4003, &H:=0)
                         , A_Index)
      If L=0 And T=0 And W=0 And H=0
         Continue
      If TaskList.accState(A_Index)=0x40000000
         Continue
      If TaskList.accState(A_Index)&8
         Return, A_Index
   }
}

MouseIsOver()
{
   global
   MouseGetPos, XPos, YPos, WinID, WinControl
   WinGetClass, WinClass, % "ahk_id"WinID
   Return, % WinClass="Shell_TrayWnd"
         And WinControl="MSTaskListWClass1"
          Or WinID=hWnd2 ? True:False
}

GetTaskInfo()
{
   global
   TWinID:=
   Loop, % TaskList.accChildCount
   {
      TWinTitle:=TaskList.accName(A_Index)
      TaskList.accLocation(ComObjParameter(0x4003, &L:=0)
                         , ComObjParameter(0x4003, &T:=0)
                         , ComObjParameter(0x4003, &W:=0)
                         , ComObjParameter(0x4003, &H:=0)
                         , A_Index)
      If L=0 And T=0 And W=0 And H=0
         Continue
      TWinID:=
      WinGet, TWinID, ID, % TWinTitle
      WinGetPos, TWinX, TWinY, TWinW, TWinH, % "ahk_id"TWinID
      TIconLEFTAbs:=NumGet(L), TIconTOPAbs:=NumGet(T)
      TIconWidth:=NumGet(W), TIconHeight:=NumGet(H)
      If RContains(TIconLEFTAbs, TIconTOPAbs
                  , TIconWidth, TIconHeight
                  , XPos, YPos)
         Break
      Else
         TWinID:=
   }
   Return, TWinID
}

SelectStuff(Dir)
{
   global
   If (TCount=2 And Dir=1)
   Or (TCount=TaskList.accChildCount And Dir=0)
   {
      TrayTip,, % "достигнут "
   . (Dir=1 ? "верхний":"нижний")
           . " край списка икон"
      Return
   }
   Sleep, 300
   If Dir=0
      TCount++
   Else
      TCount--
   If TCount>TaskList.accChildCount
      TCount:=TaskList.accChildCount
   If TCount<2
      TCount:=2
   State:=TaskList.accState(TCount)
   TaskList.accLocation(ComObjParameter(0x4003, &L:=0)
                      , ComObjParameter(0x4003, &T:=0)
                      , ComObjParameter(0x4003, &W:=0)
                      , ComObjParameter(0x4003, &H:=0)
                      , TCount)
   If !L And !T And !W And !H
   {
      If Dir=0
         TCount++
      Else
         TCount--
      If TCount>TaskList.accChildCount
         TCount:=TaskList.accChildCount
      Else If TCount<2
         TCount:=2
   }
   acc_Select(ppTaskList, TCount, 3)
   TaskList.accDoDefaultAction(TCount)
}

COM_AccessibleObjectFromWindow(Hwnd)
{
   global
   DllCall("oleacc\AccessibleObjectFromWindow", "Ptr", Hwnd
                                              , "UInt", -4
                                              , "Ptr", &IID
                                              , "Ptr*", ppValueObject)
   Return, ppValueObject
}

acc_Select(pacc, idChild=0, nFlags=3)
{
   Return, DllCall(NumGet(NumGet(1*pacc)+84), "UInt", pacc
                                            , "Int", nFlags
                                            , "Int64", 3
                                            , "Int64", idChild)
}

RContains(X, Y, W, H, CX, CY)
{
   Return, ((((X<=CX) And (CX<(X+W))) And (Y<=CY)) AND (CY<(Y+H)))
}

Скрипт корректно не работает с группированными окнами.

P.S.: Вы меня извините, но далее я эту тему разрабатывать не буду.

Вот иллюстрация задуманного:
Допустим, что у нас есть несколько окон, где повторяющимся будет "калькулятор" (у которого название для всех окон одинаковое, но в конце я добавил 1, 2 и 3, чтобы их отличить):
Список 1 (столбцы: Index и Title)

1. миранда
2. фаерфокс
3. ноутпад
4. гуглхром
5. калькулятор1
6. калькулятор2
7. калькулятор3

Список 2 (столбцы: Handle и Title)

0x10188 гуглхром
0x1304a2 калькулятор3
0х230c0c миранда
0x427709 фаерфокс
0x43020c калькулятор1
0xb0138 ноутпад
0xc0c3c калькулятор2

Каков будет порядок переключения окон, если мы захотим проскроллить весь список по кругу, начиная с окна ноутпада:
1. ноутпад (вызов по титулу, т.к. совпадений с другими записями нет).
2. гуглхром (вызов по титулу, т.к. совпадений с другими записями нет).
3. калькулятор (вызов по титулу не производится, т.к. есть ещё 2 совпадения. Вместо этого обращаемся ко 2-ому списку, где просто вызываем 1-ый по списку калькулятор, если список упорядочить по Handle. В нашем случае это будет "0x1304a2 калькулятор3")
4. калькулятор (вызов по титулу не производится, т.к. есть ещё 2 совпадения. Вместо этого обращаемся ко 2-ому списку, где просто вызываем 2-ой по списку калькулятор, если список упорядочить по Handle. В нашем случае это будет "0x43020c калькулятор1")
5. калькулятор (вызов по титулу не производится, т.к. есть ещё 2 совпадения. Вместо этого обращаемся ко 2-ому списку, где просто вызываем 3-ий по списку калькулятор, если список упорядочить по Handle. В нашем случае это будет "0xc0c3c калькулятор2")
6. миранда (вызов по титулу, т.к. совпадений с другими записями нет).
7. фаерфокс (вызов по титулу, т.к. совпадений с другими записями нет).

У меня в винде стоит настройка таскбара "группировать кнопки панели задач", так что для меня переключение между тремя калькуляторами будет выглядеть довольно органично, хоть и порядок их переключения будет 3-1-2 вместо 1-2-3.
Но если снять галку группировки кнопок, то такой порядок переключения окон будет выглядеть, конечно, более дико.

Или может в 1-ый скрипт можно окнам с одинаковым титулом приписывать невидимые символы, чтобы отличать одно окно от другого?

Пожалуйста, не сдавайтесь!

#NoTrayIcon
VarSetCapacity(IID, 16)
NumPut(0x11CF3C3D618736E0, IID, 0, "Int64")
NumPut(0x719B3800AA000C81, IID, 8, "Int64")
DllCall("kernel32\LoadLibrary", "Str", "Oleacc")
ControlGet, hWnd, Hwnd,, MSTaskListWClass1, ahk_class Shell_TrayWnd
taskList:=COM_AccessibleObjectFromWindow(hWnd)
Hotkey, Space, RedrawList
Gui, +AlwaysOnTop +ToolWindow
Gui, Add, ListView, r14 w450, Index|Title
RedrawList:
LV_Delete()
Loop, % taskList.accChildCount
  LV_Add("", A_Index, taskList.accName(A_Index))
Gui, Show,, % (!taskList.accChildCount ? "Nothing was found!"
: ("Found: "taskList.accChildCount " window"
. (taskList.accChildCount>1 ? "s":"  ")))"                     "
. "                        Space: refresh, F5: reload, Esc: exit"
Return

COM_AccessibleObjectFromWindow(Hwnd)
{
   global
   DllCall("Oleacc\AccessibleObjectFromWindow", "Ptr", Hwnd
                                              , "UInt", -4
                                              , "Ptr", &IID
                                              , "Ptr*", ppvObject)
   Return, ComObjEnwrap(ppvObject)
}

F5::Reload
Esc::
GuiClose:
   ExitApp

Вроде всё в порядке, все полученные названия икон приложений располагаются в списке согласно порядку, в каком они располагаются на панели задач, не взирая, на то, что каждое приложение в списке представлено двумя строками записи, можно пробовать активировать окно по его названию, пропуская строку которая похожа на название процесса, но!, опять-таки к примеру, если имеется два/три/много запущенных экземпляров того же Notepad, или Calculator (первый запущенный экземпляр которого в отличии от блокнота/любого другого приложения имеет две строки с одинаковым названием)?, на лицо проблема в виде не возможности получения дескрипторов окон (лично хотел-бы спросить у Стива Балмера, почему отсуствуют эти самые дескрипторы ). Можно получить список приложений другим путём, с дескрипторами, но в том списке не будет порядка соответствующего расположению икон приложений на панели задач:

;DetectHiddenWindows, On
#NoTrayIcon
Gui, +AlwaysOnTop -MinimizeBox +ToolWindow HwndGUIhWnd
Gui, Add, ListView, w450 h259, Index|Handle        |Title
ArrayID:=[]
WinGet, ListID, List,,, Running Applications
Loop, % ListID
{
   IDs:=ListID%A_Index%
   WinGetTitle, WinTitle, % "ahk_id"IDs
   If !WinTitle
   {
      Counter++
      Continue
   }
   ArrayID.Insert(IDs)
}
Gui, Show,, % (!ListID ? "Nothing was found!"
: ("Found all: "ListID " window"(ListID>1 ? "s":"  ")))
. ", with title: "ListID-Counter "                "
. "                           F5: reload, Esc: exit"
For Key, Value In ArrayID
{
   WinGetTitle, WinTitle, % "ahk_id"Value
   LV_Add("", Key, Value, WinTitle)
}
Return

F5::Reload
Esc::
GuiClose:
   ExitApp