Option Explicit
Dim strComputer
Dim objSWbemLocator
Dim objSWbemServicesEx
Dim objSWbemObjectEx_Win32_Volume
Dim objSWbemObjectEx_Win32_DefragAnalysis
Dim boolDefragRecommended
strComputer = "."
Set objSWbemLocator = WScript.CreateObject("WbemScripting.SWbemLocator")
Set objSWbemServicesEx = objSWbemLocator.ConnectServer(strComputer, "root\cimv2")
For Each objSWbemObjectEx_Win32_Volume In objSWbemServicesEx.InstancesOf("Win32_Volume")
With objSWbemObjectEx_Win32_Volume
WScript.Echo "-----------------------------------"
WScript.Echo "Drive:", .DriveLetter, "(" & .Label & ") [" & .DeviceID & "]"
WScript.Echo "-----------------------------------"
WScript.Echo "Serial number: ", Left(Hex(.SerialNumber), 4) & "-" & Right(Hex(.SerialNumber), 4)
WScript.Echo "Volume automount/boot/system:", Array("Yes", "No")(Abs(Not .Automount)) & "/" & Array("Yes", "No")(Abs(Not .BootVolume)) & "/" & Array("Yes", "No")(Abs(Not .SystemVolume))
WScript.Echo "Size total/free (% usage): ", FormatNumber(.Capacity / (2 ^ 30), 1) & " Gb/" & FormatNumber(.FreeSpace / (2 ^ 30), 1) & " Gb (" & FormatPercent((.Capacity - .FreeSpace) / .Capacity, 1) & ")"
WScript.Echo "Drive type (File system): ", Array("Unknown", "No Root Directory", "Removable Disk", "Local Disk", "Network Drive", "Compact Disk", "RAM Disk")(.DriveType) & " (" & .FileSystem & ")"
If .DefragAnalysis(boolDefragRecommended, objSWbemObjectEx_Win32_DefragAnalysis) = 0 Then
WScript.Echo "Block size/Cluster size: ", .BlockSize & " b/" & objSWbemObjectEx_Win32_DefragAnalysis.ClusterSize & " b"
End If
Set objSWbemObjectEx_Win32_DefragAnalysis = Nothing
WScript.Echo "-----------------------------------"
WScript.Echo
End With
Next
Set objSWbemServicesEx = Nothing
Set objSWbemLocator = Nothing
WScript.Quit 0
В моём случае свойство «.BlockSize» класса «Win32_Volume» всегда оказывалось равным свойству «.ClusterSize» класса «Win32_DefragAnalysis». Всегда ли бывает так — не скажу, не знаю. Смотрите сами.
]]>
)
]]>
, нету. Потому у меня и пусто. В итоге, мы возвращаемся к посту №2. Попробую посмотреть завтра напрямую на класс «Win32_Volume».