Серый форум — AHK: скрипт для ввода HTML-разметки обрамляющими тегами

Re: AHK: скрипт для ввода HTML-разметки обрамляющими тегами

null@example.com (Drugoy) — Tue, 24 Jan 2012 08:31:56 +0000

Grey,
спасибо!

Re: AHK: скрипт для ввода HTML-разметки обрамляющими тегами

null@example.com (Grey) — Tue, 24 Jan 2012 02:20:22 +0000

#IfWinActive, ahk_group MyGroup
GroupAdd, MyGroup, ahk_class MozillaWindowClass
GroupAdd, MyGroup, ahk_class Chrome_WidgetWin_0
GroupAdd, MyGroup, ahk_class IEFrame

^vk42:: ; ctrl+b
^vk49:: ; ctrl+i
^vk55:: ; ctrl+u
   If SubStr(A_ThisHotkey, 2)="vk42"
      Tag:="b"
   If SubStr(A_ThisHotkey, 2)="vk49"
      Tag:="i"
   If SubStr(A_ThisHotkey, 2)="vk55"
      Tag:="u"
   TagLength:=StrLen(Tag)
   ClipContent:=ClipboardAll
   Send, ^{Ins}
   Length:=StrLen(Clipboard)
   Send, % "{BS}["Tag "]+{Ins}[/"Tag "]"
   Clipboard:=ClipContent
   IsTagged:=True
   Return

^$vk5A:: ; ctrl+z
   If !IsTagged
      Send, ^{vk5A}
   Else
   {
      IfWinActive, ahk_class MozillaWindowClass
         Send, % "^{vk5A 4}{Left "Length "}"
      IfWinActive, ahk_class IEFrame
         Send, % "^{vk5A}{Left "Length "}"
      IfWinActive, ahk_class Chrome_WidgetWin_0
         Send, % "{BS "TagLength+3 "}"
             . "{Left "Length "}{BS "TagLength+2 "}"
      IsTagged:=False
   }
   Return

Re: AHK: скрипт для ввода HTML-разметки обрамляющими тегами

null@example.com (Drugoy) — Mon, 23 Jan 2012 02:42:27 +0000

Grey,
спасибо, а как помимо ctrl+b добавить и ctrl+u и ctrl+i?

Re: AHK: скрипт для ввода HTML-разметки обрамляющими тегами

null@example.com (Grey) — Mon, 23 Jan 2012 01:41:40 +0000

#IfWinActive, ahk_group MyGroup
GroupAdd, MyGroup, ahk_class MozillaWindowClass
GroupAdd, MyGroup, ahk_class Chrome_WidgetWin_0
GroupAdd, MyGroup, ahk_class IEFrame
TagLength:=StrLen(Tag:="b")

^vk42:: ; ctrl+b
   ClipContent:=ClipboardAll
   Send, ^{Ins}
   Length:=StrLen(Clipboard)
   Send, % "{BS}["Tag "]+{Ins}[/"Tag "]"
   Clipboard:=ClipContent
   IsTagged:=True
   Return

^$vk5A:: ; ctrl+z
   If !IsTagged
      Send, ^{vk5A}
   Else
   {
      IfWinActive, ahk_class MozillaWindowClass
         Send, % "^{vk5A 4}{Left "Length "}"
      IfWinActive, ahk_class IEFrame
         Send, % "^{vk5A}{Left "Length "}"
      IfWinActive, ahk_class Chrome_WidgetWin_0
         Send, % "{BS "TagLength+3 "}"
             . "{Left "Length "}{BS "TagLength+2 "}"
      IsTagged:=False
   }
   Return

Re: AHK: скрипт для ввода HTML-разметки обрамляющими тегами

null@example.com (creature.ws) — Sun, 22 Jan 2012 18:10:08 +0000

Замечательно официальный форум оказался более дружелюбен.

Re: AHK: скрипт для ввода HTML-разметки обрамляющими тегами

null@example.com (Drugoy) — Sun, 22 Jan 2012 17:55:26 +0000

creature.ws пишет:

А какие отличия должны быть подчеркнуты в описании?
IfWinActive — команда, WinActive() — функция, #IfWinActive — директива.
#IfWinActive, IfWinActive ::en.
Действия по условию If WinActive("ahk_class MozillaWindowClass") or WinActive("ahk_class Chrome_WidgetWin_0") выполнятся в случае если активно окно с классом MozillaWindowClass или Chrome_WidgetWin_0.
Добавить к этому нечего.

Ну вот не работает оно. Не знаю почему. У Notepad++ класс явно другой (я даже проверил), но хоткеи срабатывают и в нём.
В принципе вопрос решил:

GroupAdd, Browsers, ahk_class MozillaWindowClass
GroupAdd, Browsers, ahk_class Chrome_WidgetWin_0
GroupAdd, Browsers, ahk_class IEFrame

#IfWinActive ahk_group browsers
!sc030::Wrap("b") ; Alt+B
!sc016::Wrap("u") ; Alt+U
!sc017::Wrap("i") ; Alt+I


Wrap(tag)
   {
    OldClipboard := Clipboard
    send, ^{vk43} ; Ctrl+C
    Sleep, 10
    Clipboard := "[" tag "]" . Clipboard . "[/" tag "]"
    send, ^{vk56} ; Ctrl+V
    Clipboard := OldClipboard
	return
    }
	return

Re: AHK: скрипт для ввода HTML-разметки обрамляющими тегами

null@example.com (creature.ws) — Sun, 22 Jan 2012 17:27:05 +0000

А какие отличия должны быть подчеркнуты в описании?
IfWinActive — команда, WinActive() — функция, #IfWinActive — директива.
#IfWinActive, IfWinActive ::en.
Действия по условию If WinActive("ahk_class MozillaWindowClass") or WinActive("ahk_class Chrome_WidgetWin_0") выполнятся в случае если активно окно с классом MozillaWindowClass или Chrome_WidgetWin_0.
Добавить к этому нечего.

Re: AHK: скрипт для ввода HTML-разметки обрамляющими тегами

null@example.com (Drugoy) — Sun, 22 Jan 2012 17:12:48 +0000

creature.ws пишет:

1. По ссылке синтаксис команды описан, в переборе вариантов нет необходимости.
If WinActive("ahk_class MozillaWindowClass") or WinActive("ahk_class Chrome_WidgetWin_0")

И в таком случае - срабатывает и в notepad++.
Синтаксис описан так, что без примеров использования - мне ничего не понятно. На мой взгляд там всё очень запутано:
не описана разница между IfWinActive, If WinActive и #IfWinActive.
А примеров там мало (нет примера если нужно указать не одну проверку, а несколько).

Re: AHK: скрипт для ввода HTML-разметки обрамляющими тегами

null@example.com (creature.ws) — Sun, 22 Jan 2012 16:59:08 +0000

1. По ссылке синтаксис команды описан, в переборе вариантов нет необходимости.

If WinActive("ahk_class MozillaWindowClass") or WinActive("ahk_class Chrome_WidgetWin_0")

2. Замечательно, поддерживаю.

Re: AHK: скрипт для ввода HTML-разметки обрамляющими тегами

null@example.com (Drugoy) — Sun, 22 Jan 2012 16:51:37 +0000

Я не очень в AHK разбираюсь и мне нужна более детальная помощь:
1.

If WinActive("ahk_class MozillaWindowClass") or ("ahk_class Chrome_WidgetWin_0")

также как и

IfWinActive, ("ahk_class MozillaWindowClass") or ("ahk_class Chrome_WidgetWin_0")

и также как и

IfWinActive, ("MozillaWindowClass|Chrome_WidgetWin_0")

работает и в Notepad++ почему-то.
2. Предлагаю такую:

   OldClipboard := Clipboard
...
произвести действия:
копировать выделенный текст
обрамить его тэгами
вставить уже обрамлённый тегами текст (попутно решив проблему 2.Б.)
...
   Clipboard := OldClipboard

Re: AHK: скрипт для ввода HTML-разметки обрамляющими тегами

null@example.com (creature.ws) — Sun, 22 Jan 2012 16:18:19 +0000

1. IfWinActive
2. Предложите концепцию, как получить текст из окна FIrefox, Chrome, IE не используя буфер обмена.
A. Clipboard
B. Однократным нажатием ctrl+z отменить можно именно вставку.

AHK: скрипт для ввода HTML-разметки обрамляющими тегами

null@example.com (Drugoy) — Sun, 22 Jan 2012 15:38:22 +0000

Cкрипт для ввода HTML-разметки обрамляющими тегами
Как его изменить следующим образом?
1. Сделать чтобы срабатывал только в окнах с указанными классами MozillaWindowClass, Chrome_WidgetWin_0 и IEFrame.
2. Желательно изменить подход в скрипте таким образом, чтобы он работал не через копировать-вставить, т.к.:
А. в буфере обмена в этот момент может быть что-то полезное, что будет утрачено
Б. невозможно отменить обрамление тегами однократным нажатием CTRL+Z: требуется 4 нажатия вместо 1.