Серый форум — AHK: A_PriorKey не всегда запоминает нажатые кнопки

Re: AHK: A_PriorKey не всегда запоминает нажатые кнопки

2012-12-18T20:06:12Z

Вы меня натолкнули на мысль, что можно блокировать кнопки Esc, !f4 и клики в определенной области и закрывать это окно с помощью autohotkey.

Re: AHK: A_PriorKey не всегда запоминает нажатые кнопки

2012-12-18T19:56:59Z

Что вы этой фразой имели в виду?

Мне нечего добавить к этой фразе.

А без объектов такое воплотить можно?

Можно, воплощайте.

Re: AHK: A_PriorKey не всегда запоминает нажатые кнопки

2012-12-18T18:40:33Z

Понял, что для того чтобы эту всю конструкцию понять нужно внимательно читать про объекты.
А без объектов такое воплотить можно?

Что мешает ждать клавиши с помощью Input, а клики в нужных (или ненужных) координатах отлавливать иным способом?

И еще вопрос.

; подразумевается, что для выбора пресета будет произведён хотя бы один клик.
; иначе нужно обрабатывать все пути закрытия окна.

Что вы этой фразой имели в виду?

Re: AHK: A_PriorKey не всегда запоминает нажатые кнопки

2012-12-18T17:32:27Z

это как такую конструкцию понять?

KeyList := {}
Это создание объекта с именем KeyList.
KeyList := {winTitle: …, Hotkeys: …}
Объект KeyList содержит два поля: winTitle и Hotkeys.
winTitle: winTitle
В поле с именем winTitle записано содержимое переменной winTitle
Hotkeys: ["~Esc", "~!f4", "~LButton"]
В поле с именем Hotkeys записан массив содержащий три значения:
под номером 1 — строку ~Esc
под номером 2 — строку ~!f4 и т.д.

почему кавычки

Второй аргумент — строка.

вот это все непонятно.

Это всё равнозначно:

Hotkey, IfWinActive, New Sequence
Hotkey, ~Esc, WindowClose , On
Hotkey, ~!f4, WindowClose, On
Hotkey, ~LButton, WindowClose, On

При SetHotkeys(KeyList, "WindowClose")

Hotkey, IfWinActive, New Sequence
Hotkey, ~Esc, Off
Hotkey, ~!f4, Off
Hotkey, ~LButton, Off

При SetHotkeys(KeyList, "")

Ну и замудренный скрипт у вас получился

Правильно, давайте и впредь выходить из цикла с помошью goto.

Re: AHK: A_PriorKey не всегда запоминает нажатые кнопки

2012-12-18T16:11:18Z

Если честно, то непонятно почти все.

KeyList := {winTitle: winTitle, Hotkeys: ["~Esc", "~!f4", "~LButton"]}

- это как такую конструкцию понять?

SetHotkeys(KeyList, "WindowClose")

- почему кавычки, что значит эта буквальная строка? Типа GoSub?

SetHotkeys(KeyList, label) {
    if KeyList.winTitle
        Hotkey, IfWinActive, % KeyList.winTitle

    for index, key in KeyList.Hotkeys
        Hotkey, %key%, % label? label : "Off", % label? "On" : ""
}

вот это все непонятно.

Спасибо. Ну и замудренный скрипт у вас получился.

Re: AHK: A_PriorKey не всегда запоминает нажатые кнопки

2012-12-18T05:00:35Z


; подразумевается, что для выбора пресета будет произведён хотя бы один клик.
; иначе нужно обрабатывать все пути закрытия окна.

winTitle := "New Sequence"
classNN := "Edit4"
KeyList := {winTitle: winTitle, Hotkeys: ["~Esc", "~!f4", "~LButton"]}
CloseButton := {x0: 123, x1: 234, y0: 345, y1: 567} ; координаты кнопки закрытия окна
CancelButton := {x0: 123, x1: 234, y0: 345, y1: 567} ; координаты кнопки отмены

loop
{
    WinWaitActive, %winTitle%
    SetHotkeys(KeyList, "WindowClose")
    WinWaitClose, %winTitle%
    SetHotkeys(KeyList, "")
}
until !windowClosed

MsgBox %winTitle%`nтекст :`n`n%text%
return

WindowClose:
    ControlGetText, text, %classNN% , %winTitle%
    windowClosed := (A_ThisHotkey ~= "LButton")? ClickInRect(CloseButton) || ClickInRect(CancelButton) : true
    return

SetHotkeys(KeyList, label) {
    if KeyList.winTitle
        Hotkey, IfWinActive, % KeyList.winTitle

    for index, key in KeyList.Hotkeys
        Hotkey, %key%, % label? label : "Off", % label? "On" : ""
}

ClickInRect(Rect) {
    CoordMode, Mouse, Relative
    MouseGetPos, x, y
    return x > Rect.x0 && x < Rect.x1 && y > Rect.y0 && y < Rect.y1
}

Непонятно — спрашивайте, прокомментирую.

Re: AHK: A_PriorKey не всегда запоминает нажатые кнопки

2012-12-17T16:24:41Z

Irbis, с флагом тоже пробовал - результат такой же.
Мне кажется, что A_PriorKey что срабатывание хоткиев проходят по одному алгоритму.

Что мешает ждать клавиши с помощью Input, а клики в нужных (или ненужных) координатах отлавливать иным способом?

Ну вот с Input я так до конца и не разобрался, потому как цикл останавливается на этом инпуте и ждет нажатия кнопки.
А как ловить паралельно нажатия мыши?

Re: AHK: A_PriorKey не всегда запоминает нажатые кнопки

2012-12-17T16:06:00Z

Что мешает ждать клавиши с помощью Input, а клики в нужных (или ненужных) координатах отлавливать иным способом?

Re: AHK: A_PriorKey не всегда запоминает нажатые кнопки

2012-12-17T16:00:37Z

Так команда Input же ждет пока не произойдет нажатие определенной клавиши.
А мне надо, чтобы цикл заканчивался не только по нажатию enter, но и по нажатию кнопки мышки.

Re: AHK: A_PriorKey не всегда запоминает нажатые кнопки

2012-12-17T15:53:33Z

Попробуй вместо использования A_PriorKey менять флаг (Achtung ), повесив на Esc хоткей:

+ открыть спойлер

#SingleInstance force
#InstallKeybdHook
#InstallMouseHook
Start:
loop
{
   IfWinActive, New Sequence
   {          
      Achtung := 0
      loop
      {
         GetKeyState, state, LButton
         if state = D
            MouseGetPos, xpos, ypos
         NameOld := Name
         ControlGetText, Name, Edit4, New Sequence
         IfWinNotExist, New Sequence
            break
      }
      if Achtung || (A_PriorKey = "LButton") && (xpos > 590) || (A_PriorKey = "LButton") && (ypos < 60)
         Continue
      SplashImage,,  w120 B1  ,, Please Wait...
      If Name =
         Name := NameOld
      StringReplace, Name, Name, `r`n, `n, All
      Send, ^{vk5A}^{vk49} ; Crtl+z Ctrl+i 
.......


~Escape::
~!F4::
Achtung := 1
Return

Re: AHK: A_PriorKey не всегда запоминает нажатые кнопки

2012-12-17T15:47:41Z

Input попробовали, но использовать решили A_priorKey, A_priorKey надежды не оправдал, но …
Что-то я не пойму ход ваших мыслей

Re: AHK: A_PriorKey не всегда запоминает нажатые кнопки

2012-12-17T15:29:04Z

Да, с Input я тоже вначале пробовал.
Но проблема в том, что «не отменять» его можно не только нажатием Enter,
но еще и нажатием мыши на ОК либо нажатием 2 раза мышью на любой из пресетов.

Re: AHK: A_PriorKey не всегда запоминает нажатые кнопки

2012-12-17T15:09:45Z

которое можно закрыть (отменить) с помощью esc, Alt+f4, или нажав на кнопку cancel или нажав на крестик.

Сответственно «не отменять» его можно лишь нажатием Enter?

Правильнее отслеживать событие которое явно указывает на необходимость продолжать, ведь окно можно «убрать» иными способами, учёт которых не имеет смысла.

Пример:

winTitle := "ahk_class Notepad"
classNN := "Edit1"

loop {
    WinWaitActive, %winTitle%
    ControlGetText, Name, %classNN% , %winTitle%
    Input, singleKey, v l1, {Enter}
}
until ErrorLevel = "EndKey:Enter"

MsgBox мы дождались нажатия Enter в окне %winTitle%`nтекст в окне перед нажатием Enter:`n`n%Name%

Re: AHK: A_PriorKey не всегда запоминает нажатые кнопки

2012-12-17T13:47:43Z

А лучший вариант можно озвучить?
А то я знаю только еще один.
http://www.autohotkey.com/docs/FAQ.htm#repeat

Re: AHK: A_PriorKey не всегда запоминает нажатые кнопки

2012-12-17T13:41:39Z

А в какую сторону пересматривать-то?

В строну отказа от A_PriorKey.