Серый форум — VBS: Зарегистрировать сервис

Re: VBS: Зарегистрировать сервис

null@example.com (dab00) — Thu, 09 Aug 2012 07:05:54 +0000

alexii пишет:

smaharbA советовал sc.exe .

Я и имел ввиду sc, сорри, очепятка, sc /?

Re: VBS: Зарегистрировать сервис

null@example.com (alexii) — Thu, 09 Aug 2012 06:23:07 +0000

smaharbA советовал sc.exe .

Re: VBS: Зарегистрировать сервис

null@example.com (dab00) — Thu, 09 Aug 2012 06:05:22 +0000

Попробовал, работает... Попробуйте явно прописать путь sPathName и sParamName.
Как вариант используйте совет уважаемого smaharbA - cs /?

Re: VBS: Зарегистрировать сервис

null@example.com (Евген) — Thu, 09 Aug 2012 06:01:44 +0000

А у меня другой вопросец появилсо
Мне нужно сервис запустить от имени локального админа, для этого в параметры создания сервиса добавил

objInParam.StartName = ".\locadmlogin"
objInParam.StartPassword = "locadmpassword"

Но ругаеться ошибкой "Не возможно создать службу"

Re: VBS: Зарегистрировать сервис

null@example.com (smaharbA) — Thu, 09 Aug 2012 05:51:30 +0000

а что команду sc уже отменили ?

Re: VBS: Зарегистрировать сервис

null@example.com (Starley25) — Thu, 09 Aug 2012 05:25:25 +0000

Права самые самые .

Re: VBS: Зарегистрировать сервис

null@example.com (dab00) — Thu, 09 Aug 2012 04:58:05 +0000

Скрипт предоставляется "как есть" . Может прав не хватает?

Re: VBS: Зарегистрировать сервис

null@example.com (Starley25) — Thu, 09 Aug 2012 00:38:03 +0000

dab00 Предоставленный вами скрипт не работает,
Const scrFileName = "Speed_Met.vbs"
Const ServiceName = "SpeedCP"
положил в корень диска с, своей же машины ваш скрипт, туда же положил скрипт который нужно запускать Speed_Met.vbs от имени сервиса и там же srvany.exe. После запуска вашего скрипта ошибка: "Не удалось создать службу SpeedCP", сообщение из этой части кода:

If objOutParam.ReturnValue <> 0 Then
   MsgBox "Не удалось создать службу " & ServiceName

Re: VBS: Зарегистрировать сервис

null@example.com (smaharbA) — Wed, 01 Aug 2012 17:23:21 +0000

этож пипец как набрать help

Re: VBS: Зарегистрировать сервис

null@example.com (dab00) — Wed, 01 Aug 2012 10:02:52 +0000

Пример

Re: VBS: Зарегистрировать сервис

null@example.com (Rom5) — Wed, 01 Aug 2012 09:13:01 +0000

dab00, а можно пример запуска приложения от имени учетки пользователя с помощью SWbemLocator?

Хочу стартовать "gpupdate.exe /force" от имени пользователя на удаленной машине, знаю только способ с созданием одноразового задания в шедулере машины.

Re: VBS: Зарегистрировать сервис

null@example.com (dab00) — Wed, 01 Aug 2012 08:15:38 +0000

Starley25 пишет:

Это локально, а как удаленно можно выкрутиться, запустить все это чудо на удаленной машине?

Копируете srvany и скрипт, который должен запускаться в качестве службы в шару на удаленном компе, подключаетесь к wmi удаленного компа: или "winmgmts:\\" & ИмяКомпа, или от имени пользователя - через SWbemLocator, далее по тексту.

Re: VBS: Зарегистрировать сервис

null@example.com (Starley25) — Wed, 01 Aug 2012 04:46:26 +0000

Пока писал ответ уже и решение нашлось .
Скрипт от dab00 то, что доктор прописал.
Это локально, а как удаленно можно выкрутиться, запустить все это чудо на удаленной машине?

Re: VBS: Зарегистрировать сервис

null@example.com (dab00) — Wed, 01 Aug 2012 04:45:39 +0000

Я регистрировал следующим образом:


Const scrFileName = "MyScript.vbs"
Const ServiceName = "MyService"
Const HKLM = &H80000002   

With CreateObject("Scripting.FileSystemObject")
   sPathName = .BuildPath(.GetParentFolderName(.GetFile(WScript.ScriptFullName)),"srvany.exe")   
   sParamName = "wscript.exe " &.BuildPath(.GetParentFolderName(.GetFile(WScript.ScriptFullName)),scrFileName)
End With

Set objWMI = GetObject("winmgmts:\\.\Root\CIMV2")      
Set objInstance = objWMI.Get("Win32_Service")
Set objMethod = objInstance.Methods_("Create")
Set objInParam = objMethod.inParameters.SpawnInstance_()

'задаем параметры
objInParam.Name = ServiceName
objInParam.DisplayName = "My Interactive Service"
objInParam.StartMode = "Automatic"
objInParam.DesktopInteract = True
objInParam.PathName = sPathName
'создаем службу
Set objOutParam = objInstance.ExecMethod_("Create", objInParam)

If objOutParam.ReturnValue <> 0 Then
   MsgBox "Не удалось создать службу " & ServiceName
   WScript.Quit
End If
   
'создаем ключи реестра, чтобы запускать srvany.exe с параметром - нашим скриптом
sKeyPath = "SYSTEM\CurrentControlSet\Services\" & ServiceName & "\Parameters"
With GetObject("winmgmts:\\.\root\default:StdRegProv")
   .CreateKey HKLM,sKeyPath
   .SetStringValue HKLM,sKeyPath,"Application",sParamName
End With

If Err.Number <> 0 Then
   MsgBox "Не удалось создать ключи реестра " & ServiceName
   WScript.Quit
End If

'запускаем службу
Set colServices = objWMI.ExecQuery("SELECT * FROM Win32_Service WHERE Name='" & ServiceName & "'")
If colServices.Count Then
   For Each objService In colServices
      ret = objService.StartService
      If ret <> 0 Then
         MsgBox "Не удалось запустить службу " & ServiceName
         WScript.Quit
      End If
   Next
Else
   MsgBox "Не удалось создать службу " & ServiceName
   WScript.Quit
End If

MsgBox "Служба " & ServiceName & " установлена и запущена"

В этом примере srvany и скрипт, который запускается в качестве службы находятся в том же каталоге, что и скрипт регистрации службы.

Re: VBS: Зарегистрировать сервис

null@example.com (alexii) — Wed, 01 Aug 2012 04:31:16 +0000

Starley25, зарегистрировать службу из предназначенного для того приложения можно любым способом, но попытаться создать службу из стороннего приложения (как в Вашем примере) можно только с помощью специально предназначенного для этого способа — instsrv.exe & srvany.exe: Создание определяемой пользователем службы.