Серый форум — AHK: Заблокировать для ввода только часть Gui

Re: AHK: Заблокировать для ввода только часть Gui

2013-11-12T18:30:57Z

Можно заблокировать таб, и заменить "клоном" контрола который не надо блокировать в этой вкладке:


Gui, +HWNDhGui -DPIScale 
Gui, Color, FF8C00 
Gui, Add, Tab2, w800 h600 vTab, 1|2
Gui, Tab, 1
Gui, Add, ListBox, r19, 123|123|123|123|123|123|123|123|123|123|123|123|123|123|123|123|123|123|123  
Gui, Add, GroupBox, x222 y222 w444 h222  
Gui, Add, Button, xp+122 yp+180 w200 h35 gButton vButton hwndhButton, Блокировать
Gui, Show
Return

Button:
    GuiControl,, Button, % ButText := (T := !T) ? "Разблокировать" : "Блокировать"
    GuiControlGet, Pos, Pos, Button    
    GuiControl, -v, Button 
    GuiControl, Disable%T%, Tab 
    DllCall("DestroyWindow", "Ptr", hButton) 
    Gui, Tab, 1
    Gui, Add, Button, x%Posx% y%Posy% w%Posw% h%Posh% vButton gButton hwndhButton, %ButText%
    Return
    
GuiEscape:
GuiClose:
    ExitApp

Выглядит не очень.

-----

Скрывать и показывать большие группы контролов лучше, используя другой таб в нужной вкладке первого таба (возможно заблокированного). При переключении вкладок первого таба скрывать\показывать второй таб:


Gui, +HWNDhGui -DPIScale 
Gui, Color, FF8C00 
Gui, Add, Tab2, w800 h600 vTab1 gTab1, 1|2|3
Gui, Tab, 1 
Gui, Add, ListBox, r19, 123|123|123|123|123|123|123|123|123|123|123|123|123|123|123|123|123|123|123  

Gui, Add, Tab2, xp+222 yp+222 w0 h0 vTab2, | 
Gui, Add, GroupBox, w444 h222   
Gui, Add, Button, xp+122 yp+180 w200 h35 gButton vButton, Блокировать
Gui, Show
Return

Button:
    GuiControl,, Button, % (T := !T) ? "Разблокировать" : "Блокировать" 
    GuiControl, Disable%T%, Tab1
    Return
    
Tab1:
    GuiControlGet, Tab1 
    GuiControl, % "Hide" (Tab1 != 1), Tab2 
    Return

GuiEscape:
GuiClose:
    ExitApp

Re: AHK: Заблокировать для ввода только часть Gui

2013-03-28T17:27:08Z

Я вот тут подумал, а возможно ли контрол созданный для какой-то конкретной вкладки таба, на время сделать независимым от этой вкладки?

Re: AHK: Заблокировать для ввода только часть Gui

2013-03-24T16:56:02Z

Если кнопка будет внутри заблокированного Tab, естественно, она окажется заблокированной. Поэтому я и не понял Вашего стремления туда её засунуть.

serzh82saratov пишет:

Как понять визуально?
Там будет несколько элементов которые должны работать, остальные заблокированы в том числе нельзя чтоб срабатывал ТАБ. Элементы должны быть все размещены на табе, т.к. Таб на всё окно.

Визуально - это так:

#SingleInstance, Force
Gui, Add, Button,  x300 y500, Блокировать
Gui, Add, Button,  x300 y550, Разблокировать
Gui, Add, Tab, x10 y10 w500 h550 vMyTab, Основные|Вид|Видимость|Установки
Gui, Add, GroupBox, w444 h222 
Gui, Add, Button,  w200 h35, 111
Gui, Add, Button,  w200 h35, 222
Gui, Add, Button,  w200 h35, 333
Gui, Show
Return

ButtonБлокировать:
GUIControl, Disable, MyTab
Return

ButtonРазблокировать:
GUIControl, Enable, MyTab
Return

Esc::
GuiClose:
ExitApp

Кнопки не принадлежат вкладке элемента Tab и расположены поверх него. Однако, я не испытывал такой способ в полной мере. На XP работает без глюков.

Re: AHK: Заблокировать для ввода только часть Gui

2013-03-24T14:18:44Z

А я всё никак не пойму, зачем кнопку блокировки размещать в самом элементе "Tab".

потому что больше её разместить негде.

Вам нужно, чтобы она там была визуально, или действительно размещалась внутри вкладки элемента "Tab"?

Как понять визуально?
Там будет несколько элементов которые должны работать, остальные заблокированы в том числе нельзя чтоб срабатывал ТАБ. Элементы должны быть все размещены на табе, т.к. Таб на всё окно.

Re: AHK: Заблокировать для ввода только часть Gui

2013-03-24T14:09:48Z

Вы хотите заблокировать сразу много элементов управления (контролов) нажатием одной кнопки в окне GUI. Сделать это напрямую почему-то тяжело/невозможно. Поэтому Вы стремитесь разместить контролы на вкладке элемента "Tab", чтобы можно было их заблокировать одним махом.

А я всё никак не пойму, зачем кнопку блокировки размещать в самом элементе "Tab". Какой от этого прок? И вообще, Вам нужно, чтобы она там была визуально, или действительно размещалась внутри вкладки элемента "Tab"?

Re: AHK: Заблокировать для ввода только часть Gui

2013-03-24T13:13:19Z

ypppu
Да вы так сильно не напрягайтесь, если не смогли понять суть задачи.
У меня тоже такая картинка есть в коллекции.

Re: AHK: Заблокировать для ввода только часть Gui

2013-03-24T13:06:44Z

serzh82saratov пишет:

На табе должна находится кнопка!

Re: AHK: Заблокировать для ввода только часть Gui

2013-03-24T10:38:56Z

На табе должна находится кнопка!
И ещё DropDownList и кнопка.

Re: AHK: Заблокировать для ввода только часть Gui

2013-03-24T10:33:48Z

serzh82saratov пишет:

Чтобы на вашем примере кнопка "Блокировать" оставалась неблокированной

Вуаля!

#SingleInstance, Force
Gui, Add, Button,  , Блокировать
Gui, Add, Button,  , Разблокировать
Gui, Add, Tab, w500 h550 vMyTab, Основные|Вид|Видимость|Установки
Gui, Add, GroupBox, w444 h222 
Gui, Add, Button,  w200 h35, 111
Gui, Add, Button,  w200 h35, 222
Gui, Add, Button,  w200 h35, 333
Gui, Show
Return

ButtonБлокировать:
GUIControl, Disable, MyTab
Return

ButtonРазблокировать:
GUIControl, Enable, MyTab
Return

Esc::
GuiClose:
ExitApp

Re: AHK: Заблокировать для ввода только часть Gui

2013-03-24T10:11:30Z

Чтобы на вашем примере кнопка "Блокировать" оставалась неблокированной

Re: AHK: Заблокировать для ввода только часть Gui

2013-03-24T10:05:39Z

Теперь уже не представляю, чего Вы хотите... В первом сообщении кнопка "Заблокировать" находится внутри вкладки, которую она блокирует. Неудивительно, что при этом блокируется сама кнопка.

Сформулируйте вопрос чётко и однозначно.

Re: AHK: Заблокировать для ввода только часть Gui

2013-03-24T08:58:19Z

ypppu пишет:

Я дал готовый код на заданный вопрос.

Ну GUIControl, Disable, MyTab конечно не стандартное решение

ypppu пишет:

Контролами можно управлять командой GUIControl.

Так как их разблокировать для пользователя при заблокированном Tab`е?

Re: AHK: Заблокировать для ввода только часть Gui

2013-03-24T08:52:25Z

serzh82saratov пишет:

ypppu пишет:
Ну, это можно (c)
Но не нужно. Как мне после этого управлять нужными мне контролами?

Как это - не нужно? Я дал готовый код на заданный вопрос.
Контролами можно управлять командой GUIControl.

Re: AHK: Заблокировать для ввода только часть Gui

2013-03-24T08:40:59Z

ypppu пишет:

Ну, это можно (c)

Но не нужно. Как мне после этого управлять нужными мне контролами?

Re: AHK: Заблокировать для ввода только часть Gui

2013-03-24T08:36:30Z

serzh82saratov пишет:

ypppu пишет:
Так это догадки насчёт быстродейтвия или Вы проверяли?
Хорошо, как отключить Таб?

Ну, это можно (c)

#SingleInstance, Force
Gui, Add, Tab, w500 h550 vMyTab, Основные|Вид|Видимость|Установки
Gui, Add, GroupBox, x22 y22 w444 h222 
Gui, Add, Button,  w200 h35, 111
Gui, Add, Button,  w200 h35 , 222
Gui, Add, Button,  w200 h35 , 333
Gui, Add, Button, xp+122 yp+180 w200 h35 gButton vButton, Блокировать
Gui, Show
Return

Button:
GUIControl, Disable, MyTab
Return

Esc::
GuiClose:
ExitApp