Серый форум — CMD/BAT: Замена одной строки на другую в txt файле

Re: CMD/BAT: Замена одной строки на другую в txt файле

null@example.com (bugagashi) — Wed, 03 Oct 2012 04:42:04 +0000

я немного не понял, а где тут путь к файлу ищется?
у меня ведь не на диске с:, а в локальной сети.

Re: CMD/BAT: Замена одной строки на другую в txt файле

null@example.com (digreesun) — Tue, 02 Oct 2012 17:07:54 +0000

MegaScrew пишет:

Rumata, ваш пример работает, но если его подвести под указанную тут задачу то не работает.
Нерабочий код:
@echo off

set XYZ=FA_ALERT=1
SET find=FA_ALERT=1
SET replace=FA_ALERT=0


echo %XYZ%

set XYZ=%XYZ:%find%=%replace%%

echo %XYZ%
Так как после подстановки %find% cmd не смотрит дальше. Так это обойти что бы все заработало?

Можно! Например вот так:

@echo off

call :MaskEQ VAR "==!=="
echo.%VAR%
rem Now VAR contains string in HEX: 1E 1E 21 1E 1E

call :RestEQ VAR "%VAR%"
echo.%VAR%
rem Now VAR restored to: ==!==

exit /b

:MaskEQ
rem call :MaskEQ VAR "%STR%"
setlocal EnableExtensions
set STR=%~2
if not defined STR goto _exit_MaskEQ
rem mask ! char to 0x1d before EnableDelayedExpansion
set STR=%STR:!=1d%
set i=0
setlocal EnableDelayedExpansion
:_next_MaskEQ
set C=!STR:~%i%,1!
if not defined C goto _ret_MaskEQ
set C=%C:"=%
set /a j=%i%+1
rem replace = char to pattern 0x1e
if "%C%"=="=" set STR=!STR:~0,%i%!1e!STR:~%j%!
set /a i=%i%+1
goto _next_MaskEQ
:_ret_MaskEQ
endlocal&set STR=%STR%
rem restore ! char from 0x1d
set STR=%STR:1d=!%
:_exit_MaskEQ
endlocal&set %1=%STR%
goto :EOF


:RestEQ
rem call :RestEQ VAR "%STR%"
setlocal EnableExtensions
set STR=%~2

rem restore = char from 0x1e
if defined STR set STR=%STR:1e==%
endlocal&set %1=%STR%
goto :EOF

P.S.
Вместо нечитабельных символов 0x1D и 0x1E можно задать любую уникальную строку
Всех благ!

там где style="color: #448888;"> это не мое это лишнее ну кто знает поймет

Вот без подсветки синтаксиса:

@echo off

call :MaskEQ VAR "==!=="
echo.%VAR%
rem Now VAR contains string in HEX: 1E 1E 21 1E 1E

call :RestEQ VAR "%VAR%"
echo.%VAR%
rem Now VAR restored to: ==!==

exit /b

:MaskEQ
rem call :MaskEQ VAR "%STR%"
setlocal EnableExtensions
set STR=%~2
if not defined STR goto _exit_MaskEQ
rem mask ! char to 0x1d before EnableDelayedExpansion
set STR=%STR:!=1d%
set i=0
setlocal EnableDelayedExpansion
:_next_MaskEQ
set C=!STR:~%i%,1!
if not defined C goto _ret_MaskEQ
set C=%C:"=%
set /a j=%i%+1
rem replace = char to pattern 0x1e
if "%C%"=="=" set STR=!STR:~0,%i%!1e!STR:~%j%!
set /a i=%i%+1
goto _next_MaskEQ
:_ret_MaskEQ
endlocal&set STR=%STR%
rem restore ! char from 0x1d
set STR=%STR:1d=!%
:_exit_MaskEQ
endlocal&set %1=%STR%
goto :EOF


:RestEQ
rem call :RestEQ VAR "%STR%"
setlocal EnableExtensions
set STR=%~2
if defined STR set STR=%STR:1e==%&rem restore = char from 0x1e
endlocal&set %1=%STR%
goto :EOF

Re: CMD/BAT: Замена одной строки на другую в txt файле

null@example.com (bugagashi) — Tue, 02 Oct 2012 11:58:02 +0000

Я бы хотел добавить от себя вопрос.
Суть такая же.
Есть файл INF.DAT
В нём есть строка, начинающаяся на origin, после идёт
= значение.
Необходимо значение, какое оно бы не было, заменить на 0.
Файл находиться в сети, на одной и той же машине. например \\Andrey\prepare\
После prepare могут быть ещё папки. INF.DAT есть всегда и, внутри оного, origin = значение, тоже.

Re: CMD/BAT: Замена одной строки на другую в txt файле

null@example.com (Rumata) — Fri, 10 Aug 2012 11:37:21 +0000

MegaScrew пишет:

Так это обойти что бы все заработало?

Скорее всего никак.

Лично я использую утилиты SED, AWK из комплекта UnixUtils или PERL; или же пишу небольшой скрипт на JSCRIPT и внедряю его в BAT-файл, как это описано здесь - bat+jscript: два в одном

Ваша задача очень легко решается в 1-2 строки с помощью SED/AWK/PERL и требует больших усилий в командной строке DOS.

Re: CMD/BAT: Замена одной строки на другую в txt файле

null@example.com (MegaScrew) — Fri, 10 Aug 2012 10:50:40 +0000

Rumata, ваш пример работает, но если его подвести под указанную тут задачу то не работает.
Нерабочий код:

@echo off

set XYZ=FA_ALERT=1
SET find=FA_ALERT=1
SET replace=FA_ALERT=0


echo %XYZ%

set XYZ=%XYZ:%find%=%replace%%

echo %XYZ%

Так как после подстановки %find% cmd не смотрит дальше. Так это обойти что бы все заработало?

Re: CMD/BAT: Замена одной строки на другую в txt файле

null@example.com (Rumata) — Fri, 10 Aug 2012 08:27:11 +0000

MegaScrew пишет:

по второму вопросу про %PATH:str1=str2% ??

@echo off

set XYZ=VAR=VALUE

echo %XYZ%

set XYZ=%XYZ:VAR=KEY%

echo %XYZ%

Re: CMD/BAT: Замена одной строки на другую в txt файле

null@example.com (MegaScrew) — Fri, 10 Aug 2012 07:33:53 +0000

Rumata и alexii, спасибо за инфу.
так я тоже в FAR-e, собственно в нем и увидел лишние пробелы в итоговом файле.
А что скажете по второму вопросу про %PATH:str1=str2% ??

Re: CMD/BAT: Замена одной строки на другую в txt файле

null@example.com (alexii) — Fri, 10 Aug 2012 07:18:41 +0000

И:

    IF !line!==%find% ( SET line=%replace% )

на:

    IF !line!==%find% ( SET line=%replace%)

. Начинаю понимать, почему рекомендуют использовать такую форму:

set "Var=Value"

Мне-то, в Far Manager'е, все пробельные символы видны.

Re: CMD/BAT: Замена одной строки на другую в txt файле

null@example.com (Rumata) — Fri, 10 Aug 2012 07:04:00 +0000

MegaScrew пишет:

Есть в нем недостаток, после прохода по файлу данный скрипт добавляет два лишних пробела в конец каждой строки.

Замените

echo !line! >> %tfile%

на

echo !line!>> %tfile%

========
Вообще, лучше делать один централизованный вывод. Мне известны два способа:

1. группировка

(
    echo string
    echo another string
) > filename

2. вызов подпрограммы

call :sub > filename

:: выход из скрипта
goto :EOF

:sub
echo string
echo another string

:: выход из подпрограммы
goto :EOF

Re: CMD/BAT: Замена одной строки на другую в txt файле

null@example.com (MegaScrew) — Fri, 10 Aug 2012 06:28:20 +0000

это рабочий батник.
Запускать myfile.bat targetfile.txt

@ECHO OFF
setlocal enabledelayedexpansion
SET ifile=%1
SET tfile=%ifile%.tmp
SET find=FA_ALERT=1
SET replace=FA_ALERT=0
IF EXIST %tfile% DEL /Q %tfile%

FOR /F "tokens=* delims=, " %%a IN (%ifile%) DO ( 
    set line=%%a
    IF !line!==%find% ( SET line=%replace% )
    echo !line! >> %tfile%
)

MOVE /Y %tfile% %ifile%

EXIT /B 0

PS:
Есть в нем недостаток, после прохода по файлу данный скрипт добавляет два лишних пробела в конец каждой строки. Следовательно обработать один и тот же файл дважды не получиться так как строка %finde% не будет совпадать со строкой у которой в конце пробелы. Кто знает как вылечить это?
PSS: более простой вариант был бы с использованием %PATH:str1=str2% только вот беда, если в str1 или str2 есть знак равно как в данном случае то все летит в чертям, кто знает как лечить?
Взять строку в кавычки не предлагать так как в рамках данной задачи это не вариант.

Re: CMD/BAT: Замена одной строки на другую в txt файле

null@example.com (smaharbA) — Thu, 09 Aug 2012 18:52:21 +0000

это не батник, это эскиз

Re: CMD/BAT: Замена одной строки на другую в txt файле

null@example.com (Arg) — Thu, 09 Aug 2012 13:44:59 +0000

Большое спасибо, я так понял это то что будет происходить с самим файлом, а как указать что бы этот скрипт применялся к конкретному файлу (путь как указать?) Просто так попробовал включить такой батник, он несработал.

Re: CMD/BAT: Замена одной строки на другую в txt файле

null@example.com (smaharbA) — Thu, 09 Aug 2012 11:34:03 +0000

for %%x ... do (
for %%y in (%%x) do (
set z=%%y
if !z!==FA_ALERT=1 set !z!=FA_ALERT=0
set zz=!zz!!z!тутапробел
)
echo !zz!
)

как то так

CMD/BAT: Замена одной строки на другую в txt файле

null@example.com (Arg) — Thu, 09 Aug 2012 08:15:16 +0000

Здраствуйте, помогите пожалуйста написать батник, я неочень хорошо в них разбираюсь, но юзал поиск, находил несколько схожих тем, но разобраться все равно неполучилось.

Нужно, что бы при нажатии на батник в файле MYFILE.TXT, который состоит из не более чем 100 строк, строка FA_ALERT=1 заменялась на строку FA_ALERT=0, желательно что бы при этом ненужно было указывать номер этой строки.

Заранее спасибо всем откликнувшимся.