Серый форум — AHK:конвертация строка->время и операции?

Re: AHK:конвертация строка->время и операции?

null@example.com (serzh82saratov) — Thu, 04 Jul 2013 09:54:33 +0000

Malcev пишет:

Но по большому счету, главное чтобы работало.

По большому счету, надо вникать в "алгоритм более* правильных решений". Тем паче, что:

ТС пишет:

Можно ли как-то немудрено

А не :

Приведите все способы решения задачи

Malcev
Ваш алгоритм можно расписать на 1 строку кода, с помощью выражения. И это очевидно. Я "раскатал" на 4 строки. Чтобы была универсальность, и можно было (при желании) также получать дату в нужном формате.

---------------------------------

*Указатель, на относительность утверждения. Т.к. наверняка можно сделать ещё проще.

Re: AHK:конвертация строка->время и операции?

null@example.com (Malcev) — Wed, 03 Jul 2013 23:50:15 +0000

А есть смысл городить огород, когда есть встроенные методы обработки времени?

Нету. Я решал задачу ориентировочно своих знаний.
Конечно ваш способ короче.
Но по большому счету, главное чтобы работало.

Re: AHK:конвертация строка->время и операции?

null@example.com (serzh82saratov) — Wed, 03 Jul 2013 09:00:21 +0000

Можно ещё сократить решение:


StartTime = 21:02:09
Duration = 04:58:01

StringSplit, D, Duration, :
Time := 20010101 RegExReplace(StartTime, ":"), S:=(D1*3600)+(D2*60)+D3
Time += S, S
FormatTime, EndTime, % Time, HH:mm:ss

MsgBox % EndTime

Re: AHK:конвертация строка->время и операции?

null@example.com (serzh82saratov) — Wed, 03 Jul 2013 08:37:58 +0000

Malcev пишет:

А вот и мой исправленный:

А есть смысл городить огород, когда есть встроенные методы обработки времени?

Re: AHK:конвертация строка->время и операции?

null@example.com (Malcev) — Tue, 02 Jul 2013 13:52:04 +0000

Ваш вариант неправильно форматирует время.
Правильней:

FormatTime, Time, % Time, HH:mm:ss

А вот и мой исправленный:

StartTime = 21:02:59
Duration = 48:58:01

StringSplit, Start, StartTime, :
StringSplit, Dur, Duration, :
if (Start3 + Dur3) >= 60
{
   Start3 -=60
   Start2 +=1
}
if (Start2 + Dur2) >= 60
{
   Start2 -=60
   Start1 += 1
}
while (Start1 + Dur1) >= 24
   Start1 -=24
EndTime3 := Start3 + Dur3
EndTime2 := Start2 + Dur2
EndTime1 := Start1 + Dur1
SetFormat, float, 02.0
Loop, 3
   EndTime%A_Index% += 0.0
msgbox, EndTime = %EndTime1%:%EndTime2%:%EndTime3%
return

Re: AHK:конвертация строка->время и операции?

null@example.com (serzh82saratov) — Tue, 02 Jul 2013 10:24:22 +0000

Malcev пишет:

Можно так:

StartTime = 21:02:59
Duration = 04:58:01

А на таких значениях?


StartTime = 21:02:59
Duration = 04:58:01

Time := A_YYYY A_MM A_DD RegExReplace(StartTime, ":")
StringSplit, Dur, Duration, :
Time += Dur3, S
Time += Dur2, M
Time += Dur1, H
FormatTime, EndTime, % Time, HH:mm:ss

MsgBox % EndTime

Re: AHK:конвертация строка->время и операции?

null@example.com (Malcev) — Mon, 01 Jul 2013 21:56:17 +0000

Можно так:

StartTime = 01:02:59
Duration = 04:58:01

StringSplit, Start, StartTime, :
StringSplit, Dur, Duration, :
if (Start3 + Dur3) >= 60
{
   Start3 -= 60
   Start2 += 1
}
if (Start2 + Dur2) >= 60
{
   Start2 -= 60
   Start1 += 1
}
EndTime3 := Start3 + Dur3
EndTime2 := Start2 + Dur2
EndTime1 := Start1 + Dur1
SetFormat, float, 02.0
Loop, 3
   EndTime%A_Index% += 0.0
msgbox, EndTime = %EndTime1%:%EndTime2%:%EndTime3%
return

AHK:конвертация строка->время и операции?

null@example.com (Zeirram) — Mon, 01 Jul 2013 21:19:34 +0000

Доброе утро,

Есть метки времени - начала неких событий, и есть длительности этих событий.
Все вида HH:mm:ss, в формате строки.
Можно ли как-то немудрено сложить начала и длительности, дабы получить финалы событий, в том же виде?