<![CDATA[Серый форум — VBS: Простой способ декодирования base64]]> https://forum.script-coding.com/viewtopic.php?id=6957 Tue, 10 Apr 2012 08:40:55 +0000 PunBB <![CDATA[Re: VBS: Простой способ декодирования base64]]> https://forum.script-coding.com/viewtopic.php?pid=59091#p59091 Не удержался, позволил себе немного оптимизировать код. ) Уж очень идея понравилась.


Function base64encode(data)
    With CreateObject("CDO.Message").BodyPart
        .Charset = "utf-8"
        .ContentTransferEncoding = "base64"
        With .GetDecodedContentStream
            .WriteText data
            .Flush
        End With
        With .GetEncodedContentStream
            base64encode = .ReadText(.Size - 2) 'Отрезаем перевод строки на хвосте
        End With
    End With
End Function

Function base64decode(data)
    With CreateObject("CDO.Message").BodyPart
        .ContentTransferEncoding = "base64"
        .Charset = "windows-1251"
        With .GetEncodedContentStream
            .WriteText data
            .Flush
        End With
        With .GetDecodedContentStream
            .Charset = "utf-8"
            base64decode = .ReadText
        End With
    End With
End Function
]]> Tue, 10 Apr 2012 08:40:55 +0000 https://forum.script-coding.com/viewtopic.php?pid=59091#p59091 <![CDATA[Re: VBS: Простой способ декодирования base64]]> https://forum.script-coding.com/viewtopic.php?pid=59035#p59035 Супер ! ) А я и забыл совсем что у CDO есть такая возможность !

]]> Sun, 08 Apr 2012 17:33:38 +0000 https://forum.script-coding.com/viewtopic.php?pid=59035#p59035 <![CDATA[Re: VBS: Простой способ декодирования base64]]> https://forum.script-coding.com/viewtopic.php?pid=59034#p59034 smaharbA, супер :-)

]]> Sun, 08 Apr 2012 17:33:36 +0000 https://forum.script-coding.com/viewtopic.php?pid=59034#p59034 <![CDATA[Re: VBS: Простой способ декодирования base64]]> https://forum.script-coding.com/viewtopic.php?pid=59030#p59030 
set cdo=CreateObject("CDO.Message")
set bp=cdo.BodyPart
bp.ContentTransferEncoding = "base64"
Set s=bp.GetEncodedContentStream
bp.Fields.Item("urn:schemas:mailheader:content-type").Value="text/plain; charset=""windows-1251"""
bp.Fields.Update
s.WriteText "wuDx/yDP8+/q6O0="
s.Flush
Set s = bp.GetDecodedContentStream
s.charset = "windows-1251"
msgbox s.ReadText
]]> Sun, 08 Apr 2012 14:59:00 +0000 https://forum.script-coding.com/viewtopic.php?pid=59030#p59030 <![CDATA[Re: VBS: Простой способ декодирования base64]]> https://forum.script-coding.com/viewtopic.php?pid=58518#p58518 Посмотрел. Да, видел эту статью. ) И при чём тут корректность base64 ? И что такое классический base64 ? На сколько я понимаю, он всегда классический. base64 всегда кодируется байтовые массивы. ) Я спрашивал о корректности кодируемых данных. А т.к кодируется в этом случае именно байтовый массив, то о какой корректности может быть речь ? ) А сам метод кодирования заложен в объектную модель MSXML. Поэтому его я никак нарушить не могу. В моём случае он чёрный ящик. ) Поэтому кодирование, как бы я не изголялся, будет срабатывать всегда одинаково. ) Меняется лишь интерпретация данных, с которыми мы работаем.

]]> Wed, 28 Mar 2012 17:14:53 +0000 https://forum.script-coding.com/viewtopic.php?pid=58518#p58518 <![CDATA[Re: VBS: Простой способ декодирования base64]]> https://forum.script-coding.com/viewtopic.php?pid=58517#p58517 Вообще то - да.

]]> Wed, 28 Mar 2012 16:51:38 +0000 https://forum.script-coding.com/viewtopic.php?pid=58517#p58517 <![CDATA[Re: VBS: Простой способ декодирования base64]]> https://forum.script-coding.com/viewtopic.php?pid=58481#p58481 А стандарты корректности где то определены ?

]]> Tue, 27 Mar 2012 18:29:03 +0000 https://forum.script-coding.com/viewtopic.php?pid=58481#p58481 <![CDATA[Re: VBS: Простой способ декодирования base64]]> https://forum.script-coding.com/viewtopic.php?pid=58480#p58480 2Xameleon
Наверное стоит упомянуть о том в какой кодировке конвертируется текст.
И о том, что результат резко отличается от классического base64 кодирования.
И хотя закодированный утилитой текст все таки может быть декодирован в строку utf-16le, но можно ли его считать корректным base64 кодом?

]]> Tue, 27 Mar 2012 18:17:59 +0000 https://forum.script-coding.com/viewtopic.php?pid=58480#p58480 <![CDATA[Re: VBS: Простой способ декодирования base64]]> https://forum.script-coding.com/viewtopic.php?pid=58471#p58471 Переправил код. Неправильно работали функции hexToStr и strToHex. Собрал функции в класс модуль clsEncoder. Сделал класс совместимым с HTA / WSH / WSF и т.п.

Оставил функции
encode(data, enctype) - функция кодирования byte() массива в hex / base64. enctype (0 - base64, 1-hex)
decode(data, enctype) - функция декодирования hex / base64 строки в byte() массив. enctype (0 - base64, 1-hex)
strToBin(data) - конвертация String в byte()
binToStr(data) - конвертация byte() в String
strToHex(srcstr) - кодирование String в Hex строку
hexToStr(ByVal hexstr) - декодирование Hex строки в исходный текст.

<html>
    <head>
        <title>encoder / decoder</title>
        <meta charset="windows-1251">
        <style>
        *{font-family:Tahoma;font-size:14px;}
        </style>
    </head>
    <body>
        <table width=100% height=100%>
            <tr>
                <td colspan=4>
                    Кодировщик
                    <select id="selEncoder">
                        <option value="0">base64</option>
                        <option value="1">hex</option>
                    </select>
                    <hr>
                </td>
            </tr>
            <tr>
                <td align=left>Исходные данные</td>
                <td align=right><button id="btnEncode">Encode ></button></td>
                <td align=left><button id="btnDecode">< Decode</button></td>
                <td align=right>Закодированные данные</td>
            </tr>
            <tr>
                <td colspan=2 height=100% ><textarea id="txtDecoded" style="width:100%;height:100%;"></textarea></td>
                <td colspan=2><textarea id="txtEncoded" style="width:100%;height:100%;"></textarea></td>
            </tr>
        </table>
        <script language=VBScript>
            Option Explicit
            
            Dim encoder
            Set encoder = new clsEncoder

            Sub btnEncode_onclick()
                On Error Resume Next
                Select Case selEncoder.value
                Case 0
                    txtEncoded.value = encoder.encode(encoder.strToBin(txtDecoded.value),0)
                Case 1
                    txtEncoded.value = encoder.strToHex(txtDecoded.value)
                End Select
                if Err.Number <> 0 Then MsgBox Err.Description, vbCritical, document.title
            End Sub

            Sub btnDecode_onclick()
                On Error Resume Next
                Select Case selEncoder.value
                Case 0
                    txtDecoded.value = encoder.binToStr(encoder.decode(txtEncoded.value,0))
                Case 1
                    txtDecoded.value = encoder.hexToStr(txtEncoded.value)
                End Select
                if Err.Number <> 0 Then MsgBox Err.Description, vbCritical, document.title
            End Sub

            Class clsEncoder
                Private xmldoc, encTypes
                Private Sub Class_Initialize()
                    On Error Resume Next
                    encTypes = Array("bin.base64","bin.hex")
                    if isObject(document) then 
                        Set xmldoc = document.createElement("xml")
                    Else
                        Set xmldoc = CreateObject("htmlfile").createElement("xml")
                    End if
                End Sub
                 
                Function encode(data, enctype)
                    With xmldoc.createElement("enc")
                        .dataType = encTypes(enctype)
                        .nodeTypedValue = data
                        encode = Replace(.Text,vbLf,"")
                    End With
                End Function

                Function decode(data, enctype)
                    With xmldoc.createElement("enc")
                        .dataType = encTypes(enctype)
                        .Text = data
                        decode = .nodeTypedValue
                    End With
                End Function

                Function strToBin(data)
                    With xmldoc.createElement("enc")
                        .dataType = "bin.hex"
                        .Text = strToHex(data)
                        strToBin = .nodeTypedValue
                    End With
                End Function

                Function binToStr(data)
                    With xmldoc.createElement("enc")
                        .dataType = "bin.hex"
                        .nodeTypedValue = data
                        binToStr = hexToStr(.Text)
                    End With
                End Function

                Function strToHex(srcstr)
                    Dim i: For i = 1 To LenB(srcstr)
                        strToHex = strToHex & Right("0" & Hex(AscB(MidB(srcstr, i, 1))), 2)
                    Next
                End Function

                Function hexToStr(ByVal hexstr)
                    Dim i: For i = 1 To Len(hexstr) Step 2
                        hexToStr = hexToStr & ChrB("&H" & Mid(hexstr, i, 2))
                    Next
                End Function

            End Class

        </script>
    </body>
</html>
]]> Tue, 27 Mar 2012 16:17:59 +0000 https://forum.script-coding.com/viewtopic.php?pid=58471#p58471 <![CDATA[Re: VBS: Простой способ декодирования base64]]> https://forum.script-coding.com/viewtopic.php?pid=58273#p58273 Опубликовал оба HTA приложения уважаемого Xameleon в Коллекции.
Позволил себе немного подправить код.
И если Base64EncoderDecoder.hta может пригодится искателям новых алгоритмов, то из XMLCodeTester.hta получился настоящий настольный инструмент для тестирования как кода так и установленных на машине версий MSXML.

]]> Thu, 22 Mar 2012 19:27:41 +0000 https://forum.script-coding.com/viewtopic.php?pid=58273#p58273 <![CDATA[Re: VBS: Простой способ декодирования base64]]> https://forum.script-coding.com/viewtopic.php?pid=58261#p58261 2badik
Спасибо. Получил. Проверил.
Действительно файлик прекрасно парсится с помощью MSXML 3.0, 4.0, 5.0.
C MSXML 6.0 выдает ошибку разбора.
Факт весьма печальный

]]> Thu, 22 Mar 2012 16:36:06 +0000 https://forum.script-coding.com/viewtopic.php?pid=58261#p58261 <![CDATA[Re: VBS: Простой способ декодирования base64]]> https://forum.script-coding.com/viewtopic.php?pid=58198#p58198 mozers пишет:

2badik

msxml6.dll: Ошибка разбора

А можно взглянуть на эту строку целиком?

Выслал вам на mail.ru

]]> Thu, 22 Mar 2012 05:19:59 +0000 https://forum.script-coding.com/viewtopic.php?pid=58198#p58198 <![CDATA[Re: VBS: Простой способ декодирования base64]]> https://forum.script-coding.com/viewtopic.php?pid=58156#p58156 2badik

msxml6.dll: Ошибка разбора

А можно взглянуть на эту строку целиком?

]]> Wed, 21 Mar 2012 10:23:51 +0000 https://forum.script-coding.com/viewtopic.php?pid=58156#p58156 <![CDATA[Re: VBS: Простой способ декодирования base64]]> https://forum.script-coding.com/viewtopic.php?pid=58149#p58149 Про версии парсеров:
Ошибку выдал парсер версии 6.0.
Разбор парсером версии  5.0 прошёл (раньше не проходил ?!).

msxml6.dll: Ошибка разбора ''PD94bWwgdmVyc2lvbj0iMS4wIiBlbmNvZGluZz0iV0lORE9XUy0xMjUxIj8+CjxQYWNrZXRF
UEQgeG1sbnM9InVybjpjYnItcnU6ZWQ6djIuMCIgRURObz0iND...'' как типа данных bin.base64.
код ошибки -2147467259

FIX: MSXML Does Not Parse Slash Mark Character with Base64 Encoded Data
http://support.microsoft.com/kb/301356/en-us


P.S
msxml6.dll
версия: 6.20.1076.0
название продукта: Microsoft(R) MSXML 6.0 SP2
Из реестра

Windows Registry Editor Version 5.00

[HKEY_LOCAL_MACHINE\SOFTWARE\Classes\CLSID\{88d96a05-f192-11d4-a65f-0040963251e5}\InProcServer32]
@="C:\\WINDOWS\\system32\\msxml6.dll"
"ThreadingModel"="Both"
"Class"="Microsoft.SqlServer.MSXML6.DOMDocument60Class"
"Assembly"="Microsoft.SqlServer.msxml6_interop, Version=6.0.0.0, Culture=neutral, PublicKeyToken=89845dcd8080cc91"
"RunTimeVersion"="v2.0.50727"
]]> Wed, 21 Mar 2012 06:03:41 +0000 https://forum.script-coding.com/viewtopic.php?pid=58149#p58149 <![CDATA[Re: VBS: Простой способ декодирования base64]]> https://forum.script-coding.com/viewtopic.php?pid=58141#p58141 2Xameleon
Развитие первоначальной идеи пошло совсем в другом направлении
И хотя предложенное решение "простым способом" не назовешь, однако это действительно - новинка!
Такого способа, без привлечения ADODB.Stream, или замудренных математических вычислений, с использованием только функционала XML, я (да и все присутствующие) еще не видели.
Класс!

]]> Tue, 20 Mar 2012 19:27:48 +0000 https://forum.script-coding.com/viewtopic.php?pid=58141#p58141