Серый форум — AHK: Копирование новых либо измененных файлов и директорий

Re: AHK: Копирование новых либо измененных файлов и директорий

null@example.com (serzh82saratov) — Sun, 12 May 2013 06:38:44 +0000

Так я и непонял. Что-то связанное с рекурсией функции.
Так будет работать точно:


GetDriveByLabel(pLabel, Repeat = 1) {  
    Loop % Repeat
    {
        DriveGet, List, List
        Loop, Parse, List
        {  
            DriveGet, Label, Label, %A_LoopField%: 
            If ( Label = pLabel ) 
                Return A_LoopField ":"  
        }   
        sleep, 1000
    }
}

Re: AHK: Копирование новых либо измененных файлов и директорий

null@example.com (serzh82saratov) — Sat, 11 May 2013 19:12:45 +0000

Malcev
Я в замешательстве.
Никак не могу понять почему в функции GetDriveByLabel на первой итерации оператор вызвавший функцию получает значение а в остальных итерациях остаётся пустым. Хотя при отладке внутри функции всё также верно.

Re: AHK: Копирование новых либо измененных файлов и директорий

null@example.com (Malcev) — Sat, 11 May 2013 14:44:00 +0000

serzh82saratov, код из 15 сообщения работает неверно.
Запускал скрипт, потом подключал усб - в итоге получал ошибку.
Мой же из 14 сообщения работает корректно.

Re: AHK: Копирование новых либо измененных файлов и директорий

null@example.com (serzh82saratov) — Mon, 29 Apr 2013 19:16:33 +0000

Офф:

без лишних "полуночных" присваиваний.

loop, 30   ; даем 30 секунд на распознование диска
{
   if Z!=:   ; если буква есть, а не одно двоеточие
      break
   sleep, 1000
   n++
}

30 кратная проверка переменной которая всё равно не изменится, конечно доставила
без обид.

Re: AHK: Копирование новых либо измененных файлов и директорий

null@example.com (Malcev) — Mon, 29 Apr 2013 09:36:42 +0000

Да, RunWait - работает.
Код стал намного причесаннее, без лишних "полуночных" присваиваний.
Спасибо!

Re: AHK: Копирование новых либо измененных файлов и директорий

null@example.com (serzh82saratov) — Mon, 29 Apr 2013 03:12:42 +0000

del

Re: AHK: Копирование новых либо измененных файлов и директорий

null@example.com (serzh82saratov) — Mon, 29 Apr 2013 03:02:30 +0000

Справка пишет:

В отличие от Run, RunWait будет ждать завершения запущенной программы, после чего в ErrorLevel будет сохранён код выхода программы (32-битное число со знаком). Некоторые программы возвращают этот код сразу же, несмотря на то, что продолжают выполняться; эти программы порождают другой процесс.

Re: AHK: Копирование новых либо измененных файлов и директорий

null@example.com (serzh82saratov) — Mon, 29 Apr 2013 02:58:18 +0000

Ещё так можно:


copyDest := GetDriveByLabel("Флэшка 16G", 30) 
If ( copyDest = "" ) {
    MsgBox, 4096, USB_HDD, ERROR! 
    ExitApp
} 
copySourcePattern := "G:"  

 loop %copySourcePattern%\*,, 1
{
    StringReplace destDir, A_LoopFileDir, % copySourcePattern, % copyDest
    if FileExist(destDir) != "D"
        FileCreateDir % destDir
    dest := destDir . "\" . A_LoopFileName

    FileCopy, %A_LoopFileFullPath%, % dest
    if !ErrorLevel
        continue

    FileGetTime, time, % dest
    FileGetSize, size, % dest
    if (A_LoopFileTimeModified = time) && (A_LoopFileSize = size)
        continue

    FileCopy, %A_LoopFileFullPath%, % dest, 1
    if ErrorLevel
        MsgBox, Could not copy "%A_LoopFileFullPath%" to "%dest%".
}
sleep 5000
Run, D:\Abola\USB_HDD\RemUMS.exe %copyDest%
sleep 5000
MsgBox, 4096, USB_HDD, DONE!
ExitApp 

GetDriveByLabel(pLabel, Loop = 1) {  
    DriveGet, List, List
    Loop, Parse, List
    { 
        DriveGet, Label, Label, %A_LoopField%: 
        If ( Label = pLabel )
            Return A_LoopField ":" 
    }  
    If Loop = 1
        Return ""
    sleep, 1000
    GetDriveByLabel(pLabel, Loop-1)
}

И RemUMS.exe проверьте на код выхода через RunWait, может он что-то возвращает - для пущей уверенности, и упразднения пауз по 5 сек.

Re: AHK: Копирование новых либо измененных файлов и директорий

null@example.com (Malcev) — Mon, 29 Apr 2013 02:20:27 +0000

Z := GetDriveByLabel("USB_HDD")":"   ; Если диск с таким лейблом есть, то переменной присуждается буква с двоеточим.
loop, 30   ; даем 30 секунд на распознование диска
{
   if Z!=:   ; если буква есть, а не одно двоеточие
      break
   sleep, 1000
   n++
}
if n = 30    
{
   MsgBox, 4096, USB_HDD, ERROR!
   ExitApp
}

Хотя точно, Z := GetDriveByLabel("USB_HDD")":" надо тоже в цикл всунуть, а n=0 можно вообще не прописывать.
Тогда так:


loop, 30
{
   Z := GetDriveByLabel("USB_HDD")":"
   if Z!=:
      break
   sleep, 1000
   n++
}
if n = 30
{
   MsgBox, 4096, USB_HDD, ERROR!
   ExitApp
}

copySourcePattern := "G:"
copyDest := Z

loop %copySourcePattern%\*,, 1
{
    StringReplace destDir, A_LoopFileDir, % copySourcePattern, % copyDest
    if FileExist(destDir) != "D"
        FileCreateDir % destDir
    dest := destDir . "\" . A_LoopFileName

    FileCopy, %A_LoopFileFullPath%, % dest
    if !ErrorLevel
        continue

    FileGetTime, time, % dest
    FileGetSize, size, % dest
    if (A_LoopFileTimeModified = time) && (A_LoopFileSize = size)
        continue

    FileCopy, %A_LoopFileFullPath%, % dest, 1
    if ErrorLevel
        MsgBox, Could not copy "%A_LoopFileFullPath%" to "%dest%".
}
sleep 5000
Run, D:\Abola\USB_HDD\RemUMS.exe %copyDest%
sleep 5000
MsgBox, 4096, USB_HDD, DONE!
ExitApp


GetDriveByLabel(pLabel)
{
  DriveGet, var, List
  Loop, Parse, var
  {
    DriveGet, var, Label, %A_LoopField%:
    If ( var = pLabel )
      Return A_LoopField  ;  if found, will return the drive's letter
  }
}

Re: AHK: Копирование новых либо измененных файлов и директорий

null@example.com (serzh82saratov) — Mon, 29 Apr 2013 02:13:07 +0000

А не могли бы вы прокомментировать эту конструкцию:

loop, 30
{
   if Z!=:
      break
   sleep, 1000
   n++
}
if n = 30
{
   MsgBox, 4096, USB_HDD, ERROR!
   ExitApp
}

Re: AHK: Копирование новых либо измененных файлов и директорий

null@example.com (Malcev) — Mon, 29 Apr 2013 01:25:39 +0000

В общем получился такой скрипт, который определяет букву USB диска по лейблу, копирует измененные файлы и потом отрубает диск с помощью http://www.autohotkey.com/board/topic/8 … age-drive/

Z := GetDriveByLabel("USB_HDD")":"
n = 0
loop, 30
{
   if Z!=:
      break
   sleep, 1000
   n++
}
if n = 30
{
   MsgBox, 4096, USB_HDD, ERROR!
   ExitApp
}

copySourcePattern := "G:"
copyDest := Z

loop %copySourcePattern%\*,, 1
{
    StringReplace destDir, A_LoopFileDir, % copySourcePattern, % copyDest
    if FileExist(destDir) != "D"
        FileCreateDir % destDir
    dest := destDir . "\" . A_LoopFileName

    FileCopy, %A_LoopFileFullPath%, % dest
    if !ErrorLevel
        continue

    FileGetTime, time, % dest
    FileGetSize, size, % dest
    if (A_LoopFileTimeModified = time) && (A_LoopFileSize = size)
        continue

    FileCopy, %A_LoopFileFullPath%, % dest, 1
    if ErrorLevel
        MsgBox, Could not copy "%A_LoopFileFullPath%" to "%dest%".
}
sleep 5000
Run, D:\Abola\USB_HDD\RemUMS.exe %copyDest%
sleep 5000
MsgBox, 4096, USB_HDD, DONE!
ExitApp


GetDriveByLabel(pLabel)
{
  DriveGet, var, List
  Loop, Parse, var
  {
    DriveGet, var, Label, %A_LoopField%:
    If ( var = pLabel )
      Return A_LoopField  ;  if found, will return the drive's letter
  }
}

Re: AHK: Копирование новых либо измененных файлов и директорий

null@example.com (creature.ws) — Sun, 28 Apr 2013 23:01:49 +0000

Если дата исходного файла меньше, чем дата архивного файла, значит архивный файл новее

Интересно, почему это является возможным? Негоже редактировать файлы помещённые в «архив».

Вам виднее, сравнение размера выполняет поставленную задачу или решает возникшую проблему — используйте.

Re: AHK: Копирование новых либо измененных файлов и директорий

null@example.com (Malcev) — Sun, 28 Apr 2013 16:21:00 +0000

Ну я руководствуюсь тем, что был код таким:
Если дата исходного файла меньше, чем дата архивного файла, значит архивный файл новее, следовательно его не перезаписываем.

 FileGetTime, time, % dest
    if (A_LoopFileTimeModified <= time)
        continue

Но тут не учтен момент, что во время предыдущей архивации могло что-нибудь глюкануть и файл записался неполностью.
Поэтому я и решил добавить условие

    FileGetTime, time, % dest
    FileGetSize, size, % dest
    if (A_LoopFileTimeModified <= time) && (A_LoopFileSize = size)
        continue

Или я ошибаюсь?

Re: AHK: Копирование новых либо измененных файлов и директорий

null@example.com (creature.ws) — Sun, 28 Apr 2013 15:56:36 +0000

Я бы не стал использовать результат сравнения размера файлов в качестве признака указывающего на различие содержимого.

Re: AHK: Копирование новых либо измененных файлов и директорий

null@example.com (Malcev) — Sun, 28 Apr 2013 14:13:01 +0000

creature.ws, а как вы думаете, не стоит ли добавить проверку на размер?

    FileGetTime, time, % dest
    FileGetSize, size, % dest
    if (A_LoopFileTimeModified <= time) && (A_LoopFileSize = size)
        continue