Серый форум — AHK:Расширить функционал СКМ в Firefox

Re: AHK:Расширить функционал СКМ в Firefox

2013-09-13T06:22:35Z

Всё, настроил как надо. Тему можно закрывать. Впредь буду думать куда лезу. Спасибо за помощь.

Re: AHK:Расширить функционал СКМ в Firefox

2013-09-13T05:12:06Z

Ладно, ещё проще запусти этот код. В Mozilla нажимай и смотри ToolTip. Изменяй Pause := 350 как надо для двойного клика (чем больше, тем медленнее). Потом просто замени все 3 слова ToolTip на SendInput и заработает как тебе надо.


Pause := 350
 
#If WinActive("ahk_class MozillaWindowClass") 
Mbutton::  
    SetTimer IsLong, Off
    SetTimer IsShort, Off
    If (A_PriorHotkey = "Mbutton" && A_TimeSincePriorHotkey < Pause) 
        ToolTip ^{vk73}
    Else
        SetTimer IsShort, -%Pause%
    Return
    
    IsShort:
        If GetKeyState("Mbutton", "P")
            SetTimer IsLong, % "-" 1000-Pause
        Else
            ToolTip {Mbutton}  
        Return
    
    IsLong:
        ToolTip % GetKeyState("Mbutton", "P") ? "^{vk54}" : "{Mbutton}" 
        Return
#If

+ открыть спойлер



Pause := 350
 
 
Mbutton::  
    SetTimer IsLong, % IsLong := "Off"
    SetTimer IsShort, Off
    If (A_PriorKey = "Mbutton" && A_TimeSincePriorHotkey < Pause) 
        ToolTip ^{vk73}
    Else
        SetTimer IsShort, -%Pause%
    Return
    
    IsShort:
        If GetKeyState("Mbutton", "P")
            SetTimer IsLong, % "-" IsLong := 1000-Pause
        Else
            ToolTip {Mbutton}  
        Return
    
    IsLong:
        IsLong := "Off"
        ToolTip % GetKeyState("Mbutton", "P") ? "^{vk54}" : "{Mbutton}" 
        Return
        
Mbutton Up::  
    SetTimer IsLong, Off 
    If IsLong <> Off
        ToolTip {Mbutton}
    Return

Re: AHK:Расширить функционал СКМ в Firefox

2013-09-13T05:03:15Z

вот только после 50 как то всё это туго даётся

Похвально что в таком возрасте вообще есть интерес.

P.S. Для чего так нужна была эта функция, да чисто старческая лень, не скакать каждый раз в панель табов и обратно, нажал на мышку - закрыл вкладку, нажал ещё - открыл, никуда не дергаясь мышкой.

Для чего - не интересно, интересна только сама задача, и методы её решения.

Странно, я только команды подставлял и время изменял чтобы быстрее срабатывало при зажатой кнопке, а код почему то другой стал.

Тут надо понимать для чего эти таймеры. Например SetTimer IsPress, -50 , разве физически возможно сделать двойное нажатие за 50 мсек?
И тогда в строке A_TimeSincePriorHotkey < 250 должно быть то же число.

А абстрагироваться и отладить для меня вообще тёмный лес, что отладить, как отладить.

Тут наоборот всё просто, берёте не меняя код из 22 поста. Нажимаете на Mbutton который работает независимо от окна, и смотрите ToolTip. Например ToolTip SendInput {Mbutton} в реале будет значить нажатие Mbutton. Если неподходят значения таймеров, то говорите что изменить.

Re: AHK:Расширить функционал СКМ в Firefox

2013-09-12T21:51:30Z

Странно, я только команды подставлял и время изменял чтобы быстрее срабатывало при зажатой кнопке, а код почему то другой стал. Ладно, может что не так скопировал. По поводу не интересно, оно конечно интересно своими руками сделать, вот только после 50 как то всё это туго даётся, вторую строчку прочитал, а что было в первой забыл. Утрирую немножко, но всё же. А абстрагироваться и отладить для меня вообще тёмный лес, что отладить, как отладить. Вставил в код только свои команды, правильно, или нет, не знаю, код работает, открывает, закрывает, вот только двойной клик нужно производить очень быстро, потому как если чуть медленнее(как обычно делаю в системе) код уже не срабатывает. Хотелось только это доработать если можно и всё, остальное устраивает.

#If WinActive("ahk_class MozillaWindowClass") 
Mbutton::  
    SetTimer IsPress2, Off
    If (A_PriorHotkey = "Mbutton" && A_TimeSincePriorHotkey < 250)
    {
        SetTimer IsPress, Off
        Send, ^{vk73}
        Return
    } 
    SetTimer IsPress, -250  
    Return
    
    IsPress:
        If GetKeyState("Mbutton", "P")
             SetTimer IsPress2, -750
        Else
             SendInput {Mbutton}  
        Return
    
    IsPress2:
        If GetKeyState("Mbutton", "P")
        Send, ^{vk54}
        Else
             SendInput {Mbutton} 
        Return
#If

P.S. Для чего так нужна была эта функция, да чисто старческая лень, не скакать каждый раз в панель табов и обратно, нажал на мышку - закрыл вкладку, нажал ещё - открыл, никуда не дергаясь мышкой.

Re: AHK:Расширить функционал СКМ в Firefox

2013-09-12T17:51:55Z

Абстрагируясь от окна, проведите такую отладку:


Mbutton::  
    SetTimer IsPress2, Off
    If (A_PriorHotkey = "Mbutton" && A_TimeSincePriorHotkey < 250)
    {
        SetTimer IsPress, Off
        ToolTip Открываю домашнюю страницу
        Return
    } 
    SetTimer IsPress, -250  
    Return
    
    IsPress:
        If GetKeyState("Mbutton", "P")
             SetTimer IsPress2, -750
        Else
            ToolTip SendInput {Mbutton}  
        Return
    
    IsPress2:
        If GetKeyState("Mbutton", "P")
             ToolTip Закрываю вкладку
        Else
            ToolTip SendInput {Mbutton} 
        Return

и скажите что не подходит.

Re: AHK:Расширить функционал СКМ в Firefox

2013-09-12T17:30:51Z


#If WinActive("ahk_class OperaWindowClass") 
Mbutton::  
    SetTimer IsPress2, Off
    If (A_PriorHotkey = "Mbutton" && A_TimeSincePriorHotkey < 250)
    {
        SetTimer IsPress, Off
        ToolTip Открываю домашнюю страницу
        Return
    } 
    SetTimer IsPress, -250  
    Return
    
    IsPress:
        If GetKeyState("Mbutton", "P")
             SetTimer IsPress2, -750
        Else
             SendInput {Mbutton}  
        Return
    
    IsPress2:
        If GetKeyState("Mbutton", "P")
             ToolTip Закрываю вкладку
        Else
             SendInput {Mbutton} 
        Return
#If

villla777
Неужели вам неинтересно понять что тут к чему?
Сами нагородили какой-то огород:


A_TimeSincePriorHotkey <= 250

SetTimer IsPress, -50 

SetTimer IsPress2, -150

и хотите узнать у других зачем.
Если вам надо что-то изменить, и не надо вникать в суть, то спросите как это сделать.
Лично я тут теперь ничего непонимаю.

Re: AHK:Расширить функционал СКМ в Firefox

2013-09-12T17:22:55Z

serzh82saratov
Код работает нормально, но есть маленькое неудобство, уж слишком быстро нужно делать двойной клик, чуть не успел и по новой клацай, и так несколько раз. Теми таймерами что есть, у меня регулируется только время срабатывания при удержании кнопки. Во всяком случае за пол дня так и не смог настроить на более медленный двойной клик. Может можно что то сделать, может параметр какой добавить или ещё что. Спасибо.

#If WinActive("ahk_class MozillaWindowClass") 
Mbutton::  
    If (A_PriorHotkey = "Mbutton" && A_TimeSincePriorHotkey <= 250)
    {
        SetTimer IsPress, Off
        SetTimer IsPress2, Off
Send, ^{vk54}
        
Return
    } 
    SetTimer IsPress, -50  
    Return
    
    IsPress:
        If GetKeyState("Mbutton", "P")
             SetTimer IsPress2, -150
        Else
            SendInput {Mbutton}  
        Return
    
    IsPress2:
        If GetKeyState("Mbutton", "P")
Send, ^{vk73}             

Else
            SendInput {Mbutton} 
        Return
#If

Re: AHK:Расширить функционал СКМ в Firefox

2013-09-12T10:16:30Z

Zohann пишет:

Send {Mbutton}
Return
Рекомендую справку про AHK почитать, там практически все есть, я по ней и учился.

В том то и дело что так не срабатывало вообще, значит что то я в коде накосячил, коль с неправильной записью хоть двойной клик работал. Ну в этом мне уже не разобраться. Читал я справку, и не один раз, беда в том что способности у людей разные, переназначить клавиши ещё смогу, а по сложнее уже плыву. Ладно, спасибо и на этом.

Re: AHK:Расширить функционал СКМ в Firefox

2013-09-12T09:17:42Z

Send {Mbutton}
Return

Рекомендую справку про AHK почитать, там практически все есть, я по ней и учился.

Re: AHK:Расширить функционал СКМ в Firefox

2013-09-12T06:28:49Z

Zohann
Где то около, при коротком щелчке появился кружок и срабатывает двойной клик, а вот удержание не работает.
Код такой.

Mbutton::
If WinActive("ahk_class MozillaWindowClass")
{
    n += 1
    SetTimer, KeyWin, 550
    If n = 2
Send, ^{vk54}
}        
Send {Mbutton}Return


KeyWin:
    n := 0    
    SetTimer, KeyWin, Off
    GetKeyState, state, MButton, P
    If state = D
Send, ^{vk73}
Return

Re: AHK:Расширить функционал СКМ в Firefox

2013-09-12T03:22:16Z

villla777 пишет:

$Mbutton:: не помогло.

Вставь Send {Mbutton} перед первым Return.

Re: AHK:Расширить функционал СКМ в Firefox

2013-09-11T19:47:15Z

А время нажатия как я понял меньше 250 уже не выставить.

Выставляй как удобно.

Re: AHK:Расширить функционал СКМ в Firefox

2013-09-11T19:45:04Z

serzh82saratov
А я и не заметил что для Оперы, теперь работает, спасибо. А время нажатия как я понял меньше 250 уже не выставить. Спасибо вам и Zohann что откликнулись, уж не надеялся что с чайником тут будут возиться.

Re: AHK:Расширить функционал СКМ в Firefox

2013-09-11T19:14:15Z

#If WinActive("ahk_class OperaWindowClass")

Тут заменить окно

ToolTip Открываю домашнюю страницу
и
ToolTip Закрываю вкладку

заменить на свои действия.

Re: AHK:Расширить функционал СКМ в Firefox

2013-09-11T19:09:37Z

А что тут значит Exit?

Если б я знал, в каком то коде было, да и в код от Zohann так подставлял, вроде работает.