ChatArray := GetChatArray()
/*
; Сообщения просматривать так:
for k, v in ChatArray
   MsgBox, % v
*/

MsgBox, % ChatArray[ChatArray.MaxIndex()]  ; последнее сообщение чата
return

GetChatArray()
{
   if !(hwnd := WinExist("ahk_class TConversationForm"))
      ErrorExit("Окно чата не найдено")

   if !IsObject(AccSkype := Acc_ObjectFromWindow(hwnd))
      ErrorExit("Не удалось получить IAccessible из окна чата")
      
   if !IsObject(AccChat := GetAccChat(AccSkype))
      ErrorExit("Не удалось получить сообщения")

   Array := []
   for k, v in Acc_Children(AccChat)
      Array[A_Index] := v.accName(0)
   Return Array
}

GetAccChat(AccObj)
{
   if (AccObj.accName(0) = "Содержимое чата")
      Return AccObj
   
   for k, v in Acc_Children(AccObj)
      if IsObject(obj := GetAccChat(v))
         Return obj
}

ErrorExit(message)
{
   MsgBox, % message
   ExitApp
}

Acc_Init()
{
   Static   h
   If Not   h
      h:=DllCall("LoadLibrary","Str","oleacc","Ptr")
}

Acc_ObjectFromWindow(hWnd, idObject = 0)
{
   Acc_Init()
   If   DllCall("oleacc\AccessibleObjectFromWindow", "Ptr", hWnd, "UInt", idObject&=0xFFFFFFFF, "Ptr", -VarSetCapacity(IID,16)+NumPut(idObject==0xFFFFFFF0?0x46000000000000C0:0x719B3800AA000C81,NumPut(idObject==0xFFFFFFF0?0x0000000000020400:0x11CF3C3D618736E0,IID,"Int64"),"Int64"), "Ptr*", pacc)=0
   Return   ComObjEnwrap(9,pacc,1)
}

Acc_WindowFromObject(pacc)
{
   If   DllCall("oleacc\WindowFromAccessibleObject", "Ptr", IsObject(pacc)?ComObjValue(pacc):pacc, "Ptr*", hWnd)=0
   Return   hWnd
}

Acc_GetRoleText(nRole)
{
   nSize := DllCall("oleacc\GetRoleText", "Uint", nRole, "Ptr", 0, "Uint", 0)
   VarSetCapacity(sRole, (A_IsUnicode?2:1)*nSize)
   DllCall("oleacc\GetRoleText", "Uint", nRole, "str", sRole, "Uint", nSize+1)
   Return   sRole
}

Acc_GetStateText(nState)
{
   nSize := DllCall("oleacc\GetStateText", "Uint", nState, "Ptr", 0, "Uint", 0)
   VarSetCapacity(sState, (A_IsUnicode?2:1)*nSize)
   DllCall("oleacc\GetStateText", "Uint", nState, "str", sState, "Uint", nSize+1)
   Return   sState
}

; Written by jethrow
Acc_Role(Acc, ChildId=0) {
   try return ComObjType(Acc,"Name")="IAccessible"?Acc_GetRoleText(Acc.accRole(ChildId)):"invalid object"
}
Acc_State(Acc, ChildId=0) {
   try return ComObjType(Acc,"Name")="IAccessible"?Acc_GetStateText(Acc.accState(ChildId)):"invalid object"
}
Acc_Location(Acc, ChildId=0, byref Position="") { ; adapted from Sean's code
   try Acc.accLocation(ComObj(0x4003,&x:=0), ComObj(0x4003,&y:=0), ComObj(0x4003,&w:=0), ComObj(0x4003,&h:=0), ChildId)
   catch
      return
   Position := "x" NumGet(x,0,"int") " y" NumGet(y,0,"int") " w" NumGet(w,0,"int") " h" NumGet(h,0,"int")
   return   {x:NumGet(x,0,"int"), y:NumGet(y,0,"int"), w:NumGet(w,0,"int"), h:NumGet(h,0,"int")}
}
Acc_Parent(Acc) { 
   try parent:=Acc.accParent
   return parent?Acc_Query(parent):
}
Acc_Child(Acc, ChildId=0) {
   try child:=Acc.accChild(ChildId)
   return child?Acc_Query(child):
}
Acc_Query(Acc) { ; thanks Lexikos - www.autohotkey.com/forum/viewtopic.php?t=81731&p=509530#509530
   try return ComObj(9, ComObjQuery(Acc,"{618736e0-3c3d-11cf-810c-00aa00389b71}"), 1)
}
Acc_Error(p="") {
   static setting:=0
   return p=""?setting:setting:=p
}
Acc_Children(Acc) {
   if ComObjType(Acc,"Name") != "IAccessible"
      ErrorLevel := "Invalid IAccessible Object"
   else {
      Acc_Init(), cChildren:=Acc.accChildCount, Children:=[]
      if DllCall("oleacc\AccessibleChildren", "Ptr",ComObjValue(Acc), "Int",0, "Int",cChildren, "Ptr",VarSetCapacity(varChildren,cChildren*(8+2*A_PtrSize),0)*0+&varChildren, "Int*",cChildren)=0 {
         Loop %cChildren%
            i:=(A_Index-1)*(A_PtrSize*2+8)+8, child:=NumGet(varChildren,i), Children.Insert(NumGet(varChildren,i-8)=9?Acc_Query(child):child), NumGet(varChildren,i-8)=9?ObjRelease(child):
         return Children.MaxIndex()?Children:
      } else
         ErrorLevel := "AccessibleChildren DllCall Failed"
   }
   if Acc_Error()
      throw Exception(ErrorLevel,-1)
}