Серый форум — VBS: пакетный парсинг XML

Re: VBS: пакетный парсинг XML

null@example.com (alexii) — Thu, 18 Jul 2013 13:21:54 +0000

PowerShell:

$oWebClient = New-Object System.Net.WebClient

'192.168.1.1', '192.168.1.5', '192.168.1.15', '192.168.1.50' | `
    ForEach-Object -Process {
        if (Test-Connection -ComputerName $_ -Count 1 -Quiet) {
            $sSourceFile = "http://$_/admin/spacfg.xml"
            $sDestFile   = "$env:temp" + "\spacfg.xml"

            $oWebClient.DownloadFile($sSourceFile, $sDestFile)

            [xml]$oXml = Get-Content -Path $sDestFile

            $sName   = $oXml.SelectSingleNode("/flat-profile/Host_Name     [@group='Info/System_Information']" ).'#text' + '.' + `
                       $oXml.SelectSingleNode("/flat-profile/Domain        [@group='Info/System_Information']" ).'#text'
            $sIP     = $oXml.SelectSingleNode("/flat-profile/Current_IP    [@group='Info/System_Information']" ).'#text'
            $sMAC    = $oXml.SelectSingleNode("/flat-profile/MAC_Address   [@group='Info/Product_Information']").'#text'
            $sSerial = $oXml.SelectSingleNode("/flat-profile/Serial_Number [@group='Info/Product_Information']").'#text'

            $sName, $sIP, $sMAC, $sSerial | Add-Content -Path "C:\Песочница\021\Destination\Out.txt" 
        }
    }

VBScript — примерно так:

Option Explicit

Dim strAddress


For Each strAddress In Array("192.168.1.1", "192.168.1.5", "192.168.1.15", "192.168.1.50")
    If IsEnabled(strAddress) Then
        With WScript.CreateObject("MSXML2.DOMDocument")
            If .load("http://" & strAddress & "/admin/spacfg.xml") Then
                WScript.Echo .SelectSingleNode("/flat-profile/Host_Name     [@group='Info/System_Information']" ).text & "." & _
                             .SelectSingleNode("/flat-profile/Domain        [@group='Info/System_Information']" ).text
                WScript.Echo .SelectSingleNode("/flat-profile/Current_IP    [@group='Info/System_Information']" ).text
                WScript.Echo .SelectSingleNode("/flat-profile/MAC_Address   [@group='Info/Product_Information']").text
                WScript.Echo .SelectSingleNode("/flat-profile/Serial_Number [@group='Info/Product_Information']").text
            Else
                WScript.Echo "Can't load [http://" & strAddress & "/admin/spacfg.xml]."
            End If
        End With
    End If
Next

WScript.Quit 0
'=============================================================================

'=============================================================================
Function IsEnabled(strAddress)
    Dim objSWbemObject
    
    IsEnabled = False
    
    For Each objSWbemObject In WScript.CreateObject("WbemScripting.SWbemLocator").ConnectServer(".", "root\cimv2").ExecQuery("SELECT * FROM Win32_PingStatus WHERE Address = '" & strAddress & "'")
        If Not IsNull(objSWbemObject.StatusCode) Then
            If objSWbemObject.StatusCode = 0 Then
                IsEnabled = True
            End If
        End If
    Next
End Function
'=============================================================================

Space-06, адрес — это что в примере?

Re: VBS: пакетный парсинг XML

null@example.com (Space-06) — Thu, 18 Jul 2013 08:53:50 +0000

Образец Файла
PowerShell устроит, но если будет возможность в другом исполнении то будет здорово

Re: VBS: пакетный парсинг XML

null@example.com (alexii) — Thu, 18 Jul 2013 08:12:00 +0000

Space-06, тогда сохраните какой-нибудь из них с помощью IE, упакуйте в архив и выложите на RGhost.

PowerShell в случае чего Вас устроит?

Re: VBS: пакетный парсинг XML

null@example.com (Space-06) — Thu, 18 Jul 2013 07:40:22 +0000

на пинг откликаются, по http файл доступен без авторизации

Re: VBS: пакетный парсинг XML

null@example.com (alexii) — Thu, 18 Jul 2013 07:27:43 +0000

Space-06, они на ICMP-пакеты реагируют, на ping откликаются? Файл доступен по http любому, без каких-либо авторизаций в браузере?

VBS: пакетный парсинг XML

null@example.com (Space-06) — Thu, 18 Jul 2013 04:39:47 +0000

Доброго времени суток уважаемые коллеги!!!

Возник такой вопрос как возможно организовать парсинг XML пакетно, и с выводом результата в текстовый файл?

Имеется локальная сеть: 192.168.1.0/24 в нее включены IP телефоны, ip адреса которых известны за ранее.
Собственно тут то и проблема: каждый конфиг телефона располагается по адресу http://IP/admin/spacfg.xml
Нужно прочитать буквально несколько тегов из этого файла:


DHCP
192.168.1.120
SEP58BFEA1192CC
csoft.org
255.255.255.0
192.168.1.1
192.168.1.3

SPA502G
CCQ16421D53
7.5.4
1.0.4
58BFEA1192CC
...

необходимо записать в текстовый файл: ип телефона, адрес, мак адрес и серийный номер

тут то собственно и загвоздка - как это все выполнить пакетно

буду рад идеям реализации.