Серый форум — AHK: Альтернатива BlockInput

Re: AHK: Альтернатива BlockInput

null@example.com (teadrinker) — Sun, 22 Jun 2014 17:12:04 +0000

При нажатии мышью на заголовок текущая ветвь скрипта прерывается. Это можно проследить на примере:

Gui, Show, w300 h100
Loop
{
   ToolTip % A_Index
   Sleep, 300
}

Перетаскивайте окно за заголовок — отсчёт прервётся.
Обойти можно так:

Gui, Show, w300 h100
Return

LButton::
   if (условие)
      Return
   Send {LButton Down}
   Return

LButton Up::
   Send, {LButton Up}
   Return

Хоткей LButton Up запускает новую ветвь и она выполняется.

Re: AHK: Альтернатива BlockInput

null@example.com (Pogodin) — Sun, 22 Jun 2014 16:08:59 +0000

teadrinker пишет:

Со всеми будет проблематично.

С мышью тоже не просто оказалось. Два дня бился со странным глюком в своём скрипте: при перетаскивании окна gui за заголовок, курсор намертво "прилипал" к заголовку и окно следовало за ним как привязанное. Думал где-то перехват происходит или ещё как-то прерывается действие, но даже critical не спасал. Стал удалять код блок за блоком. В итоге осталось вот это:

LButton::
    {
    Send {LButton Down}
    KeyWait,LButton
    Send {LButton Up}
    }
return

1::
Gui,Show, x100 y100 w300 h200,Gui
Return


2::
ExitApp

И курсор по прежнему "прилипает". Судя по всему до KeyWait действия не доходят. Даже вот в таком варианте

LButton::
    {
    Send {LButton Down}
    SoundBeep
    Send {LButton Up}
    }
return

1::
Gui,Show, x100 y100 w300 h200,111
Return


2::
ExitApp

при клике на заголовок окна gui, звук не воспроизводится.

Что за странный феномен и как от него можно избавиться?

Foma, у тебя применяется gui в скрипте?

Re: AHK: Альтернатива BlockInput

null@example.com (teadrinker) — Fri, 20 Jun 2014 14:10:14 +0000

Со всеми будет проблематично.

Re: AHK: Альтернатива BlockInput

null@example.com (Foma) — Fri, 20 Jun 2014 12:24:05 +0000

Просто и эффективно с мышью получилось. А со всеми сразу клавишами также просто нельзя?

Re: AHK: Альтернатива BlockInput

null@example.com (teadrinker) — Fri, 20 Jun 2014 11:59:52 +0000

Foma пишет:

А можно подробнее о последствиях такого влияния?

Функции LowLevelMouseProc() и LowLevelKeyboardProc() для корректной работы других приложений, где установлены подобные хуки, должны возвращать

Return DllCall("CallNextHookEx", Ptr, 0, Int, nCode, UInt, wParam, UInt, lParam)

У нас же они возвращают 1, соответственно другие приложения в этот период не будут получать hook-уведомлений и могут работать некорректно.

Но как быть, с перетаскиванием? Можно что-то придумать?

LButton::
if (условие)
    return
else
{
   Send {LButton Down}
   KeyWait, LButton
   Send {LButton Up}
}
return

Re: AHK: Альтернатива BlockInput

null@example.com (Foma) — Fri, 20 Jun 2014 11:51:30 +0000

И ещё вопрос. Наверное можно заменить блокировку мыши определённой процедурой, которая будет игнорировать клик при определённых условиях, а без них работать как обычно.
Для клика реализовать это просто


LButton::
if (условие)
    return
else
    click
return

Но как быть, с перетаскиванием? Можно что-то придумать?

Re: AHK: Альтернатива BlockInput

null@example.com (Foma) — Fri, 20 Jun 2014 11:40:06 +0000

Применять с осторожностью, может повлиять на другие приложения, использующие аналогичные хуки.

А можно подробнее о последствиях такого влияния?

Re: AHK: Альтернатива BlockInput

null@example.com (Foma) — Thu, 19 Jun 2014 23:21:15 +0000

Работет. И антивирь молчит. Спасибо!

Re: AHK: Альтернатива BlockInput

null@example.com (teadrinker) — Thu, 19 Jun 2014 21:06:58 +0000

Блокируем на 5 сек мышь и клавиатуру:

OnExit, Exit
hHookMouse := DllCall("SetWindowsHookEx"
   , Int, WH_MOUSE_LL := 14
   , Ptr, RegisterCallback("LowLevelMouseProc", "Fast")
   , Ptr, DllCall("GetModuleHandle", UInt, 0, Ptr)
   , UInt, 0, Ptr)
   
hHookKeybd := DllCall("SetWindowsHookEx"
   , Int, WH_KEYBOARD_LL := 13
   , Ptr, RegisterCallback("LowLevelKeyboardProc", "Fast")
   , Ptr, DllCall("GetModuleHandle", UInt, 0, Ptr)
   , UInt, 0, Ptr)
   
Sleep 5000
DllCall("UnhookWindowsHookEx", Ptr, hHookMouse), hHookMouse := ""
DllCall("UnhookWindowsHookEx", Ptr, hHookKeybd), hHookKeybd := ""
Return

Exit:
   (hHookMouse && DllCall("UnhookWindowsHookEx", Ptr, hHookMouse))
   (hHookKeybd && DllCall("UnhookWindowsHookEx", Ptr, hHookKeybd))
   ExitApp

LowLevelMouseProc(nCode, wParam, lParam)
{
   Return 1
}

LowLevelKeyboardProc(nCode, wParam, lParam)
{
   Return 1
}

Применять с осторожностью, может повлиять на другие приложения, использующие аналогичные хуки.

Re: AHK: Альтернатива BlockInput

null@example.com (Foma) — Wed, 18 Jun 2014 18:26:43 +0000

Какие ещё способы временно заблокировать клавиатуру и кнопки мыши?

Re: AHK: Альтернатива BlockInput

null@example.com (Foma) — Wed, 18 Jun 2014 16:46:52 +0000

Антивирусник блокирует за "Прямой доступ к клавиатуре". И никак нельзя настроить. Даже добавление в исключения не помогает. Жесть...

Re: AHK: Альтернатива BlockInput

null@example.com (ypppu) — Wed, 18 Jun 2014 13:56:18 +0000

Проверил, срабатывает.

AHK: Альтернатива BlockInput

null@example.com (Foma) — Wed, 18 Jun 2014 12:32:48 +0000

Дело оказалось совсем в другом, поэтому меняю название темы и вопрос. Который теперь звучит так:
Какие существуют способы, кроме BlockInput, временно заблокировать клавиатуру и кнопки мыши?

Устарело:

По какой причине может не срабатывать BlockInput в таком виде
F1::
ToolTip,start
BlockInput,on
Sleep, 10000    
BlockInput, off
ToolTip,End
Sleep, 500
ExitApp
в скомпилированном файле?