Серый форум — AHK: Как извлечь текст из контрола?

Re: AHK: Как извлечь текст из контрола?

null@example.com (Pokerist) — Tue, 23 Jul 2013 15:17:15 +0000

Перенёс в отдельную тему.

Re: AHK: Как извлечь текст из контрола?

null@example.com (teadrinker) — Sat, 30 Mar 2013 19:58:54 +0000

Так можно попробовать:

ControlGet, OutputVar, Hwnd,, Internet Explorer_Server1, ahk_class IEFrame
if (OutputVar = "")
{
   ToolTip, Контрол не найден!
   return
}

msg := DllCall("RegisterWindowMessage", Str, "WM_HTML_GETOBJECT")
SendMessage, msg,,,, ahk_id %OutputVar%

DllCall("oleacc\ObjectFromLresult", Ptr, ErrorLevel, Ptr, 0, Ptr, 0, PtrP, pdoc)
        
HTMLDocument := ComObjEnwrap(pdoc)
ObjRelease(pdoc)

if !IsObject(HTMLDocument)
   return

var := HTMLDocument.body.innerText
HTMLDocument := ""

Re: AHK: Как извлечь текст из контрола?

null@example.com (Pokerist) — Sat, 30 Mar 2013 19:14:03 +0000

Ничего с этим сделать нельзя?

Re: AHK: Как извлечь текст из контрола?

null@example.com (Pokerist) — Sun, 24 Mar 2013 16:24:27 +0000

Всё равно сбоит. Предупреждение :

Отказано в доступе ..."файл скрипта"...
....
Specificaty: body

В строке
if(HTMLDocument&&HTMLDocument.body)

Re: AHK: Как извлечь текст из контрола?

null@example.com (Александр_) — Sat, 23 Mar 2013 22:11:25 +0000

Pokerist пишет:

Можно как-то предусмотреть эти обстоятельства и предотвратить остановку работы скрипта?

ну дык как всегда:

if(HTMLDocument&&HTMLDocument.body) 
{
    var := HTMLDocument.body.innerText
    HTMLDocument := ""
}
else
    msgbox error

Re: AHK: Как извлечь текст из контрола?

null@example.com (Pokerist) — Sat, 23 Mar 2013 21:54:32 +0000

Появился вопрос. Иногда, при закрытии окна, работа скрипта срывается и появляется сообщение "No Valid COM Object!" с указанием на предпоследнюю строку:

ControlGet, OutputVar, Hwnd,, Internet Explorer_Server1, ahk_class IEFrame
if (OutputVar = "")
{
   ToolTip, Контрол не найден!
   return
}

msg := DllCall("RegisterWindowMessage", Str, "WM_HTML_GETOBJECT")
SendMessage, msg,,,, ahk_id %OutputVar%

DllCall("oleacc\ObjectFromLresult", Ptr, ErrorLevel, Ptr, 0, Ptr, 0, PtrP, pdoc)
        
HTMLDocument := ComObjEnwrap(pdoc)
ObjRelease(pdoc)

var := HTMLDocument.body.innerText
HTMLDocument := ""

Можно как-то предусмотреть эти обстоятельства и предотвратить остановку работы скрипта?

Re: AHK: Как извлечь текст из контрола?

null@example.com (Pokerist) — Thu, 21 Feb 2013 07:43:38 +0000

serzh82saratov пишет:

Осталось понять в чём же тут принципиальная разница между
В зависимости от раскладки. Никогда не пишите буквенно символьные клавиши по их именам. Замечал что само действие {CtrlDown} не всегда надёжно, видимо ос неуспевает решить что Ctrl удержан а уже послана след. кнопка, а ^{vk41} посылает сразу нажатие с модификатором.
Хотя Send, {CtrlDown}{vk41}{CtrlUp} вполне работает.

Во втором случае OC "успевает решить, что Ctrl удержан", а в первом нет? Странно как-то :-/

Re: AHK: Как извлечь текст из контрола?

null@example.com (serzh82saratov) — Wed, 20 Feb 2013 20:21:38 +0000

Pokerist пишет:
С кодами я знаком. Почему работает по разному не понимаю.

Вы про это: ^ и {CtrlDown} , или про это {vk41} и {A}.

OFF:

teadrinker пишет:
Если это действительно контрол Internet Explorer_Server, то примерно так, только указать верное название контрола и окна.

Мда, с памятью у меня беда...

Re: AHK: Как извлечь текст из контрола?

null@example.com (Pokerist) — Wed, 20 Feb 2013 17:18:43 +0000

teadrinker пишет:

Если это действительно контрол Internet Explorer_Server, то примерно так, только указать верное название контрола и окна.

Раз "Window Spy" сказал, что это он, то так оно и есть!
Огромное спасибо! Сработало великолепно! Не нужны клики, не нужна даже видимость самого контрола! Всё великолепно читается без малейших сбоев.

Re: AHK: Как извлечь текст из контрола?

null@example.com (teadrinker) — Wed, 20 Feb 2013 17:05:17 +0000

Pokerist пишет:

Не могу с помощью скрипта получить текст из контрола.

Если это действительно контрол Internet Explorer_Server, то примерно так, только указать верное название контрола и окна.

Re: AHK: Как извлечь текст из контрола?

null@example.com (Pokerist) — Wed, 20 Feb 2013 16:02:46 +0000

С кодами я знаком. Почему работает по разному не понимаю.

Re: AHK: Как извлечь текст из контрола?

null@example.com (serzh82saratov) — Wed, 20 Feb 2013 15:40:49 +0000

Вот лично вам скрипт для определения кнопок с готовым синтаксисом

Re: AHK: Как извлечь текст из контрола?

null@example.com (serzh82saratov) — Wed, 20 Feb 2013 15:36:57 +0000

Осталось понять в чём же тут принципиальная разница между

В зависимости от раскладки. Никогда не пишите буквенно символьные клавиши по их именам. Замечал что само действие {CtrlDown} не всегда надёжно, видимо ос неуспевает решить что Ctrl удержан а уже послана след. кнопка, а ^{vk41} посылает сразу нажатие с модификатором.
Хотя Send, {CtrlDown}{vk41}{CtrlUp} вполне работает.

Re: AHK: Как извлечь текст из контрола?

null@example.com (Pokerist) — Wed, 20 Feb 2013 15:26:35 +0000

serzh82saratov пишет:

или надёжнее:


clipboard := ""
 Loop { 
    ControlFocus, Internet Explorer_Server2, ahk_class PTIODEVICE
     ControlGetFocus, Focus, ahk_class PTIODEVICE
    iF ( Focus <> "Internet Explorer_Server2" )
        Continue 
    Send, ^{vk41}  ;  "A"
    Send, ^{vk43}  ;  "C"
    } Until clipboard
 ToolTip, %clipboard%
 return

Не срабатывает если не кликнуть этот контрол.

Но Вы всё равно помогли! Спасибо!

Вот так вполне себе работает:

ToolTip,
clipboard := ""
Click x, y
Send, ^{vk41}  ;  "A"
Send, ^{vk43}  ;  "C"
ClipWait, 1
;SoundBeep
ToolTip, %clipboard%

Осталось понять в чём же тут принципиальная разница между

Send, ^{vk41}

Send, {CtrlDown}{A}{CtrlUp}

Re: AHK: Как извлечь текст из контрола?

null@example.com (serzh82saratov) — Wed, 20 Feb 2013 14:17:52 +0000


clipboard := ""
 Loop
    {  ControlFocus, Internet Explorer_Server2, A
    Send, ^{vk41}  ;  "A"
    Send, ^{vk43}  ;  "C"
    } Until clipboard
 ToolTip, %clipboard%
 return

или надёжнее:


clipboard := ""
 Loop { 
    ControlFocus, Internet Explorer_Server2, ahk_class PTIODEVICE
     ControlGetFocus, Focus, ahk_class PTIODEVICE
    iF ( Focus <> "Internet Explorer_Server2" )
        Continue 
    Send, ^{vk41}  ;  "A"
    Send, ^{vk43}  ;  "C"
    } Until clipboard
 ToolTip, %clipboard%
 return