Серый форум — CMD/BAT: Как игнорировать файлы при удалении?

Re: CMD/BAT: Как игнорировать файлы при удалении?

2013-12-29T21:24:15Z

wisgest, спасиб

Re: CMD/BAT: Как игнорировать файлы при удалении?

2013-12-29T21:00:37Z

Ekklesiast пишет:

Хотелось бы как-то так:

Это элементарно:

set FILEMASK=^
.*\a3dapi.dll$ ^
.*\voice_tweak.exe$ ^
.*\Mssv12.asi$ ^
.*\.wad$

Только что-то меня берёт сомнение, правильно ли в данном случае составлен шаблон для FINDSTR.
По-моему, должно быть так (не проверял):

set FILEMASK=^
^^a3dapi\.dll$ ^
^^voice_tweak\.exe$ ^
^^Mssv12\.asi$ ^
.*\.wad$

~~~~~~~~~~~~~~~~~~~~
По поводу последнего примера до правки:

Ekklesiast пишет:

для удобства надо как-то разместить список игнорируемых файлов в столбик, т.к. в строчку оч. неудобно.

for %%i in (bin\*.cfg) do ^
  if not "%%~ni"=="auto" ^
  if not "%%~ni"=="config" ^
  if not "%%~ni"=="default" ^
  if not "%%~ni"=="lang" ^
  if not "%%~ni"=="listen" ^
  if not "%%~ni"=="server" ^
  if not "%%~ni"=="skill" ^
  if not "%%~ni"=="violence" ^
    del /f /q "%%~i"

setlocal enabledelayedexpansion
set IF=auto\config\default\lang\listen\server\skill\violence
set IF=\%IF:\=" \%"
set IF=!IF:\=if not "%%~ni"=="!
for %%i in (bin\*.cfg) do %IF% del /f /q "%%~i"

setlocal enabledelayedexpansion
set IF=auto^
\config^
\default^
\lang^
\listen^
\server^
\skill^
\violence
set IF=\%IF:\=" \%"
set IF=!IF:\=if not "%%~ni"=="!
for %%i in (bin\*.cfg) do %IF% del /f /q "%%~i"

(В двух последних примерах исправил «*» на «bin\*.cfg».)

Re: CMD/BAT: Как игнорировать файлы при удалении?

2013-12-29T17:26:07Z

wisgest, Спасиб

След. задача:


set "FILEMASK=.*\a3dapi.dll$"
set "FILEMASK=%FILEMASK% .*\voice_tweak.exe$"
set "FILEMASK=%FILEMASK% .*\Mssv12.asi$"
set "FILEMASK=%FILEMASK% .*\.wad$"
set "FILEPATH=1"
pushd "%FILEPATH%"
for /f "delims=" %%i in ('dir /a:-d /b^|findstr /v /i "%FILEMASK%"') do del /f /q /a "%%i"
popd

Как-то неудобно сделал список игнорируемых файлов (их будет штук 20) в столбик.

Хотелось бы как-то так:


set "FILEMASK=
.*\a3dapi.dll$
.*\voice_tweak.exe$
.*\Mssv12.asi$
.*\.wad$"

Заранее огромное спасибо.

Re: CMD/BAT: Как игнорировать файлы при удалении?

2013-12-29T16:56:56Z

После проверки замени ECHO на DEL:

set "FILEMASK=.*\.cfg$ .*\.txt$"
set "FILEPATH=P:\subdir"

pushd "%FILEPATH%"
for /f "delims=" %%i in ('dir /a:-d /b^|findstr /v /i "%FILEMASK%"') do echo "%%i"
popd

Re: CMD/BAT: Как игнорировать файлы при удалении?

2013-12-29T14:37:31Z

След. задача:

Есть папка, мне там нужно удалить все файлы кроме файлов с расширением *.cfg и *.txt
Также нужна возможность задавать переменный путь и маски (*.cfg и *.txt), типа так:


set FILEMASK= *.cfg and *.txt
set FILEPATH= 1

for %%i in ('dir /b /s "%FILEPATH%\*.*"') do if not "%%~ni"==%FILEMASK% del /f /q "%%~i"

Подскажите как сделать

Re: CMD/BAT: Как игнорировать файлы при удалении?

2013-09-27T07:23:19Z

Ещё способ исключить файлы при удалении - поставить исключаемым файлам атрибуты скрытый и/или системный в любой комбинации командой attrib. После команды del снять атрибуты.
Можно наоборот - удаляемым файлам поставить нужные атрибуты, а в команде del использовать ключ /a

Re: CMD/BAT: Как игнорировать файлы при удалении?

2013-07-13T15:42:01Z

зачет

Re: CMD/BAT: Как игнорировать файлы при удалении?

2013-07-13T12:48:14Z

rost, попробуйте на свой страх и риск:

for /f "skip=1 delims=" %%i in ('dir /b /o:-d *.cfg') do del "%%~i"

Re: CMD/BAT: Как игнорировать файлы при удалении?

2013-07-13T09:59:55Z

добрый день!
если задание изменим: удалить все файлы *.cfg, кроме самого "старого" *.cfg
как теперь будет выглядеть батник?

Re: CMD/BAT: Как игнорировать файлы при удалении?

2013-07-10T09:34:01Z

del

Re: CMD/BAT: Как игнорировать файлы при удалении?

2013-07-10T08:35:36Z

Ekklesiast, напишите заголовок темы по-русски.

Re: CMD/BAT: Как игнорировать файлы при удалении?

2013-07-10T08:30:25Z

спасиб ))

Re: CMD/BAT: Как игнорировать файлы при удалении?

2013-07-10T07:15:59Z

Ekklesiast пишет:

добавил строку в *.bat
чё-то не фурычит

«Подымите мне очи…»:

shiz пишет:

для пакетного файла "%" надо удвоить

Re: CMD/BAT: Как игнорировать файлы при удалении?

2013-07-10T07:15:31Z

shiz пишет:

(для пакетного файла "%" надо удвоить)

Re: CMD/BAT: Как игнорировать файлы при удалении?

2013-07-10T06:55:15Z

shiz пишет:

for %i in (*.cfg) do if not "%~ni"=="1" if not "%~ni"=="2" if not "%~ni"=="3" del /f /q "%~i"

добавил строку в *.bat
чё-то не фурычит
))