Серый форум — AHK: Определить процесс выделенного файла и закрыть его

Re: AHK: Определить процесс выделенного файла и закрыть его

null@example.com (Flasher) — Thu, 06 Apr 2017 11:29:43 +0000

becauseim
Вы же по ссылке отсюда пришли. Так и чем не вариант?

Re: AHK: Определить процесс выделенного файла и закрыть его

null@example.com (becauseim) — Thu, 06 Apr 2017 08:46:05 +0000

Flasher, тогда не понял, который из предложенных вариантов использовать отдельно для проводника, т.к. перепробовал вроде бы все, но заметил результат работы только тех примеров, которые ориентированы на рабочий стол.

Re: AHK: Определить процесс выделенного файла и закрыть его

null@example.com (Flasher) — Wed, 05 Apr 2017 23:05:21 +0000

becauseim
Я бы не тащил в функцию, т.к. проводниковый SelectedItems из неё не лезет, в ином случае будет лишний цикл с переменной как в первых примерах.
По приложению: если оно поддерживает списки, то почему нет? Пути же возвращаются.

Re: AHK: Определить процесс выделенного файла и закрыть его

null@example.com (becauseim) — Wed, 05 Apr 2017 19:45:34 +0000

Какую функцию наряду с GetDesktopIShellFolderViewDual() использовать для работы с проводником?
Может ли данная функция использоваться, например, для импорта выделенных файлов в определенное приложение?

Re: AHK: Определить процесс выделенного файла и закрыть его

null@example.com (teadrinker) — Mon, 02 Jun 2014 15:07:03 +0000

Ну, "писал" — это громко сказано. Так, скорректировал просто.

Re: AHK: Определить процесс выделенного файла и закрыть его

null@example.com (YMP) — Mon, 02 Jun 2014 15:01:13 +0000

Ну, в том смысле, что интересно стало, вот и спросил.

Универсальностью, наверное.

В смысле, "наверное"? Код-то ты писал или нет?

Re: AHK: Определить процесс выделенного файла и закрыть его

null@example.com (teadrinker) — Mon, 02 Jun 2014 14:49:28 +0000

В смысле? Универсальностью, наверное. Получаем IShellFolderViewDual для рабочего стола, можем использовать и другие его методы.

Re: AHK: Определить процесс выделенного файла и закрыть его

null@example.com (YMP) — Mon, 02 Jun 2014 14:46:11 +0000

teadrinker пишет:

Наверное, лучше так:

А чем лучше?

Re: AHK: Определить процесс выделенного файла и закрыть его

null@example.com (teadrinker) — Mon, 02 Jun 2014 14:27:10 +0000

serzh82saratov пишет:

И возможно ли получать его для других окон проводника?

А зачем для других окон? В других работает Shell.Application.

YMP пишет:

Вот так, например.

Наверное, лучше так:

IShellFolderViewDual := GetDesktopIShellFolderViewDual()
Return
    
F11::
    for item in IShellFolderViewDual.SelectedItems
        MsgBox, % item.Path
Return
    

GetDesktopIShellFolderViewDual()
{
    IShellWindows := ComObjCreate("{9BA05972-F6A8-11CF-A442-00A0C90A8F39}")
    desktop := IShellWindows.Item(ComObj(19, 8)) ; VT_UI4, SCW_DESKTOP                
   
    ; Retrieve top-level browser object.
    if ptlb := ComObjQuery(desktop
        , "{4C96BE40-915C-11CF-99D3-00AA004AE837}"  ; SID_STopLevelBrowser
        , "{000214E2-0000-0000-C000-000000000046}") ; IID_IShellBrowser
    {
        ; IShellBrowser.QueryActiveShellView -> IShellView
        if DllCall(NumGet(NumGet(ptlb+0)+15*A_PtrSize), "ptr", ptlb, "ptr*", psv) = 0
        {
            ; Define IID_IDispatch.
            VarSetCapacity(IID_IDispatch, 16)
            NumPut(0x46000000000000C0, NumPut(0x20400, IID_IDispatch, "int64"), "int64")
           
            ; IShellView.GetItemObject -> IDispatch (object which implements IShellFolderViewDual)
            DllCall(NumGet(NumGet(psv+0)+15*A_PtrSize), "ptr", psv
                , "uint", 0, "ptr", &IID_IDispatch, "ptr*", pdisp)
           
            IShellFolderViewDual := ComObjEnwrap(pdisp)
            ObjRelease(psv)
        }
        ObjRelease(ptlb)
    }
    return IShellFolderViewDual
}

Пробовал получить IShellBrowser для XP через WM_GETISHELLBROWSER, указатель возвращает, но выяснилось, что он в адресном пространстве проводника, так что для нас бесполезен.

Re: AHK: Определить процесс выделенного файла и закрыть его

null@example.com (YMP) — Mon, 02 Jun 2014 06:51:23 +0000

Собственно, там проблема выше, где получается объект desktop. Константа SCW_DESKTOP введена только в Висте. Поэтому в XP получить таким образом desktop не удаётся.

Re: AHK: Определить процесс выделенного файла и закрыть его

null@example.com (serzh82saratov) — Mon, 02 Jun 2014 06:37:12 +0000

А почему так, ведь:

IShellFolderViewDual пишет:

Minimum supported client Windows XP desktop apps only

Re: AHK: Определить процесс выделенного файла и закрыть его

null@example.com (YMP) — Mon, 02 Jun 2014 06:31:38 +0000

Кстати, на XP SP3 вот это не работает:


if ptlb := ComObjQuery(desktop
        , "{4C96BE40-915C-11CF-99D3-00AA004AE837}"  ; SID_STopLevelBrowser
        , "{000214E2-0000-0000-C000-000000000046}") ; IID_IShellBrowser

No valid COM object.

Re: AHK: Определить процесс выделенного файла и закрыть его

null@example.com (YMP) — Mon, 02 Jun 2014 05:48:37 +0000

Нет, это IShellFolderViewDual, насколько понимаю. Про другие окна не знаю пока.

Re: AHK: Определить процесс выделенного файла и закрыть его

null@example.com (serzh82saratov) — Mon, 02 Jun 2014 05:19:53 +0000

YMP, круто!
А тут

ComObjEnwrap(pdisp)

мы получаем объект IFolderView2 принадлежащий рабочему столу, и можем использовать все методы по ссылке? И возможно ли получать его для других окон проводника?

Re: AHK: Определить процесс выделенного файла и закрыть его

null@example.com (YMP) — Mon, 02 Jun 2014 04:58:30 +0000

Да, это работает. Вот так, например.


F11::
    SelectedItems := DesktopGetSelectedItems()
    Loop, % SelectedItems.Count
        MsgBox, % SelectedItems.Item(A_Index - 1).Name
Return
    

DesktopGetSelectedItems()
{
    shellWindows := ComObjCreate("{9BA05972-F6A8-11CF-A442-00A0C90A8F39}")
    
    desktop := shellWindows.Item(ComObj(19, 8)) ; VT_UI4, SCW_DESKTOP                
   
    ; Retrieve top-level browser object.
    if ptlb := ComObjQuery(desktop
        , "{4C96BE40-915C-11CF-99D3-00AA004AE837}"  ; SID_STopLevelBrowser
        , "{000214E2-0000-0000-C000-000000000046}") ; IID_IShellBrowser
    {
        ; IShellBrowser.QueryActiveShellView -> IShellView
        if DllCall(NumGet(NumGet(ptlb+0)+15*A_PtrSize), "ptr", ptlb, "ptr*", psv:=0) = 0
        {
            ; Define IID_IDispatch.
            VarSetCapacity(IID_IDispatch, 16)
            NumPut(0x46000000000000C0, NumPut(0x20400, IID_IDispatch, "int64"), "int64")
           
            ; IShellView.GetItemObject -> IDispatch (object which implements IShellFolderViewDual)
            DllCall(NumGet(NumGet(psv+0)+15*A_PtrSize), "ptr", psv
                , "uint", 0, "ptr", &IID_IDispatch, "ptr*", pdisp:=0)
           
            Items := ComObjEnwrap(pdisp).SelectedItems()
            ObjRelease(psv)
        }
        ObjRelease(ptlb)
    }
    return Items
}