Серый форум — AHK: StringSplit и 4-е подряд пробела.

Re: AHK: StringSplit и 4-е подряд пробела.

2013-05-30T11:13:15Z

Что думаете по счёт такого варианта?:


text =
(
sec"    "mA"    "mV
3,2452587890625    -0,00311479461379349    0,854992806911469
3,29225610351563    -0,00306393066421151    0,884990870952606
)


RegExSplit( text, "MyArray", "    |\R", """")
loop % MyArray0
    MsgBox,, MyArray%A_Index%, % MyArray%A_Index%
Listvars

RegExSplit( Str, NameArr, Delimiter, OmmitChr := "")    {
    Local Pos := 1, PrPos := ""
    While (PrPos <> Pos) 
        PrPos := Pos, %NameArr%0 := A_Index - 1
        , Pos := RegExMatch(Str, "S`a)(?<" A_Index ">.*?)(?:" Delimiter "|$)", %NameArr%, Pos) + StrLen(%NameArr%) 
        , %NameArr%%A_Index% := Trim(%NameArr%%A_Index%, OmmitChr)
}
return

Тут нет варианта того, что в тексте окажется символ разделителя для StringSplit.
Результат эдинтичен применению StringSplit.

Re: AHK: StringSplit и 4-е подряд пробела.

2013-05-16T10:56:22Z

Правильно ли я понял что "Chr(9733)" это извлечение символа которого скорее всего небудет в исходной строке, и это:


text =
(
sec"    "mA"    "mV
3,2452587890625    -0,00311479461379349    0,854992806911469
3,29225610351563    -0,00306393066421151    0,884990870952606
)

text := RegExReplace(text, "`a)(    |\R)", Chr(29733))

StringSplit StringArr, text, % Chr(29733)
Listvars
Pause

также верно, как и код выше, и как это:


text := RegExReplace(text, "`a)(    |\R)", "¶")

StringSplit StringArr, text, ¶

Re: AHK: StringSplit и 4-е подряд пробела.

2013-05-14T16:27:20Z

И еще раз спасибо.

added: гдето на порядок быстрее..или больше.

Re: AHK: StringSplit и 4-е подряд пробела.

2013-05-14T16:15:58Z

Согласно рекомендациям из справки.

text =
(
sec"    "mA"    "mV
3,2452587890625    -0,00311479461379349    0,854992806911469
3,29225610351563    -0,00306393066421151    0,884990870952606
)

StringReplace text, text, % "    ", % Chr(9733), 1
StringReplace text, text, `r`n, % Chr(9733), 1
StringReplace text, text, `n, % Chr(9733), 1

StringSplit StringArr, text, % Chr(9733)
Listvars
Pause

Re: AHK: StringSplit и 4-е подряд пробела.

2013-05-14T12:34:58Z

ИЗвиняюсь, у меня 1.1.08. Спасибо. Сейчас обновлюсь.

Re: AHK: StringSplit и 4-е подряд пробела.

2013-05-14T12:28:54Z

В ByRef ommit := "" не нужно убрать двоеточие. с ним работает аж с ноября 2012.

1.1.09.00 - November 7, 2012
Allow optional parameters to be declared with := instead of =, for consistency with variable declarations and expressions.

Re: AHK: StringSplit и 4-е подряд пробела.

2013-05-14T12:26:54Z

Спасибо большое.

(в ByRef ommit := "" надо убрать двоеточие. с ним не работает)

Re: AHK: StringSplit и 4-е подряд пробела.

2013-05-14T12:02:34Z

text =
(
sec"    "mA"    "mV
3,2452587890625    -0,00311479461379349    0,854992806911469
3,29225610351563    -0,00306393066421151    0,884990870952606
)

s := RegExSplit(text, " {4}|\R")
loop % s.MaxIndex()
    MsgBox % s[A_Index]

RegExSplit(ByRef string, ByRef pattern, ByRef ommit := "") {
    startPos := 1, EntryList := []

    while matchPos := RegExMatch(string, pattern, match, startPos)
        EntryList.Insert(Trim(SubStr(string, startPos, matchPos - startPos), ommit))
        , startPos := matchPos + (IsObject(match)? match.len : StrLen(match))

    EntryList.Insert(Trim(SubStr(string, startPos), ommit))
    return EntryList
}

AHK: StringSplit и 4-е подряд пробела.

2013-05-14T11:55:15Z

Добрый день.
Скрипт считывает текстовый файл в переменную, а затем пытается разбить на куски с помощью StringSplit.

Delim=%A_Space%+%A_Space%+%A_Space%+%A_Space%
FileRead, ALL, %SourceFile%
StringSplit, StringArr, ALL , %Delim%

Куски текста (числа), отделены либо 4-мя пробелами либо "концом строки" и "переводом каретки". Код выше - не работает т.к. пробелы учитывает поштучно, а не 4-е разом. В результате образуется куча пустых переменных.

Пример считываемого файла:

sec"    "mA"    "mV
3,2452587890625    -0,00311479461379349    0,854992806911469
3,29225610351563    -0,00306393066421151    0,884990870952606

Спасибо.