Серый форум — VBS: Ожидание данных из COM порта

Re: VBS: Ожидание данных из COM порта

null@example.com (MSTos) — Sun, 12 Apr 2015 20:31:49 +0000

Доброго времени суток.
Искал информацию по ошибкам с ком портов и попал к вам на страницу...
Себе инфу не нашел, но помочь с вашими проблемами могу...
я подключал весы через ком порт. тоже опрос портов, тоже висла система....
у меня были весы, которые должны были отправлять инфу на ком порт после получения команды от ком порта....
отправлял, и ждал получения.... иногда даже получал...
а потом разобрался в проблеме...
1. все события получения инфы с ком порта должны генерироваться в :

Private Sub MSComm_OnComm()
    A = MSComm.Input
    MsgBox "Наш порт прислал следующую строку = " & A
End Sub

Зацикливать что либо и постоянно опрашивать порт - не метод!!
С таким успехом можно просто ставить бесконечный цикл и просто ничего не делать в нем...

2. для такого события должны быть наcтройки....


With MSComm
    .Settings = "9600,n,8,1" ' скорость, четность, бит, что то там еще (не помню толком)
    .CommPort = 2                ' назначеный порт
    .Handshaking = comNone 'генерировать событие при получение инфы с ком порта в Sub MSComm_OnComm()
    .InputLen = 0                    ' длина получаемой строки с ком порта, если = 0 - значит без ограничений
    .PortOpen = True              ' ну и собственно открытие порта
End With

более конкретно расписаны все настройки на сайте Firststeps.ru в разделе Visual Basic

Надеюсь кому - то поможет.
Извините если нарушил правила форума, здесь впервые и просто решил помочь.
кроме того я не скриптовик - пишу на VB и VBA.

Re: VBS: Ожидание данных из COM порта

null@example.com (Mat Skywalker) — Mon, 06 Feb 2012 01:37:09 +0000

Не помогает. Событие не приходит.


Private Sub MSComm_OnComm()

Не отрабатывает. Пробую сделать тоже самое из HTA, тот же результат. 50% загрузка проца.


On Error Resume Next
set WshShell = CreateObject("WScript.Shell")
Set scan = CreateObject("MSCOMMLib.MSComm")
Set objArgs = WScript.Arguments
For I = 0 to objArgs.Count - 1
  Comand=objArgs(I)
Next
    If (scan Is Nothing) Then 
        MsgBox "Компонента не установлена",  vbCritical
    End If
scan.Settings = "9600,n,8,1"
if Comand ="" then 
scan.CommPort = 2
Else 
scan.CommPort =  Comand
End If
scan.PortOpen = True
scan.InputLen = 0
While 1
if scan.InBufferCount>0 then 
call listen
scan.PortOpen = True
End if
If Err.Number <> 0 Then
    MsgBox "Так не пойдет. Описание ошибки: "& Err.Description, vbCritical
	wscript.quit
Else
    On Error GoTo 0
End If
WScript.Sleep 10
Wend

sub listen()
Do Until len(bcod)=15
bcod=bcod+scan.Input
loop
bcod=trim(Right(bcod, Len(bcod)-1))
WshShell.SendKeys "{F12}"+bcod+"{ENTER}"
bcod=""
scan.PortOpen = False
scan.InputLen = 0
End sub

Остановился на таком варианте, он грузит проц только 1-2 сек, в момент считывания штрих-кода.

Re: VBS: Ожидание данных из COM порта

null@example.com (alexii) — Fri, 03 Feb 2012 10:01:07 +0000

Использовать либо форму:

WScript.CreateObject(strProgID, strPrefix)

либо форму:

WScript.ConnectObject(objEventSource, strPrefix)

где «strPrefix» — префикс процедур обработки событий.

CreateObject Method
ConnectObject Method

Sesame Script: Getting - or Creating - an Object

Пример использования на форуме.

Re: VBS: Ожидание данных из COM порта

null@example.com (Xameleon) — Fri, 03 Feb 2012 09:52:18 +0000

Не уверен, что правильно написал, т.к потестировать не на чем. Но как то так. А дальше в событии обрабатывать сами данные через Input


Option Explicit
Dim MSComm
Set MSComm = WScript.CreateObject("MSCOMMLib.MSComm","MSComm_")
With MSComm
    .Settings = "9600,n,8,1"
    .CommPort = 2
    .PortOpen = True
End With

Private Sub MSComm_OnComm()
    MsgBox "EVENT !"
End Sub

Do
    WScript.Sleep 10
Loop

Re: VBS: Ожидание данных из COM порта

null@example.com (Mat Skywalker) — Fri, 03 Feb 2012 09:35:26 +0000

Нет, а это как?

Re: VBS: Ожидание данных из COM порта

null@example.com (alexii) — Fri, 03 Feb 2012 04:19:49 +0000

Mat Skywalker, на события подписались при создании объекта?

Re: VBS: Ожидание данных из COM порта

null@example.com (Mat Skywalker) — Fri, 03 Feb 2012 01:36:34 +0000

Пока что ничего не помогает, даже это:


...
While 1
 If (scan.CommEvent <>0) Then call listen 'Ждем данных с порта
If Err.Number <> 0 Then
    MsgBox "Так не пойдет. Описание ошибки: "& Err.Description, vbCritical
	wscript.quit
Else
    On Error GoTo 0
End If
Wend
...

И вообще CommEvent всегда 0

Re: VBS: Ожидание данных из COM порта

null@example.com (alexii) — Fri, 03 Feb 2012 01:14:09 +0000

Примеры здесь: MSComm Control (MSComm Control) смотрели? Может такое сгодится?

OFF:

но грузит проц на 50% А если их запустить 2 то на 100%. Вопрос, что можно сделать…

Добавить ядер на процессоре ?

Re: VBS: Ожидание данных из COM порта

null@example.com (Евген) — Thu, 02 Feb 2012 16:57:38 +0000

wscript.sleep 100

не поможет ?

Do Until len(bcod)=14 ' Именно эта часть вызывает загрузку процессора
bcod=bcod+scan.Input
wscript.sleep 100
loop

Не ?

VBS: Ожидание данных из COM порта

null@example.com (Mat Skywalker) — Thu, 02 Feb 2012 16:39:50 +0000

Написал скрипт для перехвата данных из COM порта и пересылке их на кнопки. Нужно это для того, чтобы сканеры штрих-кодов COM портовые работали как клавиатурные.
Скрипт вполне работоспособен, но грузит проц на 50% А если их запустить 2 то на 100%.
Вопрос, что можно сделать, чтобы он не был столь ресурсоемким:


On Error Resume Next
set WshShell = CreateObject("WScript.Shell")
Set scan = CreateObject("MSCOMMLib.MSComm") ' Используется MSCOMM32.OCX
Set objArgs = WScript.Arguments
For I = 0 to objArgs.Count - 1
  Comand=objArgs(I)
Next
    If (scan Is Nothing) Then 
        MsgBox "Компонента не установлена",  vbCritical
    End If
scan.Settings = "9600,n,8,1"
if Comand ="" then 
scan.CommPort = 2 ' По умолчанию слушаем 2-й порт
Else 
scan.CommPort =  Comand
End If
While 1
call listen
If Err.Number <> 0 Then 'Обработчик ошибок
    MsgBox "Так не пойдет. Описание ошибки: "& Err.Description, vbCritical
	wscript.quit
Else
    On Error GoTo 0
End If
Wend

sub listen()
scan.PortOpen = True
scan.InputLen = 0
Do Until len(bcod)=14 ' Именно эта часть вызывает загрузку процессора
bcod=bcod+scan.Input
loop
bcod=trim(Right(bcod, Len(bcod)-1))
WshShell.SendKeys "{F12}"+bcod+"{ENTER}" 'Отсылаем команду в клавиатуру с префиксом и постфиксом
bcod=""
scan.PortOpen = False
End sub

Может есть другой способ получить данные из COM порта?