Серый форум — AHK: Работа скрипта AHK только в опред-ной области программы - ClassNN

Re: AHK: Работа скрипта AHK только в опред-ной области программы - ClassNN

null@example.com (ComSyntax) — Sat, 12 May 2012 18:56:01 +0000

creature.ws пишет:

Например, изменить:

Ура!!! Заработало!!!
Спасибо, добрый человек:)

Re: AHK: Работа скрипта AHK только в опред-ной области программы - ClassNN

null@example.com (creature.ws) — Sat, 12 May 2012 18:40:14 +0000

Например, изменить:

; AHK-L
#SingleInstance ignore
Run, Photoshop.exe, , Max UseErrorLevel
if ErrorLevel = ERROR
    {
    MsgBox При запуске программы Photoshop произошла ошибка. Пожалуйста, попробуйте снова.
    ExitApp
    }
WinWaitActive ahk_class Photoshop
SetTimer Check, 2000
Return
 
#If WinActive("ahk_class Photoshop") && SubWinClass()
    WheelDown::Send, {)}
    WheelUp::Send, {(}
    MButton & WheelDown:: Send, {f}
    MButton & WheelUp::Send, {n}
#if
Check:
  IfWinNotExist ahk_class Photoshop
    {
    ExitApp
    }
Return
 
SubWinClass()
{
    MouseGetPos,,,, ClassNN
    return ClassNN ~= "PSViewC3"
}

Re: AHK: Работа скрипта AHK только в опред-ной области программы - ClassNN

null@example.com (ComSyntax) — Sat, 12 May 2012 18:05:54 +0000

Протестировал скрипт, всё работает пока открыта только одна вкладка в фотошопе, потом нет. Оказалось что значение "PSViewC33" изменяется при открытие последующих вкладок. Например, если открыта только одна вкладка, то значением рабочей области фотошопа будет являться "PSViewC33", если два, то "PSViewC34", если три, то "PSViewC35" и т. д. Как быть?

Re: AHK: Работа скрипта AHK только в опред-ной области программы - ClassNN

null@example.com (ComSyntax) — Fri, 11 May 2012 15:22:40 +0000

Обе версии работают!!!
Благодарю Вас:)

Re: AHK: Работа скрипта AHK только в опред-ной области программы - ClassNN

null@example.com (Irbis) — Fri, 11 May 2012 15:16:39 +0000

Немного опередил

#SingleInstance ignore
Run, Photoshop.exe, , Max UseErrorLevel
if ErrorLevel = ERROR
    {
    MsgBox При запуске программы Photoshop произошла ошибка. Пожалуйста, попробуйте снова.
    ExitApp
    }
WinWaitActive ahk_class Photoshop
SetTimer Check, 2000
Return

#IfWinActive ahk_class Photoshop
WheelDown:: Send % ok() ? "{)}" : "{click WD}"
WheelUp:: Send % ok() ? "{(}" : "{click WU}"
MButton & WheelDown:: Send  % ok() ? "{f}" : "{click M down}{click WD}{click M up}"
MButton & WheelUp:: Send  % ok() ? "{n}" : "{click M down}{click WU}{click M up}"
#IfWinActive

ok()
{
   MouseGetPos,,,,ctrl
   return (ctrl = "PSViewC33")
}

Check:
  IfWinNotExist ahk_class Photoshop
    ExitApp
Return

Re: AHK: Работа скрипта AHK только в опред-ной области программы - ClassNN

null@example.com (creature.ws) — Fri, 11 May 2012 15:06:31 +0000


; AHK-L
#SingleInstance ignore
Run, Photoshop.exe, , Max UseErrorLevel
if ErrorLevel = ERROR
    {
    MsgBox При запуске программы Photoshop произошла ошибка. Пожалуйста, попробуйте снова.
    ExitApp
    }
WinWaitActive ahk_class Photoshop
SetTimer Check, 2000
Return

#If WinActive("ahk_class Photoshop") && SubWinClass("PSViewC33")
    WheelDown::Send, {)}
    WheelUp::Send, {(}
    MButton & WheelDown:: Send, {f}
    MButton & WheelUp::Send, {n}
#if
Check:
  IfWinNotExist ahk_class Photoshop
    {
    ExitApp
    }
Return

SubWinClass(nClassNN)
{
    MouseGetPos,,,, cClassNN
    return cClassNN == nClassNN
}

AHK: Работа скрипта AHK только в опред-ной области программы - ClassNN

null@example.com (ComSyntax) — Fri, 11 May 2012 14:47:48 +0000

Подскажите пожалуйста, какие изменения/дополнения следует ввести в ниже приведенный скрипт, чтобы скомпилированная программа на AHK действовала не по всей области Фотошопа, а только в определенной ее области?
А именно в области ClassNN: PSViewC33.
Данные из Window Spy:

>>>>>>>>>( Now Under Mouse Cursor )<<<<<<<<
ClassNN: PSViewC33
Text:
Color:
>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<

Скрипт:

#SingleInstance ignore
Run, Photoshop.exe, , Max UseErrorLevel
if ErrorLevel = ERROR
    {
    MsgBox При запуске программы Photoshop произошла ошибка. Пожалуйста, попробуйте снова.
    ExitApp
    }
WinWaitActive ahk_class Photoshop
SetTimer Check, 2000
Return

#IfWinActive ahk_class Photoshop
WheelDown::Send, {)} 
WheelUp::Send, {(} 
MButton & WheelDown:: Send, {f}
MButton & WheelUp::Send, {n}

Check:
  IfWinNotExist ahk_class Photoshop
    {  
    ExitApp
    } 
Return

Заранее всех благодарю.