ControlGet, thisHwnd, Hwnd,, % thisTitle ": отключить звук"

потом

ControlClick,, ahk_id %thisHwnd%

Только вот не знаю как научиться различать состояние muted/unmuted: чтобы показывать для них разные тултипы.

#SingleInstance, Force
DetectHiddenWindows, On
SetTitleMatchMode, 3

; Choose step value (percents)
Step := 10

#Volume_Mute::
#Volume_Up::
#Volume_Down::
    WinGetClass, Class, A
    If (Class = "MozillaWindowClass")
        thisTitle := "Mozilla Firefox"
    Else If (Class ~= "(Progman|Shell_TrayWnd)")
        thisTitle := "Системные звуки"
    Else
        WinGetActiveTitle, thisTitle
    Run, SndVol.exe,, Hide
    WinWait, ahk_class #32770 ahk_exe SndVol.exe
    If (A_ThisHotkey = "#Volume_Mute")    ; Hotkey dependent code
        ControlGet, thisHwnd, Hwnd,, % thisTitle ": отключить звук"
    Else
        ControlGet, thisHwnd, Hwnd,, % thisTitle ": громкость"
    WinGet, ListHwnd, ControlListHwnd
    WinGet, List, ControlList
    If (A_ThisHotkey = "#Volume_Mute")    ; Hotkey dependent code
        ControlClick,, ahk_id %thisHwnd%
    Else
    {
        thisHwnd := RegExReplace(ListHwnd, "S).*" thisHwnd "`n(.*?)`n.*", "$1")
        SendMessage, 0x0400,,,, ahk_id %thisHwnd%
        volLvl := A_ThisHotkey = "#Volume_Up" ? Step : -Step    ; Hotkey dependent code
        volLvl := ErrorLevel - volLvl
        volLvl := volLvl > 100 ? 100 : volLvl < 0 ? 0 : volLvl
        SendMessage, 0x0400 + 34, , % volLvl,, ahk_id %thisHwnd%
        TrayTip, % thisTitle, % 100 - volLvl "%", 1, 1
    }
    WinClose
    Return

WM_USER                 := 0x0400
; Messages 
TBM_GETPOS              := (WM_USER)

Константа WM_USER = 0x400. В контексте «окна с ползунком» сообщение с номером 0x400 можно назвать TBM_GETPOS. Отправляя с помощью SendMessage сообщение с номером 0x400 окну типа msctls_trackbar32 в ErrorLevel вы получите положение  ползунка.

    ControlSend,, % A_ThisHotkey = "#2" ? "{PgUp}" : "{PgDn}", % "ahk_id " H := RegExReplace(ListHwnd, "S).*" Hwnd "`n(.*?)`n.*", "$1")
    SendMessage, 0x0400,,,, ahk_id %H%

Что это за SendMessage?
Что делает RegExReplace(ListHwnd, "S).*" Hwnd "`n(.*?)`n.*", "$1")?
Такое тяжело читается, когда писал не сам.

Кто же ВАМ не даёт изменить в моём коде переменную StaticText таким же образом как и в своём коде переменную title??? Какая-то религия не позволяет?

Видимо вы очень уж сильно полюбили свой с таким трудом собранный скрипт...

Похоже Вы не читаели то, что я написал, когда описывал работу своего скрипта и не понимаете, что в моём коде эта переменная получает значение соответствующее заголовку активного (в момент нажатия хоткея) окна: т.е. я не вписываю её в код руками, как это делаете Вы в своём коде.
А для "Mozilla Firefox" просто пришлось делать исправление, т.к. окно имеет не такой заголовок, каким оно отображается в SndVol.exe.

Но в принципе, если в Вашем коде исправить

Else
    Return

на

Else
    WinGetActiveTitle, StaticText

то он начинает работать так же, как и мой код.
Спасибо за то, что прикрутили подсказку с текущим уровнем громкости, вот только мне больше хочется её видеть не в виде TrayTip, а в виде OSD прогрессбара.

осмелюсь предложить такой код:

У предложенного Вами скрипта другой функционал: он управляет только "системными звуками", мой же скрипт - управляет громкостью приложения, чьё окно в данный момент активно.

Плюс, в мой скрипт можно легко добавить управление "Системными звуками", например, вот так:

    Else If (title = "Program Manager")
        title := "Системные звуки"

И тогда управлять громкостью системных звуков можно будет если перед нажатием хоткея активировать рабочий стол.
(Можно добавить такую же привязку и к Панели задач, например)

(GetText = StaticText ": громкость") ? trackbar := A_Index + 1 

Я протестую .

(GetText = StaticText ": громкость") ? trackbar := A_Index + 1 : ""

Если хочется лаконично записать выражение типа if () then ()

(GetText = StaticText ": громкость") && trackbar := A_Index + 1 

Дело и правда что ли в каких-то "мета-символах", о которых я ничего не знаю.

Регулярные выражения (RegEx) - краткий справочник пишет:

Экранированные (escaped) символы: большинство литер (например, abc123) внутри шаблона понимаются буквально. Но чтобы литеры, которые используются как метасимволы (\.*?+[{|()^$), понимались в обычном смысле, их надо предварять влево наклоненной чертой. Например, \. означает буквально точку, и \\ означает буквально левую наклонную.

Всё по-прежнему.

Не понял.

Это я не понял сначала - уже подправил то сообщение: всё работает, спасибо.
Про метасимволы - не подумал, что нужно экранировать и те, что внутри переменной title.

If thisControlText ~= "\Q" title "\E: громкость$"

Всё заработало как надо, спасибо!

serzh82saratov
Перед контролом, отвечающим за ползунок управления громкостью какого-то приложения, находится контрол "StaticN" (вместо N - число), с текстом "Имя_приложения: громкость". Петля (loop) в моём коде как раз и ищет совпадение title активного окна с текстом у всех "StaticN" контроллов, находя нужный. Как только она его нашла - мы знаем его порядковый номер, но т.к. контрол, отвечающий за ползунок - следующий в списке контроллов, то мы должны добавить единицу к найденному порядковому номеру и сохранить это всё в какую-то переменную:

thisControl := A_Index + 1

На следующей итерации петли - мы проверяем, соответствует ли текущая итерация петли (A_Index) числу в той переменной, и если соответствует - то это и есть контрол, отвечающий за ползунок и мы его и посылаем ControlSend, а потом просто удаляем ту переменную (после этого стоит сделать и разрыв петли (Break), который я не добавил в код, т.к. занимался debugging-ом).
В принципе, можно даже ничего не записывать в переменную "thisControl", а просто создавать её и проверять само наличие. Это сэкономит целых несколько байт памяти.

А что конкретно не понятно? Miranda NG - это мультипротокольный мессенеджер для разных сетей. TabSRMM - плагин от этой программы, отвечающий за окна чат-контейнеров. Без этого (или аналогичного) плагина - некому было бы создавать окна чата. Title у окна выглядит, например, вот так: "Drugoy (Online)". Ради дебага пробовал заранее вбивать этот текст в переменную и искать совпадение текста "StaticN" с текстом из этой переменной - тогда всё срабатывает.
А "$" - это не часть title'а, это часть RegExp синтаксиса, означает, что данное выражение должно находиться в конце строки. Его можно удалить, без него всё так же работает.

MsgBox % "true = true:`t"       (true = true)
        . "`n""1"" = true:`t`t" ("1" = true)
        . "`n1 = true:`t`t"     (1 = true)
        . "`n123 = true:`t"     (123 = true)
        . "`n!!123 = true:`t"   (!!123 = true)

RegExMatch возвращает позицию символа в строке, или ноль, если шаблон в строке не присутствует.
Число отличное от нуля можно интерпретировать как true, но число само по себе не равно true.
Если подстрока соответствующая шаблону поиска не нужна, а важен сам факт нахождения шаблона — используйте оператор ~=.

Прочитав абзац выше и запустив код, вы уже всё поняли, но всё же:

If RegExMatch(thisControlText, title ": громкость$")

If thisControlText ~= title ": громкость$"

If (RegExMatch(thisControlText, title ": громкость$") = true)

не выполняется. А с другими окнами других программ - нормально выполняется.

Ничего не пойму??? В 15 посте приведён код, он получает все контролы и из скрытого окна!

Всё уже ок, говорю же, просто не допонял сначала.

Вот Вам готовый скрипт:

#SingleInstance, Force
DetectHiddenWindows, On

F1::
F2::
    WinGetActiveTitle, title    ; Store the title of the active window in a var 'title'
    If (RegExMatch(title, ".* - Mozilla Firefox") = true)    ; Fix for Mozilla Firefox
        title := "Mozilla Firefox"
    Run SndVol.exe ;,, Hide
    WinWait ahk_class #32770 ahk_exe SndVol.exe
    WinGet, controls, ControlList
    ; msgbox % controls
    Loop, parse, controls, `n
    {
    ; msgbox %A_LoopField%
        If (A_Index = thisControl)
        {
            ControlSend, %A_LoopField%, % A_ThisHotkey = "F1" ? "{PgUp}" : "{PgDn}"
            thisControl :=
        }
        Else If (RegExMatch(A_LoopField, "Static.*") = true)
        {
            ControlGetText, thisControlText, %A_LoopField%
            ; MsgBox Current control: '%A_LoopField%'`nText: '%thisControlText%'`nTitle we search for: '%title%'
            If (RegExMatch(thisControlText, title ": громкость$") = true)
            {
                thisControl := A_Index + 1
                ; Msgbox Title '%title%' matches '%thisControlText%'!`nA_LoopField: '%A_LoopField%'
            }
        }
    }
    ; WinClose
    Return

А сейчас я застрял над проблемой с окнами мирандовского TabSRMM:

If (RegExMatch(thisControlText, title ": громкость$") = true)

это условие с ними почему-то никогда не выполняется, хотя если раскомменировать строки с MsgBox-ами (который я использую для debugging'а) - то видно, что они совпадают.
С Mozilla Firefox, Media Player Classic - Home Cinema и foobar2000 скрипт нормально срабатывает, даже в hide режиме.