Серый форум — AHK: Авто размер GUI, в зависимости от "Text"

Re: AHK: Авто размер GUI, в зависимости от "Text"

null@example.com (serzh82saratov) — Sun, 28 Apr 2013 18:25:38 +0000

Да и сабж упрощает тоже:


Gui +AlwaysOnTop +ToolWindow -0x400000 +E0x08000000
Gui Font, % "bold italic cWhite s" Font := 32, Times New Roman  
Gui Color, 696969

Space::
    DllCall("DestroyWindow", "Ptr", hText)
    Gui Add, Text, hwndhText x%Font% y%Font%, % (T := !T) ? "..." : "Очень`n             длинный текст"  
    Gui Show, NA x5 y5 AutoSize
    Return

Re: AHK: Авто размер GUI, в зависимости от "Text"

null@example.com (serzh82saratov) — Sun, 28 Apr 2013 17:52:48 +0000

ypppu
ну задавая ширину тексту конечно-же всё просто и очевидно (хотя подобрать под каждый, и чтобы всё ровно было... способ не айс). Речь то про то, что текст заранее неизвестен.

Но напоминание про AutoSize немного помогло упростить код из 35 поста

Re: AHK: Авто размер GUI, в зависимости от "Text"

null@example.com (ypppu) — Sun, 28 Apr 2013 15:44:10 +0000

Это был ответ на вопрос о том, как сделать чтоб окно не мелькало, то есть без использования Gui, Destroy.

Gui, +AlwaysOnTop -Border +ToolWindow +Disabled
Gui, Color,  Blue
Gui, font, s22 cWhite
Gui, Add, Text, vMyText, Text0
Gui, Show, NoActivate x5 y5
Return

1::
Config = ...
w := 100
Gosub, GuiConfig
Return

2::
Config = Очень длинный текст
w := 400
Gosub, GuiConfig
Return

GuiConfig:
GUIControl, , MyText, %Config%
GuiControl, MoveDraw, MyText, w%w%
Gui, Show, AutoSize

Re: AHK: Авто размер GUI, в зависимости от "Text"

null@example.com (serzh82saratov) — Sun, 28 Apr 2013 12:59:50 +0000

ypppu
Сильно похоже на голую теорию.
Вы код можете привести?

--------------

Это как раз было первым что пришло в голову, и сразу ушло:

Space::
    Gui, +AlwaysOnTop -0x400000 +E0x08000000 
    Gui, Color, % T ? "95746A" : "FF8C00"
    Gui, Font, % "Italic s" (T ? "18 cWhite": "200 c95746A"), Times New Roman 
    Gui Add, Text, x20 y20 Center, % (T := !T) ? "..." : "Очень`n`nдлинный текст"  
    Gui, Show, AutoSize
    Return

Re: AHK: Авто размер GUI, в зависимости от "Text"

null@example.com (ypppu) — Sun, 28 Apr 2013 11:31:16 +0000

Как сделать чтоб окно не мелькало, то есть видимо без использования Gui, Destroy.

Лишний раз выполнить команду Gui, Show, AutoSize.

Re: AHK: Авто размер GUI, в зависимости от "Text"

null@example.com (serzh82saratov) — Sat, 27 Apr 2013 20:19:31 +0000

Использование клона окна для относительного позиционирования контролов, и перерисовки окна:


Gui Add, Text, Center vText
Gui, Add, GroupBox, Center vGroupBox
Gui, Add, Button, vButton1 
Gui, Add, Button, vButton2 
Gui, Add, Button, vButton3
Gui, Show
Gosub Space
Return 
    
Space::
    Text := (T := !T) ? "наблюдаем " : "`n`n`n`nза поведением текста`n`n`n`nи кнопок`n`n`n`n"
    Button := (T) ? "min" : "MAXIMIZE" 
    Gui, Clo:Add, Text, vText xm+10 ym+30 Center, % Text
    Gui, Clo:Add, GroupBox, vGroupBox xp-10 ys-20 wp+20 hp+30
    Gui, Clo:Add, Button, vButton2 x+15 y+15 Section, % Button
    Gui, Clo:Add, Button, vButton1 xm ys, % Button
    Gui, Clo:Add, Button, vButton3 xs ym, % Button
    GuiControl, , % Move("Text"), % Text 
    GuiControl, , % Move("Button1"), % Button
    GuiControl, , % Move("Button2"), % Button
    GuiControl, , % Move("Button3"), % Button 
    GuiControl, , % Move("GroupBox"), % Button 
    Gui, Clo:Destroy 
    Gui, Show, AutoSize
    Return 
    
Move(Control) {
    GuiControlGet, Pos, Clo:Pos, % Control
    GuiControl, Move, % Control, w%Posw% h%Posh% x%Posx% y%Posy%   
    Return Control
}

Или:


Space::
    Text := (T := !T) ? "наблюдаем " : "`n`n`n`nза поведением текста`n`n`n`nи кнопок`n`n`n`n"
    Button := (T) ? "min" : "MAXIMIZE" 
    
    DllCall("DestroyWindow", "Ptr", hText)
    Gui Add, Text, xm+10 ym+30 Center hwndhText, % Text
    
    DllCall("DestroyWindow", "Ptr", GroupBox)
    Gui, Add, GroupBox, xp-10 yp-20 wp+20 hp+30 Center hwndGroupBox, % Button
    
    DllCall("DestroyWindow", "Ptr", Button1 )
    Gui, Add, Button, hwndButton1  x+15 y+15 Section, % Button
    
    DllCall("DestroyWindow", "Ptr", Button2)
    Gui, Add, Button, hwndButton2 xm ys, % Button
    
    DllCall("DestroyWindow", "Ptr", Button3)
    Gui, Add, Button, hwndButton3 xs ym+15, % Button
    
    Gui, Show, AutoSize 
    Return

Есть идеи попроще?

Re: AHK: Авто размер GUI, в зависимости от "Text"

null@example.com (serzh82saratov) — Tue, 09 Apr 2013 17:55:12 +0000

Решил сделать своеобразный ToolTip.
И вопросик появился: возможно ли как-то сделать его поверх всех окон? То есть и поверх тех что тоже имеют стиль "AlwaysOnTop".



#SingleInstance force   

Space::
    Gui, +AlwaysOnTop -0x400000 +E0x08000000 
    Gui, Color, % T ? "95746A" : "FF8C00"
    Gui, Font, % "Italic s" (T ? "18 cWhite": "200 c95746A"), Times New Roman
    DllCall("DestroyWindow", "Ptr", hStatic)
    Gui Add, Text, hwndhStatic x20 y20 Center, % (T := !T) ? "..." : "Очень`n`nдлинный текст" 
    GuiControlGet, Pos, Pos, %hStatic%    
    MouseGetPos, mX, mY
    Gui, Show, % "NA x" mX+15 " y" mY+15 " w" PosX*2+PosW " h" PosY*2+PosH
    Return
    
Esc::
    GuiClose:
    ExitApp

Re: AHK: Авто размер GUI, в зависимости от "Text"

null@example.com (serzh82saratov) — Sun, 07 Apr 2013 20:42:41 +0000

Решение:

 
Gui +AlwaysOnTop +ToolWindow -0x400000 +E0x08000000
Gui Font, % "s" Font := 22  
Gui Color, FF8C00

Space::
    DllCall("DestroyWindow", "Ptr", hText)
    Gui Add, Text, hwndhText x%Font% y%Font%, % (T := !T) ? "..." : "Очень`n             длинный текст"  
    Gui Show, NA x5 y5 AutoSize
    Return

Re: AHK: Авто размер GUI, в зависимости от "Text"

null@example.com (serzh82saratov) — Sun, 07 Apr 2013 20:27:04 +0000

teadrinker
Эх, над дилетантом подшучиваете


Gui, -Border
Gui, Font, s22
Gui Add, Text, hwndhStatic
Return

Space::
    DllCall("DestroyWindow", "Ptr", hStatic)
    Gui Add, Text, hwndhStatic x10 y15, % (T := !T) ? "..." : "Очень длинный текст "
    GuiControlGet, Pos, Pos, %hStatic% 
    Gui, Show, % "x5 y5 w" PosX*2+PosW " h" PosY*2+PosH
    Return

Для решения задачки вроде подходит. Или я что-то снова недопонял...

Re: AHK: Авто размер GUI, в зависимости от "Text"

null@example.com (teadrinker) — Sun, 07 Apr 2013 19:15:32 +0000

Точно.

Re: AHK: Авто размер GUI, в зависимости от "Text"

null@example.com (serzh82saratov) — Sun, 07 Apr 2013 19:12:00 +0000

То есть исключительно для освобождения ресурсов?

Re: AHK: Авто размер GUI, в зависимости от "Text"

null@example.com (teadrinker) — Sun, 07 Apr 2013 19:07:15 +0000

Удаление можно использовать для изменения вида GUI, если есть уверенность, что удаляемый контрол больше не понадобится.

Re: AHK: Авто размер GUI, в зависимости от "Text"

null@example.com (serzh82saratov) — Sun, 07 Apr 2013 19:01:47 +0000

Не знаю, ссылка на пример же была дана

Не очень нравится как оно работает, не много тормознуто и не всегда ровно.

А как (где, зачем) в принципе можно использовать удаление hwnd?

Re: AHK: Авто размер GUI, в зависимости от "Text"

null@example.com (teadrinker) — Sun, 07 Apr 2013 18:56:24 +0000

Не знаю, ссылка на пример же была дана. Там функция для определения размера текста.

Re: AHK: Авто размер GUI, в зависимости от "Text"

null@example.com (serzh82saratov) — Sun, 07 Apr 2013 18:35:00 +0000

Удаление hwnd, это интересно.
А это может как-то решить сабж?