@echo off


if "%~1" == "" (
    echo.Usage: %~n0 command-name
    goto :EOF
)


setlocal

set DOSKEY="%windir%\system32\doskey.exe"
set FINDSTR="%windir%\system32\findstr.exe"


set found=
call :check_macro "%~1"
call :check_extension "%~1"
call :check_external "%~1"
call :check_internal "%~1"
if not defined found echo.Nothing found for "%~1"


endlocal

goto :EOF


:check_macro
%DOSKEY% /macros | %FINDSTR% /b "\<%~1\>"
if errorlevel 1 goto :EOF
set found=1
goto :EOF


:check_external
for %%p in ( "%PATH:;=" "%" ) do (
    call :check_extension "%%~p\%~1"
)
goto :EOF


:check_extension
for %%x in ( "%PATHEXT:;=" "%" ) do (
    if exist "%~1%%~x" (
        echo %~1%%~x
        set found=1
    )
)
goto :EOF


:check_internal
(

    echo.assoc break call cd chdir cls color copy date del dir echo
    echo.endlocal erase exit for ftype goto if md mkdir move path
    echo.pause popd prompt pushd rd rem ren rename rmdir set setlocal
    echo.shift start time title type ver verify vol

) | %FINDSTR% /i "\<%~1\>" >nul && echo.-- internal "%~1"
if errorlevel 1 goto :EOF
set found=1
goto :EOF

help | more
help dir
help xcopy