Error:  No valid COM object!

    Line#
    012: DllCall("shell32\SHGetFolderLocation", "Ptr", 0, "int", sPath, "Ptr", 0, "Uint", 0, "Ptr*", pidl)  
    013: DllCall("shell32\SHBindToParent", "Ptr", pidl, "Ptr", GUID4String(IID_IShellFolder,"{000214E6-0000-0000-C000-000000000046}"), "Ptr*", pIShellFolder, "Ptr*", pidlChild)  
    015: DllCall(VTable(pIShellFolder, 10), "Ptr", pIShellFolder, "Ptr", 0, "Uint", 1, "Ptr*", pidlChild, "Ptr", GUID4String(IID_IContextMenu,"{000214E4-0000-0000-C000-000000000046}"), "Ptr", 0, "Ptr*", pIContextMenu)  
    016: ObjRelease(pIShellFolder)  
    017: CoTaskMemFree(pidl)  
    019: hMenu := DllCall("CreatePopupMenu")
    022: DllCall(VTable(pIContextMenu, 3), "Ptr", pIContextMenu, "Ptr", hMenu, "Uint", 0, "Uint", 3, "Uint", 0x7FFF, "Uint", 0x100)  
--->    024: pIContextMenu2 := ComObjQuery(pIContextMenu, IID_IContextMenu2:="{000214F4-0000-0000-C000-000000000046}")
    025: pIContextMenu3 := ComObjQuery(pIContextMenu, IID_IContextMenu3:="{BCFCE0A0-EC17-11D0-8D10-00A0C90F2719}")
    026: WPOld := DllCall("SetWindowLong", "Ptr", A_ScriptHWND, "int",-4, "Uint",RegisterCallback("WindowProc"))
    028: DllCall("GetCursorPos", "int64*", pt)  
    029: DllCall("InsertMenu", "Ptr", hMenu, "Uint", 0, "Uint", 0x0400|0x800, "Ptr", 2, "Ptr", 0)  
    030: DllCall("InsertMenu", "Ptr", hMenu, "Uint", 0, "Uint", 0x0400|0x002, "Ptr", 1, "Ptr", &sPath)  
    032: idn := DllCall("TrackPopupMenuEx", "Ptr", hMenu, "Uint", 0x0100|0x0001, "int", pt << 32 >> 32, "int", pt >> 32, "Ptr", A_ScriptHWND, "Uint", 0)
    056: struct_size := 16+11*A_PtrSize

ShellContextMenu("C:\Windows")
ExitApp

; ================ FUNCTION ================

ShellContextMenu(sPath)
{
    If sPath Is Not Integer
        DllCall("shell32\SHParseDisplayName", "str", sPath, "Ptr", 0, "Ptr*", pidl, "Uint", 0, "Uint*", 0)
        ;This function is the preferred method to convert a string to a pointer to an item identifier list (PIDL).
    else
        DllCall("shell32\SHGetFolderLocation", "Ptr", 0, "int", sPath, "Ptr", 0, "Uint", 0, "Ptr*", pidl)
    DllCall("shell32\SHBindToParent", "Ptr", pidl, "Ptr", GUID4String(IID_IShellFolder,"{000214E6-0000-0000-C000-000000000046}"), "Ptr*", pIShellFolder, "Ptr*", pidlChild)
    ;IShellFolder->GetUIObjectOf
    DllCall(VTable(pIShellFolder, 10), "Ptr", pIShellFolder, "Ptr", 0, "Uint", 1, "Ptr*", pidlChild, "Ptr", GUID4String(IID_IContextMenu,"{000214E4-0000-0000-C000-000000000046}"), "Ptr", 0, "Ptr*", pIContextMenu)
    ObjRelease(pIShellFolder)
    CoTaskMemFree(pidl)

    hMenu := DllCall("CreatePopupMenu")
    ;IContextMenu->QueryContextMenu
    ;http://msdn.microsoft.com/en-us/library/bb776097%28v=VS.85%29.aspx
    DllCall(VTable(pIContextMenu, 3), "Ptr", pIContextMenu, "Ptr", hMenu, "Uint", 0, "Uint", 3, "Uint", 0x7FFF, "Uint", 0x100)    ;CMF_EXTENDEDVERBS

    global pIContextMenu2 := ComObjQuery(pIContextMenu, IID_IContextMenu2:="{000214F4-0000-0000-C000-000000000046}")
    global pIContextMenu3 := ComObjQuery(pIContextMenu, IID_IContextMenu3:="{BCFCE0A0-EC17-11D0-8D10-00A0C90F2719}")
    Global    WPOld:= DllCall("SetWindowLong", "Ptr", A_ScriptHWND, "int",-4, "Uint",RegisterCallback("WindowProc"))

    DllCall("GetCursorPos", "int64*", pt)
    DllCall("InsertMenu", "Ptr", hMenu, "Uint", 0, "Uint", 0x0400|0x800, "Ptr", 2, "Ptr", 0)
    DllCall("InsertMenu", "Ptr", hMenu, "Uint", 0, "Uint", 0x0400|0x002, "Ptr", 1, "Ptr", &sPath)

    idn := DllCall("TrackPopupMenuEx", "Ptr", hMenu, "Uint", 0x0100|0x0001, "int", pt << 32 >> 32, "int", pt >> 32, "Ptr", A_ScriptHWND, "Uint", 0)

    /*
    typedef  struct _CMINVOKECOMMANDINFOEX
    {
        DWORD   cbSize;        0
        DWORD   fMask;         4
        HWND    hwnd;          8
        LPCSTR  lpVerb;        8+A_PtrSize
        LPCSTR  lpParameters;  8+2*A_PtrSize
        LPCSTR  lpDirectory;   8+3*A_PtrSize
        int     nShow;         8+4*A_PtrSize
        DWORD   dwHotKey;      12+4*A_PtrSize
        HANDLE  hIcon;         16+4*A_PtrSize
        LPCSTR  lpTitle;       16+5*A_PtrSize
        LPCWSTR lpVerbW;       16+6*A_PtrSize
        LPCWSTR lpParametersW; 16+7*A_PtrSize
        LPCWSTR lpDirectoryW;  16+8*A_PtrSize
        LPCWSTR lpTitleW;      16+9*A_PtrSize
        POINT   ptInvoke;      16+10*A_PtrSize
    } CMINVOKECOMMANDINFOEX, *LPCMINVOKECOMMANDINFOEX;

    http://msdn.microsoft.com/en-us/library/bb773217%28v=VS.85%29.aspx
    */
    struct_size  :=  16+11*A_PtrSize
    VarSetCapacity(pici,struct_size,0)
    NumPut(struct_size,pici,0,"Uint")         ;cbSize
    NumPut(0x4000|0x20000000,pici,4,"Uint")   ;fMask
    NumPut(A_ScriptHWND,pici,8,"UPtr")        ;hwnd
    NumPut(1,pici,8+4*A_PtrSize,"Uint")       ;nShow
    NumPut(idn-3,pici,8+A_PtrSize,"UPtr")     ;lpVerb
    NumPut(idn-3,pici,16+6*A_PtrSize,"UPtr")  ;lpVerbW
    NumPut(pt,pici,16+10*A_PtrSize,"Int64")   ;ptInvoke

    DllCall(VTable(pIContextMenu, 4), "Ptr", pIContextMenu, "Ptr", &pici) ; InvokeCommand

    DllCall("GlobalFree", "Uint", DllCall("SetWindowLong", "Ptr", A_ScriptHWND, "int", -4, "Uint", WPOld))
    DllCall("DestroyMenu", "Ptr", hMenu)

    ObjRelease(pIContextMenu3)
    ObjRelease(pIContextMenu2)
    ObjRelease(pIContextMenu)
    pIContextMenu2:=pIContextMenu3:=WPOld:=0
    return idn
}

WindowProc(hWnd, nMsg, wParam, lParam)
{
    Critical
    Global pIContextMenu2, pIContextMenu3, WPOld
    If pIContextMenu3
    { ;IContextMenu3->HandleMenuMsg2
        If !DllCall(VTable(pIContextMenu3, 7), "Uint", pIContextMenu3, "Uint", nMsg, "Uint", wParam, "Uint", lParam, "Uint*", lResult)
            return    lResult
    }
    Else If pIContextMenu2
    { ;IContextMenu2->HandleMenuMsg
        If !DllCall(VTable(pIContextMenu2, 6), "Uint", pIContextMenu2, "Uint", nMsg, "Uint", wParam, "Uint", lParam)
            return    0
    }
    return    DllCall("user32.dll\CallWindowProcW", "Uint", WPOld, "Ptr", hWnd, "Uint", nMsg, "Uint", wParam, "Uint", lParam)
}

VTable(ppv, idx)
{
    return NumGet(NumGet(1*ppv)+A_PtrSize*idx)
}

GUID4String(ByRef CLSID, String)
{
    VarSetCapacity(CLSID, 16,0)
    return DllCall("ole32\CLSIDFromString", "wstr", String, "Ptr", &CLSID) >= 0 ? &CLSID : ""
}

CoTaskMemFree(pv)
{
    return DllCall("ole32\CoTaskMemFree", "Ptr", pv)
}