Серый форум — CMD/BAT: Переименовать файл в подпапках каталога

Re: CMD/BAT: Переименовать файл в подпапках каталога

null@example.com (ольга) — Sun, 20 Apr 2014 09:14:20 +0000

Спасибо!

Re: CMD/BAT: Переименовать файл в подпапках каталога

null@example.com (ypppu) — Sun, 20 Apr 2014 06:03:27 +0000

ольга, как Вы заметили, код в вашем сообщении волшебным образом обрамился тегом "code".

Re: CMD/BAT: Переименовать файл в подпапках каталога

null@example.com (Yury) — Sun, 20 Apr 2014 04:45:29 +0000

setlocal enabledelayedexpansion
for /f "tokens=*" %%i in ('dir "filename.doc" /a-d /b /s 2^>nul') do (
 set date_time=!date!_!time::=.!
 ren "%%i" "filename_!date_time:~,-3!.bak"
 md "C:\Temp" 2>nul
 del /q "C:\Temp\*.bak" 2>nul
 move "%%~dpi*.bak" "C:\Temp" 2>nul
 copy "C:\Install\files\filename.doc" "%%~dpi"
)

Re: CMD/BAT: Переименовать файл в подпапках каталога

null@example.com (ольга) — Sat, 19 Apr 2014 19:16:52 +0000

Подскажите пожалуйста,как в коде ниже дописать, чтобы после переименования файла "filename.doc" в "filename_!date_time:~,-3!.bak", он (bak) перемещался (с заменой) в папку C:\Temp (если папки Temp нет, то прежде создать ее)?

@ECHO on
CD\
C:
CD Оснпапка
setlocal enabledelayedexpansion
for /f "tokens=*" %%i in ('dir /b /ad /s') do (
 set date_time=!date!_!time::=.!
 ren "%%i\filename.doc" "filename_!date_time:~,-3!.bak" 2>nul
 copy "C:\Install\files\filename.doc" "%%i"
)
pause

Заранее спасибо!

Re: CMD/BAT: Переименовать файл в подпапках каталога

null@example.com (ольга) — Fri, 18 Apr 2014 21:43:20 +0000

Спасибо большое Yury! Все работает!

Re: CMD/BAT: Переименовать файл в подпапках каталога

null@example.com (Yury) — Mon, 14 Apr 2014 11:34:55 +0000

ольга пишет:

по типу "filename_дата_время.bak"

Какие дата и время?

Если это дата и время последнего изменения файла, то так:

setlocal enabledelayedexpansion
for /f "tokens=*" %%i in ('dir /b /ad /s') do (
 for /f %%j in ("%%i\filename.doc") do (
  set date_time=%%~ti
  set date_time=!date_time: =_!
  ren "%%j" "filename_!date_time::=.!.bak" 2>nul
 )
 copy "C:\Install\files\filename.doc" "%%i"
)

Если это текущие дата и время, то так:

setlocal enabledelayedexpansion
for /f "tokens=*" %%i in ('dir /b /ad /s') do (
 set date_time=!date!_!time::=.!
 ren "%%i\filename.doc" "filename_!date_time:~,-3!.bak" 2>nul
 copy "C:\Install\files\filename.doc" "%%i"
)

ольга пишет:

имеющийся файл "filename.doc" переименовывался в "filename_дата_время.bak", затем удалялся (filename.doc)

Да удаляться-то после переименования уже как-то и нечему.

Re: CMD/BAT: Переименовать файл в подпапках каталога

null@example.com (ольга) — Mon, 14 Apr 2014 11:02:24 +0000

Решение найдено!

Re: CMD/BAT: Переименовать файл в подпапках каталога

null@example.com (ольга) — Mon, 14 Apr 2014 09:51:39 +0000

Подскажите пожалуйста, как в этом же коде сделать создание не просто файла "filename.bak", а файла по типу "filename_дата_время.bak"? Т.е. при запуске bat: имеющийся файл "filename.doc" переименовывался в "filename_дата_время.bak", затем удалялся (filename.doc) и вставлялся новый "C:\Install\files\filename.doc"?
Заранее спасибо!

Re: CMD/BAT: Переименовать файл в подпапках каталога

null@example.com (ольга) — Sun, 13 Apr 2014 14:15:25 +0000

Yury пишет:

for /f "tokens=*" %%i in ('dir /b /ad /s') do (
 ren "%%i\filename.doc" "filename.bak" 2>nul
 copy "C:\Install\files\filename.doc" "%%i"
)

Спасибо большое Вам!

Re: CMD/BAT: Переименовать файл в подпапках каталога

null@example.com (Yury) — Sun, 13 Apr 2014 13:52:46 +0000

for /f "tokens=*" %%i in ('dir /b /ad /s') do (
 ren "%%i\filename.doc" "filename.bak" 2>nul
 copy "C:\Install\files\filename.doc" "%%i"
)

CMD/BAT: Переименовать файл в подпапках каталога

null@example.com (ольга) — Sun, 13 Apr 2014 13:09:13 +0000

Здравствуйте Уважаемые программисты!
Подскажите пожалуйста, как исправить код ниже, чтобы работало следующее:
при запуске bat файла для всех вложенных папок в папке "Оснпапка" выполнялось копирование файла с именем "filename.doc" из "C:\Install\files\filename.doc", а если такой файл во вложенных папках существует, то сначала переименовать его на "filename.bak" и затем скопировать новый "filename.doc" из "C:\Install\files\filename.doc"?

Код:

@ECHO on
CD\
C:
CD Оснпапка
for /f "tokens=*" %%i in ('dir /b /ad') do (
rename filename.doc filename.bak
copy /Y "C:\Install\files\filename.doc" "%%i"
)
pause

Сейчас данный код только копирует файл "filename.doc" из "C:\Install\files\filename.doc" во все вложенные папки каталога "Оснпапка".
Заранее спасибо!