Серый форум — AHK: Определить, что идет звук

Re: AHK: Определить, что идет звук

null@example.com (Malcev) — Tue, 17 Feb 2015 10:53:00 +0000

Именно так.

Re: AHK: Определить, что идет звук

null@example.com (emmetoya) — Tue, 17 Feb 2015 09:35:47 +0000

Через анализ цвета пикселя в графическом эквалайзере с уровнем громкости?

Re: AHK: Определить, что идет звук

null@example.com (stealzy) — Tue, 17 Feb 2015 09:23:33 +0000

Malcev,
каким способом у вас решено было,
без реакции на звук,
не поделитесь?

Re: AHK: Определить, что идет звук

null@example.com (kharlashkin) — Mon, 25 Aug 2014 18:30:24 +0000

Alectric пишет:

Вариант (от автора VA) с инициализацией звукового клиента (не требует запуска левых приложений, показывает уровень сразу):

То, что надо!!!

Re: AHK: Определить, что идет звук

null@example.com (Alectric) — Mon, 25 Aug 2014 15:28:50 +0000

Вот этого кода достаточно, чтобы считывать уровень сигнала на устройстве записи по умолчанию:

#SingleInstance, Force
#include va.ahk

audioMeter := VA_GetAudioMeter("capture")
VA_IAudioMeterInformation_GetMeteringChannelCount(audioMeter, channelCount)
VA_GetDevicePeriod("capture", devicePeriod)

Loop
{
    VA_IAudioMeterInformation_GetPeakValue(audioMeter, peakValue)
    ToolTip, %peakValue%
    Sleep, %devicePeriod%
}

Только чтобы и правда увидеть уровень сигнала, нужно запустить любое приложение использующее микрофон (или устройство записи), кроме тех приложений, которые используют устройство в "монопольном режиме".

Вариант (от автора VA) с инициализацией звукового клиента (не требует запуска левых приложений, показывает уровень сразу):

#SingleInstance, Force
#include va.ahk

; Get the device which we'll be monitoring.
device := VA_GetDevice("capture")
; Get IAudioClient interface.
VA_IMMDevice_Activate(device, IID_IAudioClient:="{1CB9AD4C-DBFA-4c32-B178-C2F568A703B2}", 7, 0, audioClient)
; Get mixer format to pass to Initialize.
VA_IAudioClient_GetMixFormat(audioClient, format)
; Initialize audio client to ensure peak meter is active.
VA_IAudioClient_Initialize(audioClient, 0, 0, 0, 0, format, 0)

; Get IAudioMeterInformation interface.
audioMeter := VA_GetAudioMeter(device)
; No longer needed, so free it:
MeterLength = 30
; "The peak value for each channel is recorded over one device
;  period and made available during the subsequent device period."
VA_GetDevicePeriod("capture", devicePeriod)

Loop
{
    VA_IAudioMeterInformation_GetPeakValue(audioMeter, peakValue)
    ToolTip, %peakValue%
    Sleep, %devicePeriod%
}

Re: AHK: Определить, что идет звук

null@example.com (kharlashkin) — Mon, 25 Aug 2014 15:00:48 +0000

А как бы микрофон добавить?

Re: AHK: Определить, что идет звук

null@example.com (bWRmeA) — Wed, 12 Mar 2014 10:12:33 +0000

Если во всплывающем сообщении, во время полной тишины, будут отображаться цифры отличные от 0

float 0.000000 не равнозначно 0. Хоть это и противоречит здравому смыслу, но правильнее сравнивать 0.000000 не с 0 а с 0.000001 или со строкой "0.000000".

Re: AHK: Определить, что идет звук

null@example.com (Pokerist) — Tue, 12 Feb 2013 08:48:25 +0000

Спасибо! Похоже шапочка не понадобится. Приятно иметь дело с Профи!

Re: AHK: Определить, что идет звук

null@example.com (creature.ws) — Tue, 12 Feb 2013 07:08:00 +0000

идёт звук: срабатывание

Верно.

А он срабатывает, даже если видео остановить

Неверно.

#Persistent

audioMeter := VA_GetAudioMeter()
VA_IAudioMeterInformation_GetMeteringChannelCount(audioMeter, channelCount)
VarSetCapacity(peakValues, channelCount*4)
SetTimer, GetPeakValues, 100
return

GetPeakValues:
    VA_IAudioMeterInformation_GetChannelsPeakValues(audioMeter, channelCount, &peakValues)
    loop %channelCount%
        ToolTip %v%
    until v := NumGet(peakValues, A_Index*4-4, "float")
    return

Если во всплывающем сообщении, во время полной тишины, будут отображаться цифры отличные от 0 — ваш компьютер вам что-то нашептывает, необходимо использовать беруши и шапочку из фольги

Re: AHK: Определить, что идет звук

null@example.com (Pokerist) — Mon, 11 Feb 2013 13:28:55 +0000

Я рассчитывал, что он будет слышать то же что и я. Крутится видео - идёт звук: срабатывание. А он срабатывает, даже если видео остановить. Нужно обязательно закрывать окно плеера, чтобы срабатывания прекратились.
Если запущено приложение со встроенным flash, то тоже срабатывания идут вне зависимости, проигрывается заук или нет.
Пока не понял как выловить именно тут звук, что я хочу поймать.

Re: AHK: Определить, что идет звук

null@example.com (creature.ws) — Mon, 11 Feb 2013 01:10:46 +0000

А на что вы расчитывали?
«Молвит тут скрипт человечьим голосом: — Не серчай…»

Re: AHK: Определить, что идет звук

null@example.com (Pokerist) — Sun, 10 Feb 2013 22:31:12 +0000

Спасибо, разобрался. Правда он работает не совсем так, как я расчитывал, но это другой вопрос.

Re: AHK: Определить, что идет звук

null@example.com (Grey) — Wed, 06 Feb 2013 12:28:52 +0000

@Pokerist Вам нужно скачать архив и распаковать его либо в той же директории где и сам код, тогда уместна в коде такая запись:

creature.ws пишет:

#Include VA.ahk
...

Либо распаковать содержимое архива в папку библиотеки - ...\AutoHotkey\Lib\, директива #Include в коде будет не нужна.

Re: AHK: Определить, что идет звук

null@example.com (Pokerist) — Wed, 06 Feb 2013 12:09:10 +0000

Создал ahk-файл с этим кодом. В папке с ним создал файл VA.ahk с кодом


#SingleInstance, Force
MeterLength = 30

audioMeter := VA_GetAudioMeter()

VA_IAudioMeterInformation_GetMeteringChannelCount(audioMeter, channelCount)

; "The peak value for each channel is recorded over one device
;  period and made available during the subsequent device period."
VA_GetDevicePeriod("capture", devicePeriod)

Loop
{
    ; Get the peak value across all channels.
    VA_IAudioMeterInformation_GetPeakValue(audioMeter, peakValue)    
    meter := MakeMeter(peakValue, MeterLength)
    
    ; Get the peak values of all channels.
    VarSetCapacity(peakValues, channelCount*4)
    VA_IAudioMeterInformation_GetChannelsPeakValues(audioMeter, channelCount, &peakValues)
    Loop %channelCount%
        meter .= "`n" MakeMeter(NumGet(peakValues, A_Index*4-4, "float"), MeterLength)

    ToolTip, %meter%
    Sleep, %devicePeriod%
}

MakeMeter(fraction, size)
{
    global MeterLength
    Loop % fraction*size
        meter .= "|"
    Loop % (1-fraction)*size
        meter .= "."
    meter .= "  " fraction
    return meter
}

И полчаю ошибку "С: ... \VA.ahk (4) : ==> Call to nonexistent function."
Эта функция действительно не определена. По крайней мере, в приведенном коде. Помогите, пожлуйста!

Re: AHK: Определить, что идет звук

null@example.com (creature.ws) — Tue, 05 Feb 2013 02:10:08 +0000

#Include VA.ahk
#Persistent

audioMeter := VA_GetAudioMeter()
VA_IAudioMeterInformation_GetMeteringChannelCount(audioMeter, channelCount)
VarSetCapacity(peakValues, channelCount*4)
SetTimer, GetPeakValues, 100
return

GetPeakValues:
    VA_IAudioMeterInformation_GetChannelsPeakValues(audioMeter, channelCount, &peakValues)
    loop %channelCount%
        if NumGet(peakValues, A_Index*4-4, "float") {
            MsgBox раздался звук
            break
        }
    return