Серый форум — AHK: Закрыть рабочую папку скрипта

Re: AHK: Закрыть рабочую папку скрипта

null@example.com (serzh82saratov) — Tue, 27 May 2014 03:00:38 +0000

Заметил такой баг, так как не показывал этот файл:

MsgBox % FileExist("C:\Windows\System32\SnippingTool.exe")

У меня FileExist не видит этот файл. Хотя с taskmgr.exe из этой папки всё Ок.
Убрав FileExist (из своего кода) также не работало, пока не заменил:

Run, explorer /select`, "%FilePath%"

на:

Run, %A_WinDir%\explorer.exe /select`, "%FilePath%"

Re: AHK: Закрыть рабочую папку скрипта

null@example.com (teadrinker) — Wed, 16 Apr 2014 23:05:38 +0000

Если в папке, где содержится целевой объект, находится большое количество других объектов (например, это C:\Windows\System32), тогда с указанием SetBatchLines, -1 чувствуется разница в скорости:

SelectFilePath(A_WinDir . "\System32\taskmgr.exe")

SelectFilePath(FilePath)
{
   SetBatchLines, -1
   SplitPath, FilePath,, Dir
   for window in ComObjCreate("Shell.Application").Windows
   {
      ShellFolderView := window.Document
      
      try if ((Folder := ShellFolderView.Folder).Self.Path != Dir)
         continue
      catch
         continue
      
      for item in Folder.Items
      {
         if (item.Path != FilePath)
            continue
         
         WinActivate, % "ahk_id" window.hwnd
         ShellFolderView.SelectItem(item, 1|4|8|16)
         Return
      }
   }
   Run, explorer /select`, "%FilePath%"
}

Re: AHK: Закрыть рабочую папку скрипта

null@example.com (teadrinker) — Wed, 16 Apr 2014 14:08:27 +0000

Хотя да, отсеивать лишние окна не помешает, просто посмотрел невнимательно. Но тогда уж, чтобы не получать одни и те же объекты несколько раз, так:

SelectFilePath(FilePath)
{
   SplitPath, FilePath,, Dir
   for window in ComObjCreate("Shell.Application").Windows
   {
      ShellFolderView := window.Document
      
      try if ((Folder := ShellFolderView.Folder).Self.Path != Dir)
         continue
      catch
         continue
      
      for item in Folder.Items
      {
         if (item.Path != FilePath)
            continue
         
         ShellFolderView.SelectItem(item, 1|4|8|16)
         WinActivate, % "ahk_id" window.hwnd
         Return
      }
   }
   Run, explorer /select`, "%FilePath%"
}

Re: AHK: Закрыть рабочую папку скрипта

null@example.com (teadrinker) — Wed, 16 Apr 2014 13:25:19 +0000

serzh82saratov пишет:

Ни с того ни с сего, начало ругатся что "Folder" неизвестное имя...

Да, это я упустил, что у окна IE (которое тоже относится к Shell) нет такого свойства. Так проще:

SelectFilePath(FilePath)
{
   for item in ComObjCreate("Shell.Application").Windows
   {
      window := item, ShellFolderView := item.Document
      try for item in ShellFolderView.Folder.Items
      {
         if (item.path = FilePath)
         {
            ShellFolderView.SelectItem(item, 1|4|16)   ; 1 — select the item, 4 — deselect all but the specified item, 16 — give the item the focus.
            WinActivate, % "ahk_id" hwnd := window.hwnd
            break 2
         }
      }
   }
   if !hwnd
      Run, explorer /select`, "%FilePath%"
}

Re: AHK: Закрыть рабочую папку скрипта

null@example.com (serzh82saratov) — Wed, 16 Apr 2014 12:37:19 +0000

Ни с того ни с сего, начало ругатся что "Folder" неизвестное имя... С чего бы. Хотя и выдавая ошибку всё равно дальше работает.

По случаю переделал код, чтобы не перебирать все файлы во всех окнах.


OpenDir(FilePath)    {
    SplitPath, FilePath,, FolderPath  
    for window in ComObjCreate("Shell.Application").Windows
    {
        try if (window.Document.Folder.Self.Path = FolderPath)
        { 
            try for item in window.Document.Folder.Items
            {  
                if (item.path = FilePath)
                {
                    WinActivate, % "ahk_id" window.hwnd
                    window.Document.SelectItem(item, 1|4|16|8)   
                    Return 
                }
            } 
        } 
    }
    Run, explorer /select`, "%FilePath%"
}

Re: AHK: Закрыть рабочую папку скрипта

null@example.com (serzh82saratov) — Sat, 12 Apr 2014 19:35:53 +0000

А, нашёл, нужна восьмёрка:

SelectItem(item, 1|4|16|8)

Re: AHK: Закрыть рабочую папку скрипта

null@example.com (serzh82saratov) — Sat, 12 Apr 2014 19:32:18 +0000

Ещё вопрос. При запуске файл выделяется. Но, если список длинный, и был выделен последний файл, а наш файл первый, то как сделать так чтобы выделенный файл было видно?

Re: AHK: Закрыть рабочую папку скрипта

null@example.com (serzh82saratov) — Sat, 12 Apr 2014 17:21:25 +0000

Прерывание и своего, и следующего по иерархии цикла (по умолчанию 1).

Понял.

Работает SetTitleMatchMode RegEx, просто был неверный шаблон:


SetTitleMatchMode RegEx

run D:\MyFolder
run D:\MyFolder\MyFolder
Sleep 1100
  
Dir = D:\MyFolder
While WinExist("ahk_exe explorer.exe ahk_class CabinetWClass", "im`a)^.*?: \Q" Dir "\E$")
    WinClose
Return

Re: AHK: Закрыть рабочую папку скрипта

null@example.com (teadrinker) — Sat, 12 Apr 2014 12:58:44 +0000

Прерывание и своего, и следующего по иерархии цикла (по умолчанию 1).

Re: AHK: Закрыть рабочую папку скрипта

null@example.com (serzh82saratov) — Sat, 12 Apr 2014 09:50:42 +0000

Кстати, а что тут означает 2:

break 2

или просто опечатка?

Re: AHK: Закрыть рабочую папку скрипта

null@example.com (serzh82saratov) — Sat, 12 Apr 2014 09:21:31 +0000

Так это сразу было очевидно, диалог был интересен только с познавательной стороны. И имхо оправдался познанием заморочек с SetTitleMatchMode RegEx.

Re: AHK: Закрыть рабочую папку скрипта

null@example.com (teadrinker) — Sat, 12 Apr 2014 09:17:24 +0000

Ну да, так что мой способ, имхо, предпочтительнее, он всё-таки определяет окно папки однозначно по адресу.

Re: AHK: Закрыть рабочую папку скрипта

null@example.com (serzh82saratov) — Sat, 12 Apr 2014 09:07:29 +0000

Значит работают некие непонятно\неполноценные шаблоны

Re: AHK: Закрыть рабочую папку скрипта

null@example.com (teadrinker) — Sat, 12 Apr 2014 08:36:44 +0000

Вот так сработало:

SetTitleMatchMode RegEx

run D:\MyFolder
run D:\MyFolder\MyFolder
Sleep 2000
  
Dir := "D:\MyFolder"
if WinExist("ahk_class CabinetWClass", "\Q" Dir "\E$")
   WinClose

Re: AHK: Закрыть рабочую папку скрипта

null@example.com (teadrinker) — Sat, 12 Apr 2014 08:23:53 +0000

В справке написано

RegEx (v1.0.45+): Changes WinTitle, WinText, ExcludeTitle, and ExcludeText to be regular expressions.

Но не срабатывает почему-то.