Серый форум — AHK: замена времени графикой

Re: AHK: замена времени графикой

null@example.com (dvn) — Tue, 22 Apr 2014 09:06:09 +0000

Вот в чем:

+ открыть спойлер

Как оказалось, все связано с другим файлом(

Re: AHK: замена времени графикой

null@example.com (serzh82saratov) — Tue, 22 Apr 2014 08:58:37 +0000

файлы AHK, думал наглядно посмотрите, как там все закручено)

Я понял что файлы AHK. Но долго придётся "раскручивать". Да и вопрос то собственно в чём?

Вот полностью рабочие часики:


#SingleInstance Force
#Persistent    
#NoEnv
SetBatchLines -1
ListLines Off  
Menu, Tray, Icon, Shell32.dll, 240

Folder = D:\Images\Цифры 100х65\
Controls = Hour|Min|Sec|DD|MM  
m = 2
Gui -Caption +AlwaysOnTop +E0x08000000 +E0x20 +Lastfound -DPIScale
Gui Color, F2F5FA
WinSet, TransColor, F2F5FA 
Gui Add, Picture, vHour w100 h65
Gui Add, Picture, vMin x+%m% wp hp
Gui Add, Picture, vSec x+%m% wp hp
Gui Add, Picture, % "vDD xm+" 50+m/2 " wp hp y+" m
Gui Add, Picture, vMM x+%m% wp hp
Gui Show, NA x5 y5  
 

TimeUpdate:    
    Loop, parse, Controls, |
    { 
        If (v := A_LoopField) && (Pr%v% != A_%v%) && ((Pr%v% := A_%v%) != "")
        { 
            GuiControl, -Redraw, % v
            GuiControl,, % v , % "*w100 *h65 " Folder Ceil(A_%v%) ".bmp"
            GuiControl, +Redraw, % v  
        } 
    } 
    SetTimer, TimeUpdate, % "-" (999 - A_MSec) + 100
    Return

В чём суть вашей проблемы?

Re: AHK: замена времени графикой

null@example.com (dvn) — Tue, 22 Apr 2014 08:53:58 +0000

serzh82saratov пишет:

А про файлы я ничего не понял. Задавайте просто вопросы про конкретные проблемы.

файлы AHK, думал наглядно посмотрите, как там все закручено)

Re: AHK: замена времени графикой

null@example.com (serzh82saratov) — Tue, 22 Apr 2014 08:50:17 +0000

Может не поддерживает массивы, пробуйте Loop, parse


Controls = Hour|Min|Sec|DD|MM 

TimeUpdate:    
    Loop, parse, Controls, |
    { 
        If (v := A_LoopField) && (Pr%v% != A_%v%) && (Pr%v% := A_%v%)
        {
            GuiControl, -Redraw, % v
            GuiControl,, % v, % "*w100 *h100 " Folder v ".bmp"
            GuiControl, +Redraw, % v 
        } 
    } 
    SetTimer, TimeUpdate, % "-" (999 - A_MSec) + 100
    Return

Вот ссылка на картинки.
А это файлы отвечающие за радио.

Спасибо за картинки. А про файлы я ничего не понял. Задавайте просто вопросы про конкретные проблемы.

Re: AHK: замена времени графикой

null@example.com (dvn) — Tue, 22 Apr 2014 08:44:33 +0000

Вот ссылка на картинки.
А это файлы отвечающие за радио.

Re: AHK: замена времени графикой

null@example.com (serzh82saratov) — Tue, 22 Apr 2014 08:39:11 +0000

У меня Gui..... в одном файле прописано, а остальное в другом.
Также и вставлять?

Непонятно.

Заменил свое условие, пишет ошибку на "for k, v in ["Hour","Min","Sec","DD","MM"] ".
Проверял на эмуляторе.

Может не поддерживает массивы, пробуйте

Loop, parse,

p.s. Цифры у меня нарисованы до 99, так как они еще используются для отображения громкости.

Делитесь картинками, проще на почту serzh82saratov@mail.ru

Re: AHK: замена времени графикой

null@example.com (dvn) — Tue, 22 Apr 2014 08:29:54 +0000

+ открыть спойлер

serzh82saratov пишет:

А лучше покороче:

 
Gui -Caption +AlwaysOnTop +E0x08000000 +E0x20 +Lastfound  
Gui Color, F2F5FA
WinSet, TransColor, F2F5FA 
Gui Add, Picture, vHour Border w100 h100
Gui Add, Picture, vMin Border x+5 wp hp
Gui Add, Picture, vSec Border x+5 wp hp
Gui Add, Picture, vDD Border xm+55 y+5 wp hp
Gui Add, Picture, vMM Border x+5 wp hp
Gui Show, NA x5 y5  
 
Folder = \sdmmc\radio\numbers
 
TimeUpdate:    
    for k, v in ["Hour","Min","Sec","DD","MM"]  
    {
        GuiControl, -Redraw, %v% 
        If (Pr%v% != A_%v%)
            GuiControl,, %v%, % "*w100 *h100 " Folder (Pr%v% := A_%v%) ".bmp"
        GuiControl, +Redraw, %v% 
    } 
    SetTimer, TimeUpdate, % "-" (999 - A_MSec) + 100
    Return

У меня Gui..... в одном файле прописано, а остальное в другом.

Также и вставлять?

Заменил свое условие, пишет ошибку на "for k, v in ["Hour","Min","Sec","DD","MM"] ".
Проверял на эмуляторе.

p.s. Цифры у меня нарисованы до 99, так как они еще используются для отображения громкости.

Со звуком вот так сделано:

+ открыть спойлер

Gui, Add, Picture, vVolP x70 y410 w100 h65

;обновляем громкость
RefreshRadioVol:
AUD_VOL:=DllCall(Aud_GetVolume)
    GuiControl,, Volv, %AUD_VOL%
       IfExist, %A_ScriptDir%\Skin\Radio\Volume\%AUD_VOL%.bmp
        {
        CVal1=%A_ScriptDir%\Skin\Radio\Volume\%AUD_VOL%.bmp
        CVal2=%A_ScriptDir%\Skin\Radio\Volume\%AUD_VOL%.bmp
        CName=VolP
        ButtonPress(CName, CVal1, CVal2, 0)
        }
   return

Re: AHK: замена времени графикой

null@example.com (serzh82saratov) — Tue, 22 Apr 2014 07:56:07 +0000

А лучше покороче:

 
Gui -Caption +AlwaysOnTop +E0x08000000 +E0x20 +Lastfound  
Gui Color, F2F5FA
WinSet, TransColor, F2F5FA 
Gui Add, Picture, vHour Border w100 h100
Gui Add, Picture, vMin Border x+5 wp hp
Gui Add, Picture, vSec Border x+5 wp hp
Gui Add, Picture, vDD Border xm+55 y+5 wp hp
Gui Add, Picture, vMM Border x+5 wp hp
Gui Show, NA x5 y5  
 
Folder = \sdmmc\radio\numbers
 
TimeUpdate:    
    for k, v in ["Hour","Min","Sec","DD","MM"]  
    {
        GuiControl, -Redraw, %v% 
        If (Pr%v% != A_%v%)
            GuiControl,, %v%, % "*w100 *h100 " Folder (Pr%v% := A_%v%) ".bmp"
        GuiControl, +Redraw, %v% 
    } 
    SetTimer, TimeUpdate, % "-" (999 - A_MSec) + 100
    Return

Re: AHK: замена времени графикой

null@example.com (serzh82saratov) — Tue, 22 Apr 2014 07:40:43 +0000

Попробуйте по аналогии, как на WinCE не знаю.

+ открыть спойлер


Gui Margin, 0, 0
Gui -Caption +AlwaysOnTop +E0x08000000 +E0x20 +Lastfound  
Gui Color, F2F5FA
WinSet, TransColor, F2F5FA 
Gui Add, Picture, vHour Border w100 h100
Gui Add, Picture, vMin Border x+5 wp hp
Gui Add, Picture, vSec Border x+5 wp hp
Gui Show, NA x5 y5 AutoSize 

Folder = \sdmmc\radio\numbers
arrcontrols := ["Hour","Min","Sec"] 

TimeUpdate:    
    for k, v in arrcontrols
        GuiControl, -Redraw, %v% 
    If PrHour != %A_Hour%
        GuiControl,, Hour, % "*w100 *h100 " Folder (PrHour := A_Hour) ".bmp"
    If PrMin != %A_Min%
        GuiControl,, Min, % "*w100 *h100 " Folder (PrMin := A_Min) ".bmp"
    GuiControl,, Sec, % "*w100 *h100 " Folder A_Sec ".bmp"  
    for k, v in arrcontrols
        GuiControl, +Redraw, %v% 
    SetTimer, TimeUpdate, % "-" (999 - A_MSec) + 100
    Return

я нарисовал картинки (цифры 00.bmp-60.bmp) для этих целей

А картинка 60 зачем?

---

Отредактируйте свой пост, заглавные буквы и знаки препинания никто не отменял!

AHK: замена времени графикой

null@example.com (dvn) — Tue, 22 Apr 2014 06:09:49 +0000

Тут начал переделывать оболочку на магнилолу с WinCE 6.0, столкнулся с тем, что все написано в AHK.
Только начинаю немного разбираться.
Время и дата выводится в текстовом формате:

Gui, Font, s37, %rfont%
Gui, Add, Text, vMyTime 0x1 x100 y410 w600 h50
Gui, Font, s14, %rfont%
Gui, Add, Text, vMyDate 0x1 x100 y380 w600 h25

RefreshClock:
    ;обновление часов
    FMin = %A_Min%
    if (FMin<>FMin2) 
        {
        GuiControl, , MyTime, %A_Hour% : %A_Min%
        FMin2=%FMin%
        ;обновление даты
        FDay = %A_DD%
        if (FDay<>FDay2) 
            {
            Wday:=Day%A_WDay%
            Mon:=Mon%A_Mon%
            Day:=floor(FDay)
            GuiControl, , MyDate, %Wday%, %Day% %Mon% %A_YYYY%
            FDay2=%FDay%
            }
        }
return

Я нарисовал картинки (цифры 00.bmp-60.bmp) для этих целей.
Пробовал писать, но минуты не обновляются, а зависают на той, на которой было запущено.
Помогите написать условие?!

Картинки расположены, к примеру, \sdmmc\radio\numbers