Серый форум — AHK: Свернуть/Развернуть в трей

Re: AHK: Свернуть/Развернуть в трей

null@example.com (vlad.blik13) — Mon, 06 Apr 2020 22:35:55 +0000

Огромное спасибо!)

Не цитируйте предыдущее сообщение.

Re: AHK: Свернуть/Развернуть в трей

null@example.com (teadrinker) — Mon, 06 Apr 2020 21:00:33 +0000

Gui, New, +hwndhGui1, Gui1
Gui, Show, x300 w300 h200

Gui, New,, Gui2
Gui, Show, x700 w300 h200

OnMessage(0x404, Func("AHK_NOTIFYICON").Bind(hGui1))
OnMessage(0x112, Func("WM_SYSCOMMAND").Bind(hGui1))
return

GuiClose:
   ExitApp

WM_SYSCOMMAND(hGui, wp, lp, msg, hwnd) {
   static SC_MINIMIZE := 0xF020
   if (wp = SC_MINIMIZE && hwnd = hGui) {
      WinHide, ahk_id %hwnd%
      return 0
   }
}

AHK_NOTIFYICON(hGui, wp, lp) {
   static WM_LBUTTONDOWN := 0x201
   if (lp = WM_LBUTTONDOWN)
      WinShow, ahk_id %hGui%
}

Re: AHK: Свернуть/Развернуть в трей

null@example.com (vlad.blik13) — Mon, 06 Apr 2020 19:23:05 +0000

А как сделать так, что-бы этот код действовал лишь на одно GUI, а на другое - нет? teadrinker

Re: AHK: Свернуть/Развернуть в трей

null@example.com (DD) — Fri, 30 Aug 2019 20:50:37 +0000

Через WinClose можно.

Re: AHK: Свернуть/Развернуть в трей

null@example.com (DD) — Fri, 30 Aug 2019 10:15:37 +0000

Так тоже пробовал

Archivarius3000.exe /min
start /min Archivarius3000.exe
start /min /low Archivarius3000.exe
в свойствах ярлыка дописать /tray

Максимум получается добиться свернутого окна в кнопку на Панели задач (помимо значка в Трее).

А можно сделать проверку и убрать определенное окно с Панели задач?

Re: AHK: Свернуть/Развернуть в трей

null@example.com (teadrinker) — Thu, 29 Aug 2019 07:16:58 +0000

Не, не в курсе.
Можно так попробовать:

Run, MyExe.exe,, Hide

Re: AHK: Свернуть/Развернуть в трей

null@example.com (DD) — Wed, 28 Aug 2019 17:17:15 +0000

Для которого уже предусмотрена отправка в трей? Имею в виду «Архивариус 3000».

+ открыть спойлер

Re: AHK: Свернуть/Развернуть в трей

null@example.com (teadrinker) — Wed, 28 Aug 2019 16:38:44 +0000

Смотря, какое приложение.

Re: AHK: Свернуть/Развернуть в трей

null@example.com (DD) — Wed, 28 Aug 2019 00:41:50 +0000

А возможно сразу запустить приложение в трее?

Re: AHK: Свернуть/Развернуть в трей

null@example.com (teadrinker) — Sat, 27 Oct 2012 08:18:37 +0000

global SC_MINIMIZE := 0xF020, WM_LBUTTONDOWN := 0x201, hGui

Gui, +AlwaysOnTop +hwndhGui
Gui, Show, w300 h200, Тест

OnMessage(0x404, "AHK_NOTIFYICON")
OnMessage(0x112, "WM_SYSCOMMAND")
return

GuiClose:
   ExitApp

WM_SYSCOMMAND(wp, lp, msg, hwnd)
{
   if (wp = SC_MINIMIZE && hwnd = hGui)
   {
      WinHide, ahk_id %hwnd%
      return 0
   }
}

AHK_NOTIFYICON(wp, lp)
{
   if (lp = WM_LBUTTONDOWN)
      WinShow, ahk_id %hGui%
}

AHK: Свернуть/Развернуть в трей

null@example.com ([CM]White) — Sat, 27 Oct 2012 07:31:32 +0000

Нужно по нажатию выделенной кнопки свернуть окно в трей, а развернуть по нажатию левой кнопки мыши на иконку в трее

#SingleInstance force
Gui, +AlwaysOnTop
Gui,Show, w300 h200, Тест
return

-:
Gui, hide
return

?:
Gui, Show
return

GuiClose:
ExitApp