Серый форум — AHK: Imagesearch, нужна помощь в отладке скрипта

Re: AHK: Imagesearch, нужна помощь в отладке скрипта

2013-02-27T11:33:09Z

Ro имеет защиту от ахк. Обходится путем активации другого окна, например нажатием клавиши windows. А далее уже работать с экраном.

Re: AHK: Imagesearch, нужна помощь в отладке скрипта

2013-02-24T19:01:33Z

Еще раз хочу сказать большое спасибо Вам Grey за терпение и желание помочь! Зерно истины найдено, хоть и немного окольным путем. Натолкнули на него Ваши слова, о запуске приложения в оконном режиме. Если коротко - ни один из скриптов не работает правильно, если приложение запущенно в полноэкранном режиме (подозреваю что есть косяки в самом приложении, по части разрешения при полноэкранном режиме). В оконноме режиме, при различных разрешениях, все работает великолепно. Даже вот этот простейший вариант(на нем кстати, и остановился):

f5::
Loop
{
ImageSearch, Start_mark_X, Start_mark_Y, 0, 0, 1600, 900, чат 1600-900.png
if ErrorLevel = 2
    {
        MsgBox Нет картинки, с образцом изображения для поиска!
    }
else if ErrorLevel = 1
    {
        SoundPlay, zoidberg.mp3
        Sleep 5000
    }
}
return

f6::
pause

Re: AHK: Imagesearch, нужна помощь в отладке скрипта

2013-02-24T14:08:35Z

Выставьте в настройках родное разрешение и оконный режим, активируйте при фокусе на приложении код (F12, далее не обязательно чтобы фокус был на этом окне, это только для того, чтобы код развернул окно на весь экран, запомнил размеры и стиль, по завершению работы (Esc или выход в контекстном меню) окно восстановит свой прежний вид).

CoordMode, Pixel
sndPath:="c:\Windows\Media\", path:="c:\GyJe.png", tint:="*"tSize:=60 . A_Space

F12:: ; I/O
   If !hWnd
   {
      WinSet, AlwaysOnTop, Off, % "ahk_id"hWnd:=WinActive("A")
      WinGetPos, x, y, w, h, % "ahk_id"hWnd
      WinMove, % "ahk_id"hWnd,, 0, 0, A_ScreenWidth, A_ScreenHeight
      WinSet, Style, -0xC00000, % "ahk_id"hWnd
   }
   Loop, % (isEnable:=!isEnable) ? 1:2
      SoundBeep, 12500, 100
   SetTimer, SomeLabel, Off
   isState:=""
   KeyWait, % A_ThisHotkey
   Return

~Esc:: ; выход по удержанию, инче родная функция клавиши
   KeyWait, Esc
   If A_TimeSinceThisHotkey>750 ; величина удержания
   {
      WinMove, % "ahk_id"hWnd,, x, y, w, h
      WinSet, Style, +0xC00000, % "ahk_id"hWnd
      ExitApp
   }
   Return

#If isState
   WheelUp::
   WheelDown::
      If % A_PriorHotkey=A_ThisHotkey And A_TimeSincePriorHotkey<50
         Return
      TrayTip,, % tint:="*"(A_ThisHotkey~="Up" ? tSize+=5:tSize-=5)" "
      Return

#If isEnable
   F4::
      SetTimer, SomeLabel, % (isState:=!isState) ? 1000:"Off"
      checkup:="started"
      Loop, % isState ? 1:2
         SoundBeep, 7500, 100
      KeyWait, % A_ThisHotkey
      Return

SomeLabel:
   ImageSearch,,, 0, 0, A_ScreenWidth, A_ScreenHeight, % tint . path
   If ErrorLevel
   {
      If ErrorLevel=1
      {
         If % checkup=1 Or checkup="started"
         {
            SoundPlay, % sndPath "ding.wav", 1
            checkup:=2
         }
      }
      Else
      {
         SetTimer,, Off
         MsgBox, 262192
               , % "An error occured"
               , % "Failure to open the image file`nor a badly formatted option!"
         ExitApp
      }
   }
   Else
   {
      If % checkup=2 Or checkup="started"
      {
         SoundPlay, % sndPath "tada.wav", 1
         checkup:=1
      }
   }
   Return

elektrovenik пишет:

Мне хотелось бы сделать так, чтобы при изменении едицы, проигрывался звуковой файл.

Вы можете вырезать искомое изображение с захватом в нём к примеру только чат (1/.

Re: AHK: Imagesearch, нужна помощь в отладке скрипта

2013-02-24T12:19:19Z

Grey пишет:

Приложение полноэкранное?

Да. Но есть возможность использования в оконном режиме. Я очень рад и благодарен, что Вы желаете помочь мне, в решении поставленной задачи. Предоставлю больше материала. Вот то окно, с которым используется скрипт + данные которые может предоставить Auto It.

Ключевое изображение для работы скрипта :

Еще точнее, я вырезал именно этот кусок
Именно это изображение используется как искомое. Мне хотелось бы сделать так, чтобы при изменении едицы, проигрывался звуковой файл. Как уже писал выше, когда прогоняю скрип по скриншоту - работает все отлично, когда тоже самое пытаюсь делать в окне приложения - скрипт не находит искомого изображения в окне, хотя разумеется оно там присутствует. Ваш последний скрипт, после регулировки величины оттенка от 150 и выше, начинает проигрывать аудиофайл, соотвествующий нахождению искомого изображения, но увы даже тогда, когда этого изображения там нет.

Re: AHK: Imagesearch, нужна помощь в отладке скрипта

2013-02-24T09:07:56Z

Приложение полноэкранное?

Re: AHK: Imagesearch, нужна помощь в отладке скрипта

2013-02-24T08:20:25Z

Спасибо большое Вам Grey за участие. Ваш скрипт работает. Прихожу к выводу, что проблема заключается в самом приложении, ибо когда делаю скриншоты из него же - на скриншоте находит изменение в изображении отлично. Когда пытаюсь тоже самое сделать в приложении - снова получается чушь.

Re: AHK: Imagesearch, нужна помощь в отладке скрипта

2013-02-23T22:25:50Z

В общем у меня работает:

CoordMode, Pixel
sndPath:="c:\Windows\Media\", path:="c:\GyJe.png", tint:="*"tSize:=60 . A_Space

#If isState
   WheelUp::
   WheelDown::
      If % A_PriorHotkey=A_ThisHotkey And A_TimeSincePriorHotkey<50
         Return
      TrayTip,, % tint:="*"(A_ThisHotkey~="Up" ? tSize+=5:tSize-=5)" "
      Return
#If

F4::
   SetTimer, SomeLabel, % (isState:=!isState) ? 1000:"Off"
   checkup:="started"
   Loop, % isState ? 1:2
      SoundBeep, 7500, 100
   KeyWait, % A_ThisHotkey
   Return

SomeLabel:
   ImageSearch,,, 0, 0, A_ScreenWidth, A_ScreenHeight, % tint . path
   If ErrorLevel
   {
      If ErrorLevel=1
      {
         If % checkup=1 Or checkup="started"
         {
            SoundPlay, % sndPath "ding.wav", 1
            checkup:=2
         }
      }
      Else
      {
         SetTimer,, Off
         MsgBox, 262192
               , % "An error occured"
               , % "Failure to open the image file`nor a badly formatted option!"
         ExitApp
      }
   }
   Else
   {
      If % checkup=2 Or checkup="started"
      {
         SoundPlay, % sndPath "tada.wav", 1
         checkup:=1
      }
   }
   Return

Re: AHK: Imagesearch, нужна помощь в отладке скрипта

2013-02-22T17:36:11Z

Grey пишет:

Подставте свои данные, и поищите нужную величину оттенка скролом мыши.

sndPath:="c:\Windows\Media\", path:="C:\Users\Layzerk\Pictures\50.bmp", tint:="*"tSize:=120 . A_Space

WheelUp::
WheelDown::
   If % A_PriorHotkey=A_ThisHotkey And A_TimeSincePriorHotkey<150
      Return
   TrayTip,, % tint:="*"(A_ThisHotkey~="Up" ? tSize+=5:tSize-=5) . A_Space
   Return

F5::
   Loop
   {
      WinGetPos,,, w, h, A
      ImageSearch, outX, outY, 0, 0, 1600, 900, % tint . path
      If ErrorLevel
      {
         If ErrorLevel=1
            SoundPlay, % sndPath "ding.wav", 1
         Else
         {
            MsgBox, 262192, % "An error occured"
                  , % "Failure to open the image file`nor a badly formatted option!"
            ExitApp
         }
      }
      Else
      {
         SoundPlay, % sndPath "tada.wav", 1
      }
;       Sleep, 1000
   }
   Return

F6::Pause

Сделал, но идет постоянное проигрывание ding.wav, манипуляции скролом не дают никакого эффекта. Подскажите что не так?

Re: AHK: Imagesearch, нужна помощь в отладке скрипта

2013-02-22T17:34:12Z

Malcev пишет:

Имеется изображение на экране, положения которого могут быть различны. Мне необходимо, чтобы скрипт отслеживал изменения в данном изображении и когда таковые появляются, 
Может тогда стоит сравнивать найденные координаты этого изображения и если они изменились, то подавать сигнал.

Идея интересная, внесу немного конкретики. Изображение для поиска . Мне хотелось бы осуществить проигрывание звукового файла, когда цифра 1 будет меняться. Как лучше это сделать - я не имею понятия. Мне кажется ImageSearch наиболее подходящее. Осуществление через PixelSearch или PixelGetColor считаю очень сложным, ибо нужно отследить неизменные пиксели в единичке, что слишком крапотливо и не гарантируется, что в любом сегменте другого числа не будет пикселя того же цвета в той же координате.

Re: AHK: Imagesearch, нужна помощь в отладке скрипта

2013-02-22T16:37:44Z

Имеется изображение на экране, положения которого могут быть различны. Мне необходимо, чтобы скрипт отслеживал изменения в данном изображении и когда таковые появляются,

Может тогда стоит сравнивать найденные координаты этого изображения и если они изменились, то подавать сигнал.

Re: AHK: Imagesearch, нужна помощь в отладке скрипта

2013-02-22T15:12:06Z

Grey пишет:

@ТС Не знаю как Вы ищите без использования опции касаемо оттенков.

Ув. Grey, в отличии от Вас, к великому моему сожалению, я не разбираюсь в замечательных возможностях ahk так как Вы, в первом посте я об этом написал. На ваш форум я обращаюсь за помощью, а не критикой моих попыток, основанных на весьма скудных познаниях, выполнить какую-то желаему задумку. Тем не менее я бьюсь до последнего сам, порой разбираюсь в прямом смысле слова с утра до ночи, так же переводя англоязычные статьи и пытаясь найти крупицы истины, не желая беспокоить кого-либо без повода и если уже я захожу в тупик, тогда обращаюсь за помощью к данному форуму.
Я писал, что данный скрип я делал на основе уже имеющихся и работоспособных, соотвественно и то что вы видели - вытекало из них. Проверка скрипта на скрине( т.е открытие скриншота в любом приложении для просмотра и прогонка скрипта по нему) - результат 100%, никаких сбоев. Когда этот же скрипт задействуется уже при запущенной u r p e, и изображение на экране подобно скриншоту, происходят лжепроигрывания, о которых я писал.

Re: AHK: Imagesearch, нужна помощь в отладке скрипта

2013-02-22T15:08:04Z

creature.ws пишет:

Не нашел в вашей теме ни одного вопроса. «Мне необходимо» — главный вопрос?

Jokero пишет:

Здравствуйте. Возникла потребность создать скрипт, который будет кликать по определенной области в браузере, но область каждый раз меняется. Поэтому решил использовать тег imagesearch, но увы, он не работает. Вот сам код:
CoordMode Pixel
^Z::
   Loop
      {
         Imagesearch, x, y, %x%, %y%, %a_screenwidth%, %a_screenheight%, %a_scriptdir%\test.bmp
         If Errorlevel = 0
         MouseClick, Left, X, Y
      }

После подобной постановки вопроса, человеку отлично помогли и никто не возмущался.
creature.ws Вы видимо один, такой щепетильный?

Re: AHK: Imagesearch, нужна помощь в отладке скрипта

2013-02-22T11:14:01Z

@ТС Не знаю как Вы ищите без использования опции касаемо оттенков, вот так я к примеру нахожу искомое в окне с подобными:

sndPath:="c:\Windows\Media\", path:="c:\sarcasm.png", tint:="*"tSize:=120 . A_Space

WheelUp::
WheelDown::
   If % A_PriorHotkey=A_ThisHotkey And A_TimeSincePriorHotkey<150
      Return
   TrayTip,, % tint:="*"(A_ThisHotkey~="Up" ? tSize+=5:tSize-=5) . A_Space
   Return

F4::
   Loop
   {
      WinGetPos,,, w, h, A
      ImageSearch, outX, outY, 0, 0, w, h, % tint . path
      If ErrorLevel
      {
         If ErrorLevel=1
            SoundPlay, % sndPath "ding.wav", 1
         Else
         {
            MsgBox, 262192, % "An error occured"
                  , % "Failure to open the image file`nor a badly formatted option!"
            ExitApp
         }
      }
      Else
      {
         MouseMove, outX, outY
         SoundPlay, % sndPath "tada.wav", 1
      }
;       Sleep, 1000
   }
   Return

F6::Pause

Подставте свои данные, и поищите нужную величину оттенка скролом мыши.

Re: AHK: Imagesearch, нужна помощь в отладке скрипта

2013-02-22T09:44:50Z

Не нашел в вашей теме ни одного вопроса. «Мне необходимо» — главный вопрос?

Re: AHK: Imagesearch, нужна помощь в отладке скрипта

2013-02-22T05:10:24Z

Спасибо, что откликнулись Grey, стало немного понятнее. Хотелось бы еще, по возможности, получить помощь по главному вопросу моей темы.