Const ColNumber = 4 'количество колонок (от 0)
arr2 = Array(3,4) 'например 3-я и 5-я колонки

текст1;текст2;текст3;текст4;текст5;текст6
10.10.3.131;10;11;484;aa;191
10.10.3.131;10;11;347;aa;503
10.10.3.131;10;11;514;aa;210
10.10.3.131;10;11;510;aa;190
10.10.3.131;10;11;347;aa;503
10.10.3.131;10;11;514;aa;210

Option Explicit
Const CsvFile1 = "qwe.csv" 'читаем
Const CsvFile2 = "qwe.txt" 'пишем
Const ColNumber = 5 'количество колонок (от 0)
Dim fso, arr, k, m, n, x, y, newFile
Dim arr2 'массив номеров колонок для счета (от 0)
arr2 = Array(3,5) 'например 3-я и 5-я колонки

Set fso = CreateObject("Scripting.FileSystemObject")

If Not fso.FileExists(CsvFile1) Then
	MsgBox "Файл " & CsvFile1 & " не найден"
	WScript.Quit
End If

arr = ReadCSV(CsvFile1, ColNumber) 'читаем

With fso	
	If Not .FileExists(CsvFile2) Then
		Set newFile = .CreateTextFile(CsvFile2)
		newFile.Close	
	End If
	
	Set newFile = .OpenTextFile(CsvFile2,8)
	With newFile 
		For k = 0 To UBound(arr2)		
			m = 0
			For n = 1 To UBound(arr,2) 'считаем			
				m = m + CInt((arr(arr2(k),n)))
			Next
			.WriteLine arr(arr2(k),0) & " = " & m 'пишем
		Next
		.Close
	End With
End With

Function ReadCSV(filePath, intColNumber)	
	Dim dataArray() 
	Dim splitArray 
	Dim i, j 
	i = 0
	With fso.OpenTextFile(filePath) 		
		Do Until .AtEndOfStream 			
			splitArray = Split(.ReadLine, ";")			
			ReDim Preserve dataArray(intColNumber, i)		
			For j = 0 To intColNumber
				dataArray(j, i) = splitArray(j)
			Next				
			i = i + 1				
		Loop
		.Close
	End With
	ReadCSV = dataArray
End Function

Option Explicit

Dim objFSO

Dim strSourceFile

Dim objLogQuery
Dim objCOMTSVInputContext
Dim objRecord

Dim strQueryPart
Dim i


If WScript.Arguments.Count = 1 Then
    strSourceFile = WScript.Arguments.Item(0)
    
    Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
    
    If objFSO.FileExists(strSourceFile) Then
        Set objLogQuery = WScript.CreateObject("MSUtil.LogQuery")
        Set objCOMTSVInputContext = WScript.CreateObject("MSUtil.LogQuery.TSVInputFormat")
        
        With objCOMTSVInputContext
            .iCodepage  = 1251
            .iSeparator = ";"
        End With
        
        strQueryPart = ""
        
        With objLogQuery.Execute("SELECT * FROM '" & strSourceFile & "'", objCOMTSVInputContext)
            For i = 3 To .getColumnCount() - 1
                strQueryPart = strQueryPart & "SUM(" & .getColumnName(i) & ") AS " & .getColumnName(i) & ", "
            Next
            
            strQueryPart = Left(strQueryPart, Len(strQueryPart) - 2)
            
            .close
        End With
        
        With objLogQuery.Execute("SELECT " & strQueryPart & " FROM '" & strSourceFile & "'", objCOMTSVInputContext)
            Set objRecord = .getRecord()
            
            For i = 0 To .getColumnCount() - 1
                WScript.StdOut.WriteLine .getColumnName(i) & "=" & CStr(objRecord.getValue(i))
            Next
            
            Set objRecord = Nothing
            
            .close
        End With
        
        Set objCOMTSVInputContext = Nothing
        Set objLogQuery           = Nothing
    Else
        WScript.StdOut.WriteLine "Source file [" & strSourceFile & "] not found"
        
        WScript.Quit 2
    End If
    
    Set objFSO = Nothing
Else
    WScript.StdOut.WriteLine "Usage: cscript.exe //nologo """ & WScript.ScriptName & """ ""<Source file>"""
    
    WScript.Quit 1
End If

WScript.Quit 0

cscript.exe //nologo "c:\My Scripts\Script.vbs" "c:\Temp\FileIn.csv">"e:\FileOut.txt"