Серый форум — Кодировка vbs при записи в файл 1С

Re: Кодировка vbs при записи в файл 1С

null@example.com (A13) — Thu, 18 Jul 2013 09:38:31 +0000

alexii, большое спасибо за помощь! Буду пробовать...

Re: Кодировка vbs при записи в файл 1С

null@example.com (alexii) — Thu, 18 Jul 2013 07:25:23 +0000

Как я понимаю, вот эта часть кода… отвечает за сохранение файла в нужной кодировке.

Именно. Передаёте в функцию полный путь к файлу и строку, которую надо будет сохранить в файл. Существующий файл будет перезаписан.

К моему варианту нельзя никак прикрутить, только полная переделка скрипта?

Почему нет?! Пробуйте.

Re: Кодировка vbs при записи в файл 1С

null@example.com (A13) — Thu, 18 Jul 2013 03:57:05 +0000

Как я понимаю, вот эта часть кода:

Function SaveToFile(ByVal strFullFileName, ByVal strContent)
Const adTypeText = 2
Const adModeReadWrite = 3
Const adSaveCreateOverWrite = 2

With WScript.CreateObject("ADODB.Stream")
.Type = adTypeText
.Mode = adModeReadWrite

.Open

.Charset = "utf-8"
.WriteText strContent

.SaveToFile strFullFileName, adSaveCreateOverWrite

.Close
End With
End Function

отвечает за сохранение файла в нужной кодировке. К моему варианту нельзя никак прикрутить, только полная переделка скрипта?

Re: Кодировка vbs при записи в файл 1С

null@example.com (A13) — Thu, 18 Jul 2013 03:38:12 +0000

alexii, в том то и дело, что мой вариант пока только тот, что я писал в начале. Пытаюсь понять ваш пример, но плохо это получается. В написание скриптов я самый что ни на есть новичок, а сроки как всегда поджимают.

Re: Кодировка vbs при записи в файл 1С

null@example.com (alexii) — Wed, 17 Jul 2013 10:10:35 +0000

A13, я лишь привёл пример. Приведите Ваш код.

Re: Кодировка vbs при записи в файл 1С

null@example.com (A13) — Wed, 17 Jul 2013 08:51:16 +0000

Пересохранил в ansi, скрипт запускается. Только берет данные странно, название не соответствует базе.

' Например, группе «1cv81_тест» соответствуют две базы,
' группе «1cv81_тест2» — одна база.
' Ну, и база может соответствовать нескольким группам (в примере — база «1C тест3»).

Нужно чтоб одной группе соответствовала 1 база. Но пользователь может состоять в нескольких. Например, если он состоит в группе 1cv81_тест то ему прописывается база тест. Если же он состоит в группе 1cv81_тест и 1cv81_тест2. то соответственно он видит базы тест и тест2.
в файл ibases записывается:
[1C тест]
Connect=File=\\SRV1C\1cdb\тест;
ID=f2926bd0-b233-4353-9e35-bfce27d92759
OrderInList=24576
Folder=/
OrderInTree=49152
External=0
[1C тест2]
Connect=Srvr=srv1c;Ref=тест2;
ID=f2926bd0-b233-4353-9e35-bfce27d92759
OrderInList=40960
Folder=/
OrderInTree=65536
External=0

Сейчас он пишет:
[1C Тест]
Connect=Srvr=srv1c:1641;Ref=Тест2;
ID=f2926bd0-b233-4353-9e35-bfce27d92730
OrderInList=24576
Folder=/
OrderInTree=49152
External=0

Re: Кодировка vbs при записи в файл 1С

null@example.com (alexii) — Tue, 16 Jul 2013 18:24:11 +0000

dab00, похоже на то. Я, конечно, в Unicode-1200 попробовал — там нормально, а вот что кому-то захочется сохранять код в UTF-8 — мне как-то даже и в голову не пришло .

Re: Кодировка vbs при записи в файл 1С

null@example.com (dab00) — Tue, 16 Jul 2013 17:44:04 +0000

A13 пишет:

Строка:1
Символ:1

Похоже кодировка, нужно в ansi.

Re: Кодировка vbs при записи в файл 1С

null@example.com (alexii) — Tue, 16 Jul 2013 16:04:03 +0000

Строка:1
Символ:1

Это что-то новенькое. Вы корректно скопировали код?

Re: Кодировка vbs при записи в файл 1С

null@example.com (A13) — Tue, 16 Jul 2013 05:12:01 +0000

alexii, выдаёт ошибку
Строка:1
Символ:1
Ошибка: недопустимый знак
Код: 800А0408

Re: Кодировка vbs при записи в файл 1С

null@example.com (alexii) — Tue, 16 Jul 2013 04:11:01 +0000

Тогда Вы должны завести какой-то список, что, дескать, группа «X» соответствует таким-то версиям и таким-то параметрам, группа «Y» — таким-то версиям и таким-то параметрам, группа «Z» — таким-то версиям и таким-то параметрам, соответственно. И т.д.

Поскольку структуры в VBScript отсутствуют, проще всего. пожалуй, будет использовать вложенные массивы, наподобие (совсем не проверялось):

Option Explicit

Const strConfigFileName = "ibases.v8i"

Dim arrBases
Dim arrBase

Dim objIADsGroup
Dim strUserGroups

Dim objFSO

Dim strAppData
Dim strPath2Config

Dim strContent81
Dim strContent82


'          Группа,        Версия, Имя базы,   Путь к базе,                ID
arrBases = Array( _
    Array("1cv81_тест",  "8.1",  "1C тест",  "File=\\SRV1C\1cdb\test;",  "f2926bd0-b233-4353-9e35-bfce27d92759"), _
    Array("1cv81_тест",  "8.1",  "1C тест2", "File=\\SRV1C\1cdb\test2;", "bla-bla-bla"), _
    Array("1cv81_тест3", "8.1",  "1C тест3", "File=\\SRV1C\1cdb\test3;", "bla-bla-bla3"), _
    Array("1cv81_тест4", "8.1",  "1C тест3", "File=\\SRV1C\1cdb\test3;", "bla-bla-bla3"), _
    Array("1cv82_тест",  "8.2",  "1C тест4", "Srvr=1c:1641;Ref=test",    "f2926bd0-b233-4353-9e35-bfce27d92730"), _
    Array("1cv82_тест2", "8.2",  "1C тест5", "Srvr=1c:1641;Ref=test2;",  "bla-bla-bla2") _
)
' Например, группе «1cv81_тест» соответствуют две базы,
'           группе «1cv81_тест2» — одна база.
' Ну, и база может соответствовать нескольким группам (в примере — база «1C тест3»).

strContent81 = ""
strContent82 = ""

For Each objIADsGroup In GetObject("LDAP://" & WScript.CreateObject("ADSystemInfo").UserName).Groups
    For Each arrBase In arrBases
        If objIADsGroup.Name = "CN=" & arrBase(0) Then
            Select Case arrBase(1)
                Case "8.1"
                    strContent81 = strContent81 & _
                        "[" & arrBase(2) & "]" & vbCrLf & _
                        "Connect=" & arrBase(3) & vbCrLf & _
                        "ID=" & arrBase(4) & vbCrLf & _
                        "OrderInList=24576" & vbCrLf & _
                        "Folder=/" & vbCrLf & _
                        "OrderInTree=49152" & vbCrLf & _
                        "External=0"
                Case "8.2"
                    strContent82 = strContent82 & _
                        "[" & arrBase(2) & "]" & vbCrLf & _
                        "Connect=" & arrBase(3) & vbCrLf & _
                        "ID=" & arrBase(4) & vbCrLf & _
                        "OrderInList=24576" & vbCrLf & _
                        "Folder=/" & vbCrLf & _
                        "OrderInTree=49152" & vbCrLf & _
                        "External=0"
            End Select
        End If
    Next
Next

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
strAppData = WScript.CreateObject("Shell.Application").NameSpace("shell:AppData").self.Path


strPath2Config = objFSO.BuildPath(strAppData, "1C\1Cv81")

If objFSO.FolderExists(strPath2Config) Then
    SaveToFile objFSO.BuildPath(strPath2Config, strConfigFileName), strContent81
Else
    WScript.Echo "Path [" & strPath2Config & "] not exists."
End If


strPath2Config = objFSO.BuildPath(strAppData, "1C\1CEStart")

If objFSO.FolderExists(strPath2Config) Then
    SaveToFile objFSO.BuildPath(strPath2Config, strConfigFileName), strContent82
Else
    WScript.Echo "Path [" & strPath2Config & "] not exists."
End If


Set objFSO = Nothing

WScript.Quit 0
'=============================================================================

'=============================================================================
Function SaveToFile(ByVal strFullFileName, ByVal strContent)
    Const adTypeText      = 2
    Const adModeReadWrite = 3
    Const adSaveCreateOverWrite = 2
    
    
    With WScript.CreateObject("ADODB.Stream")
        .Type      = adTypeText
        .Mode      = adModeReadWrite
        
        .Open
        
        .Charset   = "utf-8"
        .WriteText strContent
        
        .SaveToFile strFullFileName, adSaveCreateOverWrite
        
        .Close
    End With
End Function
'=============================================================================

Re: Кодировка vbs при записи в файл 1С

null@example.com (ypppu) — Tue, 16 Jul 2013 03:26:17 +0000

A13, предложения начинаются с заглавной буквы и заканчиваются точкой.

Re: Кодировка vbs при записи в файл 1С

null@example.com (A13) — Tue, 16 Jul 2013 02:50:47 +0000

не совсем то имелось в веду: сначала, к примеру, смотрим только базы 1с 81. Есть две-три базы, мы должны проверить если пользователь добавлен в группу этой базы, то записываем ее в файл, если он же добавлен еще и в другую группу, то записываем и эту базу в файл и так в скольких группах находится пользователь, столько баз у него в файл должно записаться

Re: Кодировка vbs при записи в файл 1С

null@example.com (alexii) — Tue, 16 Jul 2013 01:29:11 +0000

A13, примерно так (не проверялось):

Option Explicit

Const strConfigFileName = "ibases.v8i"

Dim objFSO

Dim objIADsGroup
Dim strUserGroups

Dim strAppData
Dim strPath
Dim strContent


strUserGroups = ""

For Each objIADsGroup In GetObject("LDAP://" & WScript.CreateObject("ADSystemInfo").UserName).Groups
    strUserGroups = strUserGroups & "[" & objIADsGroup.Name & "]"
Next


Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

strAppData = WScript.CreateObject("Shell.Application").NameSpace("shell:AppData").self.Path

If InStr(strUserGroups, "[CN=1cv81_тест]") Then
    CreateConfig objFSO.BuildPath(strAppData, "1C\1Cv81"), "1C тест", "File=\\SRV1C\1cdb\test;", "f2926bd0-b233-4353-9e35-bfce27d92759"
    CreateConfig objFSO.BuildPath(strAppData, "1C\1Cv81"), "1C тест2", "File=\\SRV1C\1cdb\test2;", "bla-bla-bla"
End If

If InStr(strUserGroups, "[CN=1cv82_тест]") Then
    CreateConfig objFSO.BuildPath(strAppData, "1C\1CEStart"), "1C тест", "Srvr=1c:1641;Ref=test", "f2926bd0-b233-4353-9e35-bfce27d92730"
    CreateConfig objFSO.BuildPath(strAppData, "1C\1CEStart"), "1C тест2", "Srvr=1c:1641;Ref=test2;", "bla-bla-bla2"
End If

Set objFSO = Nothing

WScript.Quit 0
'=============================================================================

'=============================================================================
Sub CreateConfig(strPath2Config, strBase, strPath2Base, strID)
        If objFSO.FolderExists(strPath2Config) Then
            strContent = _
                "[" & strBase & "]" & vbCrLf & _
                "Connect=" & strPath2Base & vbCrLf & _
                "ID=" & strID & vbCrLf & _
                "OrderInList=24576" & vbCrLf & _
                "Folder=/" & vbCrLf & _
                "OrderInTree=49152" & vbCrLf & _
                "External=0"
            
            SaveToFile objFSO.BuildPath(strPath2Config, strConfigFileName), strContent
        Else
            WScript.Echo "Path [" & strPath2Config & "] not exists."
        End If
    End If
End Sub
'=============================================================================

'=============================================================================
Function SaveToFile(ByVal strFullFileName, ByVal strContent)
    Const adTypeText      = 2
    Const adModeReadWrite = 3
    Const adSaveCreateOverWrite = 2
    
    
    With WScript.CreateObject("ADODB.Stream")
        .Type      = adTypeText
        .Mode      = adModeReadWrite
        
        .Open
        
        .Charset   = "utf-8"
        .WriteText strContent
        
        .SaveToFile strFullFileName, adSaveCreateOverWrite
        
        .Close
    End With
End Function
'=============================================================================

Re: Кодировка vbs при записи в файл 1С

null@example.com (A13) — Mon, 15 Jul 2013 12:59:40 +0000

какой-то идентификатор базы, роли особой я не увидел, если будет повторяться не страшно