Серый форум — AHK: Шифрование текстовых файлов

Re: AHK: Шифрование текстовых файлов

2013-07-17T12:21:16Z

Кстати Ваш прогрессбар криво у меня работает.

Проверьте на этом:


SetBatchLines -1
ExtList = txt,ahk,ini,bat,htm ; допустимые расширения
Global Table := "а" A_Space "бвгдеёжзийклмнопрстуфхцчшщъыьэюя"
            . "А" A_Tab "БВГДЕЁЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯ"
            . "abcdefghijklmnopqrstuvwxyz"
            . "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
            . "'-!""#$&()*,./:`;?@[_\]|^``{}~+<=>№`%`r`n"
            . "1234567890", MI := 163, PIN, R
; ----------------------------------------------------
Gui, Add, Edit, x5 w150 vPIN Number, 3345
Gui, Add, Edit, xs y+5 wp R1 vCripting ReadOnly, Перетащите сюда файлы...
Gui, Add, Progress, xs y+5 wp h8 Range1-100 vMyProgress
Gui, Add, Checkbox, xs vAddTime Checked1, Добавить время
Gui, Add, Checkbox, xs vNoExt, Скрыть расширение
Gui, Add, Checkbox, xs vSaveNewFolder, Сохранять в новую папку
Gui, Add, Button, xs y+5 w74 gCript v0, Cript
Gui, Add, Button, x+5 w74 gDeCript v1, DeCript
Gui, +ToolWindow +AlwaysOnTop
Gui, Show, w160, Шифрование
Return
; ----------------------------------------------------
GuiDropFiles:
If A_GuiControl <> Cripting ; проверка контрола
    Return
nFiles := FileList := "" 
Loop, parse, A_GuiControlEvent, `n
    {
    SplitPath, A_LoopField, FileName, Dir, Extension, NameNoExt ; получить данные пути файла
    nFiles += 1 ; подсчет количества файлов
    If Extension   ; проверка расширений файлов
        If Extension not in %ExtList% ; проверка расширений файлов
            {
            MsgBox, 262192, Ошибка!, Только %ExtList%!
            Return
            }
    }
FileList := A_GuiControlEvent ; сохранить список файлов
GuiControl,, MyProgress
GuiControl,, %A_GuiControl%, % nFiles = 1 ? FileName : "Выбрано файлов: " nFiles ; %
Return
; ----------------------------------------------------
Cript:
DeCript:
Gui, Submit, NoHide
If SaveNewFolder + AddTime = 0
    {
    MsgBox, 262192, Ошибка!, Выберите минимум один вариант имён файлов`nили сохранение в папку %FolderToSave%!
    Return
    }
If FileList =
    {
    MsgBox, 262192, Ошибка!, Выберите один или несколько файлов!
    Return
    }    
if RegExMatch(PIN, ".*\D.*") = 1 ; проверка введенного кода
    {
    MsgBox, 262192, Ошибка!, Введите цифровой код!
    Return
    }
K := 0
Loop, parse, FileList, `n  ; подсчет количества символов в файлах
    {
    FileRead, Text, %A_LoopField%
    K += StrLen(Text)
    }
R := K // 99
If SaveNewFolder = 1 ; сохранять ли в папку
    {
    IfNotExist, Dir "\" A_GuiControl ; проверка папки
        FileCreateDir, %Dir%\%A_GuiControl% ; создать папку 
    Dir := Dir "\" A_GuiControl ; присвоить путь
    }
FormatTime, Time, A_Now, HH_mm_ss
; ----------------------------------------------------
Loop, parse, FileList, `n ; чтение списка файла
    { 
    Modified = ; очистка строки 
    SplitPath, A_LoopField, , , Extension, NameNoExt ; получить расширение файла
    NameNoExt := AddTime = 1 ? Time "_" NameNoExt : NameNoExt ; добавить время   
    Name := NoExt = 0 ? NameNoExt "." Extension    : NameNoExt ; скрыть расширение   
    FileRead, text, %A_LoopField% 
    FileAppend, % Cript(text, A_GuiControl), % Dir "\" Name ; Сохранение файла  
    }
FileList = ; очистка списка файлов
Return
; ----------------------------------------------------
Cript(text, mode) { 
    C := A := 1
    StringSplit, P, PIN ; сплит ключа 
    Loop, parse, text
        {
        i := InStr(Table, A_LoopField, 1) ; поиск позиции символа в Table
        P := P%C% ; очередной символ ключа
        C := ++C > P0 ? 1 : C ; проверка длины ключа
        iR := mode ? i - P : i + P ; шифруем или дешифруем
        iR := iR < 1 ? MI + iR : iR > MI ? iR - MI : iR ; позиция замещающего символа
        Res .= i = 0 ? A_LoopField : SubStr(Table, iR, 1) ; присвоить замещающий символ  
        If !Mod(A_Index, R)
            {
            GuiControl,, MyProgress, %A%    ; изменяем прогрессбар
            GuiControl,, Cripting, % A++ "%"    ; % изменяем поле  
            }
        }  
    GuiControl,, Cripting, 100`% 
    GuiControl,, MyProgress, 100
    Return Res
}

В таблицу добавил переводы строк.

Re: AHK: Шифрование текстовых файлов

2013-07-15T11:50:02Z

+ Отключение визуализации прогресса (для более быстрого де/шифрования)
+ Показ итогового времени выполнения

SetBatchLines -1
ExtList = txt,ahk,ini,bat,htm ; допустимые расширения
Global Table := "а" A_Space "бвгдеёжзийклмнопрстуфхцчшщъыьэюя"
            . "А" A_Tab "БВГДЕЁЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯ"
            . "abcdefghijklmnopqrstuvwxyz"
            . "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
            . "'-!""#$&()*,./:`;?@[_\]|^``{}~+<=>№`%"
            . "1234567890", MI := 163, A, K, PIN, Visyal           
; ----------------------------------------------------
Gui, Add, Edit, x5 w150 vPIN Number, Введите цифровой код
Gui, Add, Edit, xs y+5 wp R1 vCripting ReadOnly, Перетащите сюда файлы...
Gui, Add, Progress, xs y+5 wp h8 Range1-100 vMyProgress
Gui, Add, Checkbox, xs vVisyal Checked1, Визуализация
Gui, Add, Checkbox, xs vAddTime Checked1, Добавить время
Gui, Add, Checkbox, xs vNoExt, Скрыть расширение
Gui, Add, Checkbox, xs vSaveNewFolder, Сохранять в новую папку
Gui, Add, Button, xs y+5 w74 gCript v0, Cript
Gui, Add, Button, x+5 w74 gDeCript v1, DeCript
Gui, +ToolWindow +AlwaysOnTop
Gui, Show, w160, Шифрование
Return
; ----------------------------------------------------
GuiDropFiles:
If A_GuiControl <> Cripting ; проверка контрола
    Return
nFiles = 
FileList = 
Loop, parse, A_GuiControlEvent, `n
    {
    SplitPath, A_LoopField, FileName, Dir, Extension, NameNoExt ; получить данные пути файла
    nFiles += 1 ; подсчет количества файлов
    If Extension   ; проверка расширений файлов
        If Extension not in %ExtList% ; проверка расширений файлов
            {
            MsgBox, 262192, Ошибка!, Только %ExtList%!
            Return
            }
    }
FileList := A_GuiControlEvent ; сохранить список файлов
GuiControl,, MyProgress
GuiControl,, %A_GuiControl%, % nFiles = 1 ? FileName : "Выбрано файлов: " nFiles ; %
Return
; ----------------------------------------------------
Cript:
DeCript:
Gui, Submit, NoHide
If SaveNewFolder + AddTime = 0
    {
    MsgBox, 262192, Ошибка!, Выберите минимум один вариант имён файлов`nили сохранение в папку %FolderToSave%!
    Return
    }
If FileList =
    {
    MsgBox, 262192, Ошибка!, Выберите один или несколько файлов!
    Return
    }    
if RegExMatch(PIN, ".*\D.*") = 1 ; проверка введенного кода
    {
    MsgBox, 262192, Ошибка!, Введите цифровой код!
    Return
    }
StartTime := A_TickCount
A := K := 0
Loop, parse, FileList, `n  ; подсчет количества символов в файлах
    {
    FileRead, Text, %A_LoopField%
    K += StrLen(Text)
    }
Range = 0-%K%
GuiControl, +Range%Range%, MyProgress ; изменить размерность прогрессбара    
If SaveNewFolder = 1 ; сохранять ли в папку
    {
    IfNotExist, Dir "\" A_GuiControl ; проверка папки
        FileCreateDir, %Dir%\%A_GuiControl% ; создать папку 
    Dir := Dir "\" A_GuiControl ; присвоить путь
    }
FormatTime, Time, A_Now, HH_mm_ss
; ----------------------------------------------------
Loop, parse, FileList, `n ; чтение списка файла
    { 
    Modified = ; очистка строки 
    SplitPath, A_LoopField, , , Extension, NameNoExt ; получить расширение файла
    NameNoExt := AddTime = 1 ? Time "_" NameNoExt : NameNoExt ; добавить время   
    Name := NoExt = 0 ? NameNoExt "." Extension    : NameNoExt ; скрыть расширение   
       FileRead, text, %A_LoopField%
    FileAppend, % Cript(text, A_GuiControl), % Dir "\" Name ; Сохранение файла 
    }
FileList = ; очистка списка файлов
; ----------------------------------------------------    
tm1 := (A_TickCount - StartTime)/1000
tm2 := Floor(tm1)
StringMid, ms, tm1, StrLen(tm2) + 2, 3
GuiControl, , Cripting, % "Выполнено за " FormatSeconds(Tm2) "'" ms
Return
; ----------------------------------------------------
Cript(text, mode) { 
    C := 1
    StringSplit, P, PIN ; сплит ключа
    Loop, parse, text
        {
        If Visyal 
            {
            GuiControl,, MyProgress, % A++ ; изменяем прогрессбар
            GuiControl, , Cripting, % Floor(A*100/K)"%" ; % изменяем поле (округляем до ближайшего целого числа в меньшую сторону)
            }
        i := InStr(Table, A_LoopField, 1) ; поиск позиции символа в Table
        P := P%C% ; очередной символ ключа
        C := ++C > P0 ? 1 : C ; проверка длины ключа
        iR := mode ? i - P : i + P ; шифруем или дешифруем
        iR := iR < 1 ? MI + i - P : iR > MI ? i + P - MI : iR ; позиция замещающего символа
        Res .= i = 0 ? A_LoopField : SubStr(Table, iR, 1) ; присвоить замещающий символ
        }
    Return Res
}
; ----------------------------------------------------
FormatSeconds(NumberOfSeconds)
    {
    time = 19990101  ; Полночь произвольной даты.
    time += %NumberOfSeconds%, seconds
    FormatTime, mmss, %time%, mm:ss
    return NumberOfSeconds//3600 ":" mmss
    }
GuiClose:
ExitApp

Re: AHK: Шифрование текстовых файлов

2013-07-12T11:50:54Z

Тут нужно как можно меньше взаимодействовать с GUI Миллион символов и миллион раз дёргать гуи не айс.

Кстати я его (прогрессбар) первый раз сделал, просто давно хотел попробовать.

Может будет стимулом для переделки моего варианта.

Re: AHK: Шифрование текстовых файлов

2013-07-12T08:39:18Z

И всё таки очень сильно.

Ну кто ж спорит. Кстати я его (прогрессбар) первый раз сделал, просто давно хотел попробовать. Провести расчет и кол-во данных, и чтобы точнехонько на 100% заканчивался. Вроде получилось. Так что можно оставить его как пример.
Кстати Ваш прогрессбар криво у меня работает.

Re: AHK: Шифрование текстовых файлов

2013-07-11T10:13:25Z

serzh82saratov пишет:

Ещё есть мнение что GuiControl очень сильно тормозит процесс.

И всё таки очень сильно. Этот вариант работает минимум в 10 раз быстрее без ущерба для наглядности прогресса:


SetBatchLines -1
ExtList = txt,ahk,ini,bat,htm ; допустимые расширения
Global Table := "а" A_Space "бвгдеёжзийклмнопрстуфхцчшщъыьэюя"
            . "А" A_Tab "БВГДЕЁЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯ"
            . "abcdefghijklmnopqrstuvwxyz"
            . "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
            . "'-!""#$&()*,./:`;?@[_\]|^``{}~+<=>№`%"
            . "1234567890", MI := 163, PIN, R
; ----------------------------------------------------
Gui, Add, Edit, x5 w150 vPIN Number, Введите цифровой код
Gui, Add, Edit, xs y+5 wp R1 vCripting ReadOnly, Перетащите сюда файлы...
Gui, Add, Progress, xs y+5 wp h8 Range1-100 vMyProgress
Gui, Add, Checkbox, xs vAddTime Checked1, Добавить время
Gui, Add, Checkbox, xs vNoExt, Скрыть расширение
Gui, Add, Checkbox, xs vSaveNewFolder, Сохранять в новую папку
Gui, Add, Button, xs y+5 w74 gCript v0, Cript
Gui, Add, Button, x+5 w74 gDeCript v1, DeCript
Gui, +ToolWindow +AlwaysOnTop
Gui, Show, w160, Шифрование
Return
; ----------------------------------------------------
GuiDropFiles:
If A_GuiControl <> Cripting ; проверка контрола
    Return
nFiles = 
FileList = 
Loop, parse, A_GuiControlEvent, `n
    {
    SplitPath, A_LoopField, FileName, Dir, Extension, NameNoExt ; получить данные пути файла
    nFiles += 1 ; подсчет количества файлов
    If Extension   ; проверка расширений файлов
        If Extension not in %ExtList% ; проверка расширений файлов
            {
            MsgBox, 262192, Ошибка!, Только %ExtList%!
            Return
            }
    }
FileList := A_GuiControlEvent ; сохранить список файлов
GuiControl,, MyProgress
GuiControl,, %A_GuiControl%, % nFiles = 1 ? FileName : "Выбрано файлов: " nFiles ; %
Return
; ----------------------------------------------------
Cript:
DeCript:
Gui, Submit, NoHide
If SaveNewFolder + AddTime = 0
    {
    MsgBox, 262192, Ошибка!, Выберите минимум один вариант имён файлов`nили сохранение в папку %FolderToSave%!
    Return
    }
If FileList =
    {
    MsgBox, 262192, Ошибка!, Выберите один или несколько файлов!
    Return
    }    
if RegExMatch(PIN, ".*\D.*") = 1 ; проверка введенного кода
    {
    MsgBox, 262192, Ошибка!, Введите цифровой код!
    Return
    }
K := 0
Loop, parse, FileList, `n  ; подсчет количества символов в файлах
    {
    FileRead, Text, %A_LoopField%
    K += StrLen(Text)
    }
R := K // 100
If SaveNewFolder = 1 ; сохранять ли в папку
    {
    IfNotExist, Dir "\" A_GuiControl ; проверка папки
        FileCreateDir, %Dir%\%A_GuiControl% ; создать папку 
    Dir := Dir "\" A_GuiControl ; присвоить путь
    }
FormatTime, Time, A_Now, HH_mm_ss
; ----------------------------------------------------
Loop, parse, FileList, `n ; чтение списка файла
    { 
    Modified = ; очистка строки 
    SplitPath, A_LoopField, , , Extension, NameNoExt ; получить расширение файла
    NameNoExt := AddTime = 1 ? Time "_" NameNoExt : NameNoExt ; добавить время   
    Name := NoExt = 0 ? NameNoExt "." Extension    : NameNoExt ; скрыть расширение   
    FileRead, text, %A_LoopField% 
    FileAppend, % Cript(text, A_GuiControl), % Dir "\" Name ; Сохранение файла  
    }
FileList = ; очистка списка файлов
Return
; ----------------------------------------------------
Cript(text, mode) { 
    C := A := 1
    StringSplit, P, PIN ; сплит ключа 
    Loop, parse, text
        {
        i := InStr(Table, A_LoopField, 1) ; поиск позиции символа в Table
        P := P%C% ; очередной символ ключа
        C := ++C > P0 ? 1 : C ; проверка длины ключа
        iR := mode ? i - P : i + P ; шифруем или дешифруем
        iR := iR < 1 ? MI + iR : iR > MI ? iR - MI : iR ; позиция замещающего символа
        Res .= i = 0 ? A_LoopField : SubStr(Table, iR, 1) ; присвоить замещающий символ  
        If !Mod(A_Index, R)
            {
            GuiControl,, Cripting, % A++ "%"    ; % изменяем поле  
            GuiControl,, MyProgress, %A%    ; изменяем прогрессбар
            }
        }  
    GuiControl,, Cripting, 100`% 
    Return Res
}

Если считать что Range1-100 это вполне достаточно.

Re: AHK: Шифрование текстовых файлов

2013-07-04T14:44:31Z

Malcev пишет:

А тут разве не посерьезнее будет?

Мы ж тут не письками меряемся. А делимся знаниями, чтобы их и прирастало.

Re: AHK: Шифрование текстовых файлов

2013-07-04T12:22:29Z

Malcev
Вы понимаете. Александр_, он чертовски талантлив.
А нам надо мыслить в силу своих знаний...
Мужчина - программист.
А мы с вами - дилетанты.
Вы возьмётесь объяснить его алгоритм?

Re: AHK: Шифрование текстовых файлов

2013-07-04T12:13:35Z

А тут разве не посерьезнее будет?
http://forum.script-coding.com/viewtopi … 769#p69769

Re: AHK: Шифрование текстовых файлов

2013-07-04T11:24:37Z

Думаю получился отличный скрипт для шифрования, и многие могут теперь им воспользоватся.

Re: AHK: Шифрование текстовых файлов

2013-07-01T11:50:52Z

Замена считывания строк на чтение файла
Очистка списка файлов после де/шифрования
Создание папки выведено из цикла чтения файлов
PIN как глобальная переменная
Добавлено SetBatchLines -1
Исправлен подсчет кол-ва символов в файлах

SetBatchLines -1
ExtList = txt,ahk,ini,bat,htm ; допустимые расширения
Global A, K, PIN
Global Table := "а" A_Space "бвгдеёжзийклмнопрстуфхцчшщъыьэюя"
            . "А" A_Tab "БВГДЕЁЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯ"
            . "abcdefghijklmnopqrstuvwxyz"
            . "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
            . "'-!""#$&()*,./:`;?@[_\]|^``{}~+<=>№`%"
            . "1234567890", MI := 163            
; ----------------------------------------------------
Gui, Add, Edit, x5 w150 vPIN Number, Введите цифровой код
Gui, Add, Edit, xs y+5 wp R1 vCripting ReadOnly, Перетащите сюда файлы...
Gui, Add, Progress, xs y+5 wp h8 Range1-100 vMyProgress
Gui, Add, Checkbox, xs vAddTime Checked1, Добавить время
Gui, Add, Checkbox, xs vNoExt, Скрыть расширение
Gui, Add, Checkbox, xs vSaveNewFolder, Сохранять в новую папку
Gui, Add, Button, xs y+5 w74 gCript v0, Cript
Gui, Add, Button, x+5 w74 gDeCript v1, DeCript
Gui, +ToolWindow +AlwaysOnTop
Gui, Show, w160, Шифрование
Return
; ----------------------------------------------------
GuiDropFiles:
If A_GuiControl <> Cripting ; проверка контрола
    Return
nFiles = 
FileList = 
Loop, parse, A_GuiControlEvent, `n
    {
    SplitPath, A_LoopField, FileName, Dir, Extension, NameNoExt ; получить данные пути файла
    nFiles += 1 ; подсчет количества файлов
    If Extension   ; проверка расширений файлов
        If Extension not in %ExtList% ; проверка расширений файлов
            {
            MsgBox, 262192, Ошибка!, Только %ExtList%!
            Return
            }
    }
FileList := A_GuiControlEvent ; сохранить список файлов
GuiControl,, MyProgress
GuiControl,, %A_GuiControl%, % nFiles = 1 ? FileName : "Выбрано файлов: " nFiles ; %
Return
; ----------------------------------------------------
Cript:
DeCript:
Gui, Submit, NoHide
If SaveNewFolder + AddTime = 0
    {
    MsgBox, 262192, Ошибка!, Выберите минимум один вариант имён файлов`nили сохранение в папку %FolderToSave%!
    Return
    }
If FileList =
    {
    MsgBox, 262192, Ошибка!, Выберите один или несколько файлов!
    Return
    }    
if RegExMatch(PIN, ".*\D.*") = 1 ; проверка введенного кода
    {
    MsgBox, 262192, Ошибка!, Введите цифровой код!
    Return
    }
A := K := 0
Loop, parse, FileList, `n  ; подсчет количества символов в файлах
    {
    FileRead, Text, %A_LoopField%
    K += StrLen(Text)
    }
Range = 0-%K%
GuiControl, +Range%Range%, MyProgress ; изменить размерность прогрессбара    
If SaveNewFolder = 1 ; сохранять ли в папку
    {
    IfNotExist, Dir "\" A_GuiControl ; проверка папки
        FileCreateDir, %Dir%\%A_GuiControl% ; создать папку 
    Dir := Dir "\" A_GuiControl ; присвоить путь
    }
FormatTime, Time, A_Now, HH_mm_ss
; ----------------------------------------------------
Loop, parse, FileList, `n ; чтение списка файла
    { 
    Modified = ; очистка строки 
    SplitPath, A_LoopField, , , Extension, NameNoExt ; получить расширение файла
    NameNoExt := AddTime = 1 ? Time "_" NameNoExt : NameNoExt ; добавить время   
    Name := NoExt = 0 ? NameNoExt "." Extension    : NameNoExt ; скрыть расширение   
       FileRead, text, %A_LoopField%
    Modified := Cript(text, A_GuiControl, 1)
    FileAppend, % Modified, % Dir "\" Name ; Сохранение файла  
    }
FileList = ; очистка списка файлов
Return
; ----------------------------------------------------
Cript(text, mode, C) { 
    StringSplit, P, PIN ; сплит ключа
    Loop, parse, text
        {
        A += 1 ; подсчет обработанных символов            
        GuiControl,, MyProgress, %A% ; изменяем прогрессбар
        GuiControl, , Cripting, % Floor(A*100/K)"%" ; % изменяем поле (округляем до ближайшего целого числа в меньшую сторону)
        i := InStr(Table, A_LoopField, 1) ; поиск позиции символа в Table
        P := P%C% ; очередной символ ключа
        C := ++C > P0 ? 1 : C ; проверка длины ключа
        iR := mode ? i - P : i + P ; шифруем или дешифруем
        iR := iR < 1 ? MI + i - P : iR > MI ? i + P - MI : iR ; позиция замещающего символа
        Res .= i = 0 ? A_LoopField : SubStr(Table, iR, 1) ; присвоить замещающий символ
        }
    Return Res
}
GuiClose:
ExitApp

Re: AHK: Шифрование текстовых файлов

2013-07-01T07:15:50Z

Ещё есть мнение что GuiControl очень сильно тормозит процесс.

Каждая строчка кода тормозит процесс, давайте оставим прогрессбар как есть

Re: AHK: Шифрование текстовых файлов

2013-07-01T06:52:03Z

Ещё есть мнение что GuiControl очень сильно тормозит процесс.


Cript(text, PIN, mode, C) { 
    StringSplit, P, PIN ; сплит ключа
    Loop, parse, text
        {
        A += 1 ; подсчет обработанных символов 
        i := InStr(Table, A_LoopField, 1) ; поиск позиции символа в Table
        P := P%C% ; очередной символ ключа
        C := ++C > P0 ? 1 : C ; проверка длины ключа
        iR := mode ? i - P : i + P ; шифруем или дешифруем
        iR := iR < 1 ? MI + i - P : iR > MI ? i + P - MI : iR ; позиция замещающего символа
        Res .= i = 0 ? A_LoopField : SubStr(Table, iR, 1) ; присвоить замещающий символ
        }           
        GuiControl,, MyProgress, %A% ; изменяем прогрессбар
        GuiControl, , Cripting, % Floor(A*100/K)"%" ; % изменяем поле (округляем до ближайшего целого числа в меньшую сторону)
    Return Res
}

или на каждом сотом символе его применять.

Re: AHK: Шифрование текстовых файлов

2013-07-01T06:35:31Z

Думаю для лаконичности кода, и недобавления переноса последней строки можно и FileRead пользовать.

Согласен

Кстати почему недобавили SetBatchLines -1? 2155 против 5565 без SetBatchLines.

Да как то не думал, надо добавить, согласен.

Re: AHK: Шифрование текстовых файлов

2013-07-01T06:11:46Z

Как ни странно 2155 против 2105 с Loop, read. Думаю для лаконичности кода, и недобавления переноса последней строки можно и FileRead пользовать.

Кстати почему недобавили SetBatchLines -1? 2155 против 5565 без SetBatchLines.

Re: AHK: Шифрование текстовых файлов

2013-07-01T05:57:49Z

А что пробовать:

Результат в секундах в обоих вариантах