Серый форум — AHK: Определить контрол по координатам

Re: AHK: Определить контрол по координатам

null@example.com (Zohann) — Tue, 22 Oct 2013 04:24:04 +0000

serzh82saratov пишет:

Malcev
Это можно и попроще записать:

Похоже это то что нужно!
От WinGet, ListControl, ControlList ранее отказался, т.к. он возвращал отсортированный список (Static1, Static2...), а у меня Picture передвигаемые.
Решил накодить на AHK "Три в ряд")), задача с определением контрола решена, спасибо, будем думать дальше.

Re: AHK: Определить контрол по координатам

null@example.com (serzh82saratov) — Mon, 21 Oct 2013 22:45:27 +0000

Да, что то размытые критерии.

Re: AHK: Определить контрол по координатам

null@example.com (Malcev) — Mon, 21 Oct 2013 21:59:56 +0000

Я не знаю. Но ведь работает же.
Может потому, что контролы располагаются от большего к меньшему "матрешкой"?

Re: AHK: Определить контрол по координатам

null@example.com (serzh82saratov) — Mon, 21 Oct 2013 21:05:19 +0000

Malcev
Это можно и попроще записать:



1::  MsgBox % CoordGetControl(23, 349, WinExist("A")) 
    
CoordGetControl(tX, tY, hActWin)   {
    WinGet, ListControl, ControlList, ahk_id %hActWin%  
    Loop, parse, ListControl, `n
    {
        ControlGetPos, cX, cY, cW, cH, %A_LoopField%, ahk_id %hActWin% 
        If (cX <= tX && cY <= tY && cX + cW >= tX && cY + cH >= tY) 
            (LastMinArea >= cW * cH || LastMinArea = "") 
            ? (LastMinArea := cW * cH, Control := A_LoopField) :  "" 
    }
    Return Control
}

Принцип тот же.

Но почему вы думаете что нужный нам контрол (естественно подходящий под координаты), это обязательно тот, который ниже по списку, и меньшей площадью?

Re: AHK: Определить контрол по координатам

null@example.com (Malcev) — Mon, 21 Oct 2013 19:59:48 +0000

Слизал с оф.форума.

F3::
ActiveHwnd := WinExist("A")
Control := CoordGetControl("33","186", ActiveHwnd)
msgbox % Control
Return

CoordGetControl(xCoord, yCoord, _hWin) ; _hWin should be the ID of the active window
{
    CtrlArray := Object() 
    WinGet, ControlList, ControlList, ahk_id %_hWin%
    Loop, Parse, ControlList, `n
    {
        Control := A_LoopField
        ControlGetPos, left, top, right, bottom, %Control%, ahk_id %_hWin%
      right += left, bottom += top
        if (xCoord >= left && xCoord <= right && yCoord >= top && yCoord <= bottom)
            MatchList .= Control "|"
    }
    StringTrimRight, MatchList, MatchList, 1
    Loop, Parse, MatchList, |
    {
        ControlGetPos,,, w, h, %A_LoopField%, ahk_id %_hWin%
        Area := w * h
        CtrlArray[Area] := A_LoopField
    }
    for Area, Ctrl in CtrlArray
    {
        Control := Ctrl
        if A_Index = 1
            break
    }
    return Control
}

Re: AHK: Определить контрол по координатам

null@example.com (serzh82saratov) — Mon, 21 Oct 2013 19:02:47 +0000

Malcev


1::
tX := 23, tY := 349
hActWin := WinExist("A")
WinGet, ListControl, ControlList, ahk_id %hActWin% 
 
Loop, parse, ListControl, `n
{
    ControlGetPos, cX, cY, cW, cH, %A_LoopField%, ahk_id %hActWin% 
    If (cX <= tX && cY <= tY && cX + cW >= tX && cY + cH >= tY)
    {   
        ControlGet, Visible, Visible,, %A_LoopField%, ahk_id %hActWin% 
        If Visible
            MsgBox,, %tX% - %tY%, %A_LoopField% `n x%cX% w%cW% y%cY% h%cH% 
    }
}

Вот только много совпадений. Посмотрите на калькуляторе например кнопку 7.

ап:
Так вместо 5, 3 совпадения:



1::
tX := 23, tY := 349
hActWin := WinExist("A")
WinGet, ListControl, ControlList, ahk_id %hActWin% 
 
Loop, parse, ListControl, `n
{
    ControlGetPos, cX, cY, cW, cH, %A_LoopField%, ahk_id %hActWin%
    If (cX > tX || cY > tY)
        Continue
    If (cX + cW >= tX && cY + cH >= tY)
    {   
        ControlGet, Visible, Visible,, %A_LoopField%, ahk_id %hActWin% 
        If Visible
            MsgBox,, %tX% - %tY%, %A_LoopField% `n x%cX% w%cW% y%cY% h%cH% `n Vis %Vis% 
    }
}

Re: AHK: Определить контрол по координатам

null@example.com (serzh82saratov) — Mon, 21 Oct 2013 14:49:51 +0000

В принципе если по hWnd требуется узнавать classnn контрола и порядковый номер, то ControlList всё таки тоже придётся получать.

Re: AHK: Определить контрол по координатам

null@example.com (serzh82saratov) — Mon, 21 Oct 2013 14:40:24 +0000

Malcev
Можно, кто сказал нельзя. Применить для каждого ControlGetPos, просто может занять много времени для большого списка, зато можно узнавать и в свёрнутом окне какой контрол находится в заданных координатах.

Re: AHK: Определить контрол по координатам

null@example.com (Malcev) — Mon, 21 Oct 2013 14:06:59 +0000

А почему нельзя получить список всех контролов и потом узнать к какому из них принадлежат ваши x и y.

Re: AHK: Определить контрол по координатам

null@example.com (serzh82saratov) — Mon, 21 Oct 2013 13:51:18 +0000

Возвращает хэндл контрола, а что нужно то? И Window Spy что может показать?

Re: AHK: Определить контрол по координатам

null@example.com (Zohann) — Mon, 21 Oct 2013 12:12:28 +0000

А что за 7-значные цифры эта функция возвращает? Использую на Gui, Add, Picture. Window Spy ничего похожего не показывает.

Re: AHK: Определить контрол по координатам

null@example.com (serzh82saratov) — Mon, 21 Oct 2013 11:56:14 +0000

Можно немного упростить запись:



SetFormat, IntegerFast, h

loop  
    ToolTip % hWndFromPoint( 100, 100) 
 
hWndFromPoint( x, y)
{
    Static h
    If Not h
        h:=DllCall("LoadLibrary","Str","oleacc","Ptr")
    If DllCall("oleacc\AccessibleObjectFromPoint", "Int64", x&0xFFFFFFFF|y<<32, "Ptr*", pacc)=0
        pacc := ComObjEnwrap(9,pacc,1) 
    If DllCall("oleacc\WindowFromAccessibleObject", "Ptr", IsObject(pacc)?ComObjValue(pacc):pacc, "Ptr*", hWnd)=0
        Return    hWnd
}

АП:
Исправил код в 4 посте.

Re: AHK: Определить контрол по координатам

null@example.com (serzh82saratov) — Mon, 21 Oct 2013 11:44:46 +0000

К сожалению не смог запустить

Правильно, так должно работать:


SetFormat, IntegerFast, h

loop  
    ToolTip % Acc_WindowFromObject2(Acc_ObjectFromPoint2()) 
 
Acc_ObjectFromPoint2()
{
    Acc_Init2()
    If    DllCall("oleacc\AccessibleObjectFromPoint", "Int64", x==""||y==""?0*DllCall("GetCursorPos","Int64*",pt)+pt:x&0xFFFFFFFF|y<<32, "Ptr*", pacc, "Ptr", VarSetCapacity(varChild,8+2*A_PtrSize,0)*0+&varChild)=0
    Return    ComObjEnwrap(9,pacc,1), _idChild_:=NumGet(varChild,8,"UInt")
}

Acc_WindowFromObject2(pacc)
{
    If DllCall("oleacc\WindowFromAccessibleObject", "Ptr", IsObject(pacc)?ComObjValue(pacc):pacc, "Ptr*", hWnd)=0
    Return    hWnd
}

Acc_Init2()
{
    Static    h
    If Not    h
        h:=DllCall("LoadLibrary","Str","oleacc","Ptr")
}

Это скопипастено так, без пробелов?

Да из библиотеки Acc.

а проще метода нету?

Пока в голову не пришло.

Re: AHK: Определить контрол по координатам

null@example.com (Zohann) — Mon, 21 Oct 2013 11:16:55 +0000

serzh82saratov пишет:

IsObject(pacc)?ComObjValue(pacc):pacc

Это скопипастено так, без пробелов?
Acc_Init() - этой функции нет в коде...
К сожалению не смог запустить, а проще метода нету?

Re: AHK: Определить контрол по координатам

null@example.com (serzh82saratov) — Mon, 21 Oct 2013 10:54:43 +0000


loop 
    ToolTip %  Acc_WindowFromObject2(Acc_ObjectFromPoint2( "", x = "", y = "")) 
  
Acc_ObjectFromPoint2(ByRef _idChild_ = "", x = "", y = "")
{
    Acc_Init()
    If    DllCall("oleacc\AccessibleObjectFromPoint", "Int64", x==""||y==""?0*DllCall("GetCursorPos","Int64*",pt)+pt:x&0xFFFFFFFF|y<<32, "Ptr*", pacc, "Ptr", VarSetCapacity(varChild,8+2*A_PtrSize,0)*0+&varChild)=0
    Return    ComObjEnwrap(9,pacc,1), _idChild_:=NumGet(varChild,8,"UInt")
}

Acc_WindowFromObject2(pacc)
{
    If    DllCall("oleacc\WindowFromAccessibleObject", "Ptr", IsObject(pacc)?ComObjValue(pacc):pacc, "Ptr*", hWnd)=0
    Return    hWnd
}

Acc_ObjectFromPoint2 - кормить нужными x и y относительно экрана.