Серый форум — AHK: Тип данных

Re: AHK: Тип данных

null@example.com (YMP) — Sun, 29 Dec 2013 11:28:27 +0000

Так мало ли ему участков выделено. Тут один человек уже поднимал тему про карту памяти процесса. Я лично этим вопросом не занимался.

Re: AHK: Тип данных

null@example.com (Next) — Sun, 29 Dec 2013 07:44:36 +0000

YMP пишет:

Нет, у каждого процесса своё пространство адресов (виртуальных). Как они проецируются на реальные адреса, значения не имеет, т.к. приложения с реальными адресами не работают.

А можно, также как и базовый адрес найти быстро и сразу границы выделенного приложению участка памяти, а заодно ещё и читаемые и не читаемые участки в этих границах?

Re: AHK: Тип данных

null@example.com (Next) — Wed, 27 Nov 2013 14:09:16 +0000

Меня сбило

В качестве DllName укажите имя самого процесса.

Работает, спасибо.

Re: AHK: Тип данных

null@example.com (YMP) — Wed, 27 Nov 2013 12:48:38 +0000

Вот этот код (целиком и безо всяких изменений) у вас работает?

SetFormat, Integer, Hex
ProcessName := "opera.exe"
addr := ProcGetDllBase(ProcessName, ProcessName)
MsgBox, % addr

ProcGetDllBase(Process, DllName)    ; Process = PID or Name.
{
    static StructSize, AddrOffset, NameOffset, MODULEENTRY32
    static FLAGS := 0x18        ; TH32CS_SNAPMODULE | TH32CS_SNAPMODULE32
    static INVALID_HANDLE_VALUE := -1
    If (!StructSize) {
        If (A_PtrSize = 8)
            StructSize := 1080, AddrOffset := 24, NameOffset := 48
        Else
            StructSize := 1064, AddrOffset := 20, NameOffset := 32
        VarSetCapacity(MODULEENTRY32, StructSize, 0)
        NumPut(StructSize, MODULEENTRY32, 0, "uint")
    }
    Process, Exist, %Process%
    If (ErrorLevel = 0)
        Return 0

    snapMod := DllCall("CreateToolhelp32Snapshot", "uint", FLAGS
                                                 , "uint", ErrorLevel
                                                 , "ptr")
    If (snapMod = INVALID_HANDLE_VALUE) {
        Return 0
    }

    If DllCall("Module32FirstW", "ptr", snapMod, "ptr", &MODULEENTRY32)
    {
        pszModule := &MODULEENTRY32 + NameOffset
        If DllCall("lstrcmpiW", "wstr", DllName, "ptr", pszModule) = 0
        {
            DllCall("CloseHandle", "ptr", snapMod)
            Return NumGet(MODULEENTRY32, AddrOffset, "ptr")
        }

        While DllCall("Module32NextW", "ptr", snapMod, "ptr", &MODULEENTRY32)
        {
            If DllCall("lstrcmpiW", "wstr", DllName, "ptr", pszModule) = 0
            {
                DllCall("CloseHandle", "ptr", snapMod)
                Return NumGet(MODULEENTRY32, AddrOffset, "ptr")
            }
        }
    }
    DllCall("CloseHandle", "ptr", snapMod)
    Return 0
}

Re: AHK: Тип данных

null@example.com (YMP) — Wed, 27 Nov 2013 12:41:58 +0000

Не надо ничего менять в функции. Зачем вы это делаете? Имя второго параметра (DllName) используется в коде функции, а вы это имя меняете на что-то левое. Естественно, получается левый результат.

Примечание говорит о том, что параметр Process может быть именем процесса или его PID. Ко второму параметру это не относится. Там может быть только имя.

Re: AHK: Тип данных

null@example.com (Next) — Wed, 27 Nov 2013 12:23:50 +0000

Изменил начало

ProcessName := "opera.exe"
ProcGetDllBase(Process, ProcessName)    ; Process = PID or Name.

Результат тот же. Какое имя вы имеете ввиду? И что тогда говорит примечание?

Re: AHK: Тип данных

null@example.com (YMP) — Wed, 27 Nov 2013 12:18:00 +0000

Next пишет:

Не понимаю. Приложений много, все грузятся на свободные места в памяти. Как может быть один адрес для нескольких при приложений?

Нет, у каждого процесса своё пространство адресов (виртуальных). Как они проецируются на реальные адреса, значения не имеет, т.к. приложения с реальными адресами не работают.

Выдаёт "30". В чём может быть ошибка?

Наверно, в том, что вы меняете код, не понимая, что делаете. Второй параметр функции — имя, а не PID.

Re: AHK: Тип данных

null@example.com (Next) — Wed, 27 Nov 2013 11:15:09 +0000

YMP пишет:

Стандартный адрес 0x400000.

Не понимаю. Приложений много, все грузятся на свободные места в памяти. Как может быть один адрес для нескольких при приложений?

Если подозреваете, что у процесса он нестандартный

Всегда разный базовый адрес.

Попробовал с броузером Opera х32. Базовый получился 0x00DF0000

ProcessName := "opera.exe"
Process, Exist, %ProcessName%
PID := ErrorLevel


ProcGetDllBase(Process, PID)    ; Process = PID or Name.
{
    static StructSize, AddrOffset, NameOffset, MODULEENTRY32
    static FLAGS := 0x18        ; TH32CS_SNAPMODULE | TH32CS_SNAPMODULE32
    static INVALID_HANDLE_VALUE := -1
    If (!StructSize) {
        If (A_PtrSize = 8)
            StructSize := 1080, AddrOffset := 24, NameOffset := 48
        Else
            StructSize := 1064, AddrOffset := 20, NameOffset := 32
        VarSetCapacity(MODULEENTRY32, StructSize, 0)
        NumPut(StructSize, MODULEENTRY32, 0, "uint")
    }
    Process, Exist, %Process%
    If (ErrorLevel = 0)
        Return 10

    snapMod := DllCall("CreateToolhelp32Snapshot", "uint", FLAGS
                                                 , "uint", ErrorLevel
                                                 , "ptr")
    If (snapMod = INVALID_HANDLE_VALUE) {
        Return 20
    }

    If DllCall("Module32FirstW", "ptr", snapMod, "ptr", &MODULEENTRY32)
    {
        pszModule := &MODULEENTRY32 + NameOffset
        If DllCall("lstrcmpiW", "wstr", DllName, "ptr", pszModule) = 0
        {
            DllCall("CloseHandle", "ptr", snapMod)
            Return NumGet(MODULEENTRY32, AddrOffset, "ptr")
        }

        While DllCall("Module32NextW", "ptr", snapMod, "ptr", &MODULEENTRY32)
        {
            If DllCall("lstrcmpiW", "wstr", DllName, "ptr", pszModule) = 0
            {
                DllCall("CloseHandle", "ptr", snapMod)
                Return NumGet(MODULEENTRY32, AddrOffset, "ptr")
            }
        }
    }
    DllCall("CloseHandle", "ptr", snapMod)
    Return 30
}
    
    
addr := ProcGetDllBase("opera.exe", "opera.exe")
MsgBox, %addr%  
    
Exit

Выдаёт "30". В чём может быть ошибка?

Re: AHK: Тип данных

null@example.com (YMP) — Wed, 27 Nov 2013 08:56:49 +0000

Стандартный адрес 0x400000. Если подозреваете, что у процесса он нестандартный, попробуйте посмотреть вот этой функцией. В качестве DllName укажите имя самого процесса. Т.е., например:


addr := ProcGetDllBase("notepad.exe", "notepad.exe")

Если процесс 64-битный, скрипт нужно запускать в АНК 64. Если вернёт 0, значит, какая-то ошибка.


ProcGetDllBase(Process, DllName)    ; Process = PID or Name.
{
    static StructSize, AddrOffset, NameOffset, MODULEENTRY32
    static FLAGS := 0x18        ; TH32CS_SNAPMODULE | TH32CS_SNAPMODULE32
    static INVALID_HANDLE_VALUE := -1
    If (!StructSize) {
        If (A_PtrSize = 8)
            StructSize := 1080, AddrOffset := 24, NameOffset := 48
        Else
            StructSize := 1064, AddrOffset := 20, NameOffset := 32
        VarSetCapacity(MODULEENTRY32, StructSize, 0)
        NumPut(StructSize, MODULEENTRY32, 0, "uint")
    }
    Process, Exist, %Process%
    If (ErrorLevel = 0)
        Return 0

    snapMod := DllCall("CreateToolhelp32Snapshot", "uint", FLAGS
                                                 , "uint", ErrorLevel
                                                 , "ptr")
    If (snapMod = INVALID_HANDLE_VALUE) {
        Return 0
    }

    If DllCall("Module32FirstW", "ptr", snapMod, "ptr", &MODULEENTRY32)
    {
        pszModule := &MODULEENTRY32 + NameOffset
        If DllCall("lstrcmpiW", "wstr", DllName, "ptr", pszModule) = 0
        {
            DllCall("CloseHandle", "ptr", snapMod)
            Return NumGet(MODULEENTRY32, AddrOffset, "ptr")
        }

        While DllCall("Module32NextW", "ptr", snapMod, "ptr", &MODULEENTRY32)
        {
            If DllCall("lstrcmpiW", "wstr", DllName, "ptr", pszModule) = 0
            {
                DllCall("CloseHandle", "ptr", snapMod)
                Return NumGet(MODULEENTRY32, AddrOffset, "ptr")
            }
        }
    }
    DllCall("CloseHandle", "ptr", snapMod)
    Return 0
}

Re: AHK: Тип данных

null@example.com (Next) — Tue, 26 Nov 2013 17:51:19 +0000

У меня есть адрес ячейки памяти, но на самом деле это не абсолютный адрес, а относительный "имя_процесса + 0x0002000". Мне нужно получить значение из этого адреса, для этого нужно узнать начальный или "базовый" адрес. Это адрес с которого этот процесс загружен в память. Если он 0x00F00000, то нужный мне будет 0x00F20000. В первом сообщении как раз и говорится о "базовом адресе". Как узнать этот "базовый" адрес?

Re: AHK: Тип данных

null@example.com (Alectric) — Tue, 26 Nov 2013 17:13:08 +0000

Next пишет:

А как определить адрес с которого процесс загружен в память?

Непонял вопроса...

Re: AHK: Тип данных

null@example.com (Next) — Tue, 26 Nov 2013 16:51:09 +0000

А я думал, что это вроде как "базовый адрес процесса". Почему-то же это "base" в редакторе выделяется синим? А как определить адрес с которого процесс загружен в память?

Re: AHK: Тип данных

null@example.com (Alectric) — Tue, 26 Nov 2013 15:40:31 +0000

Next пишет:

А что это "base" означает? Откуда оно берётся? Это что, какая-то системная переменная?

Это адрес по которому происходит чтение, который был указан заранее. Например base=0x36c124cd.
Просто ТС выкладывает не полный скрипт а кусками.

Re: AHK: Тип данных

null@example.com (Next) — Tue, 26 Nov 2013 09:37:45 +0000

kamaz, или кто-нибудь, ау!

Re: AHK: Тип данных

null@example.com (Next) — Mon, 25 Nov 2013 13:44:46 +0000

А что это "base" означает? Откуда оно берётся? Это что, какая-то системная переменная?