Серый форум — AHK: sleep в пределах одного блока

Re: AHK: sleep в пределах одного блока

null@example.com (ypppu) — Thu, 24 Jul 2014 15:22:09 +0000

Чувствую, это будут часы-таймер на 12400 строк.

Re: AHK: sleep в пределах одного блока

null@example.com (serzh82saratov) — Thu, 24 Jul 2014 12:25:32 +0000

А также плюс, то что код будет не ввиде переменной, а в обычном виде. Всё включая Main: это стандартная шапка в которой не надо разбиратся, далее пишем сколько угодно меток. При закрытии или перезагрузке основного скрипта, остальные тоже закрываются моментально.


#NoTrayIcon
#SingleInstance Off 

WM_CloseMyScript := DllCall("RegisterWindowMessage", "Str", "CloseAHKScripts")
OnMessage(WM_CloseMyScript, "WM_CloseMyScript")
OnExit, CloseAll
Param = %1% 
If Param =
    PostMessage, WM_CloseMyScript, 0, A_ScriptHWND,, ahk_id 0xFFFF 
GoTo % IsLabel(Param) ? Param : "Main" 

WM_CloseMyScript(wParam, lParam)   { 
    If (lParam != A_ScriptHWND)  {
        OnExit
        ExitApp
    }
    return true
}

Esc::
CloseAll:
    PostMessage, WM_CloseMyScript, 0, A_ScriptHWND,, ahk_id 0xFFFF
    ExitApp
    
    
Main:
    Menu, Tray, Icon
    Loop
    {
        ToolTip % A_Index "|" A_TickCount 
        If !Mod(A_Index, 100) ; тут любое условие
        { 
            Process, Exist, %Pid_Send% ; это для того чтобы не запустить, если скрипт ещё не закрылся. Если оно конечно нужно.
            If (Pid_Send = "" || !ErrorLevel)
                Run, %A_ScriptFullPath% Send, , , Pid_Send 
        }
    }
 
Send:
    Send 9
    sleep, 500
    Send 8
    sleep, 500
    Send 7
    sleep, 300
    Send 6
    sleep, 100
    Send 5
    OnExit
    ExitApp

С командой GuiControl конечно не выйдет, но можно в параметрах ком строки передавать хэндлы нужных контролов, и делать тоже самое командами Control*.
Если во вторичных скриптах перед ExitApp не прописать OnExit, то все скрипты будут закрыты, что в некоторых случаях может быть удобно.

Re: AHK: sleep в пределах одного блока

null@example.com (serzh82saratov) — Thu, 24 Jul 2014 11:28:25 +0000

Malcev пишет:

А можно и отдельный процесс создать внутри скрипта, но выглядить будет сложнее:

Думаю так будет проще http://forum.script-coding.com/viewtopi … 612#p84612, так и файлы не надо ни создавать ни удалять, и файл скрипта только один.

Re: AHK: sleep в пределах одного блока

null@example.com (Странникх) — Thu, 24 Jul 2014 11:22:57 +0000

Создавать тоже интересный способ и по началу я даже хотел все переписать с SetTimer'ов, но в результате выходит примерно также по сложности.

Самый простой вариант из всего - иметь уже созданные файлы и загружать их тогда, когда они нужны.

Re: AHK: sleep в пределах одного блока

null@example.com (Malcev) — Thu, 24 Jul 2014 10:46:25 +0000

Одним файлом можно создавать остальные, запускать их и при выходе из скрипта стирать.
А можно и отдельный процесс создать внутри скрипта, но выглядить будет сложнее:
http://forum.script-coding.com/viewtopi … 427#p65427

Re: AHK: sleep в пределах одного блока

null@example.com (Странникх) — Thu, 24 Jul 2014 10:35:27 +0000

Да, но мне не нравится факт того, что нужно иметь вместо одного файла в папке четыре, а то и больше. Я преследую цель - упростить все. Не люблю трудности, как по себе человек простой.

Re: AHK: sleep в пределах одного блока

null@example.com (Malcev) — Thu, 24 Jul 2014 10:11:10 +0000

Почитайте внимательно ссылку в 13 посте.
Александр_ там все по полочкам раскладывает.

чтобы не забивать этим трей

http://www.script-coding.com/AutoHotkey/NoTrayIcon.html

Re: AHK: sleep в пределах одного блока

null@example.com (Странникх) — Thu, 24 Jul 2014 10:08:20 +0000

Ну.. да, в принципе можно создать кучу AHK скриптов, которые открывались бы и закрывались бы, чтобы не забивать этим трей.
Но я все равно буду искать ближайшее время решение, чтобы уместить все в одном скрипте. О и да пока писал кажется его нашел! Называется установка кучи таймеров с разным временем ожидания, то есть:

SetTimer, sleeper500, 500
sleeper500:
if x = 0
{
GuiControl, 2: Show, TimerText25
x = 1
Return ; Вот отсюда таймер запустится в 500 мс. Грубо говоря он подождет 500 мс, так как было бы написав sleep, 500 и приступит к выполнению дальше (то есть где x = 1)
}
if x = 1
{
GuiControl, 2: Hide, TimerText25
GuiControl, 2: Show, TimerText20
}
} ; Ну аналогию Вы дальше поняли

Re: AHK: sleep в пределах одного блока

null@example.com (Malcev) — Thu, 24 Jul 2014 09:49:22 +0000

Как заметил ypppu:

В AutoHotkey нет параллельных потоков

Хотите мультипоточность создавайте 2 скрипта и между ними обменивайтесь информацией.
Про псевдомультипоточность тут разбирались:
http://forum.script-coding.com/viewtopic.php?id=6406

Re: AHK: sleep в пределах одного блока

null@example.com (Странникх) — Thu, 24 Jul 2014 09:30:52 +0000

Timer: 
{
GuiControl, 2: Show, TimerText25
sleep, 500
GuiControl, 2: Hide, TimerText25
GuiControl, 2: Show, TimerText20
sleep, 500
GuiControl, 2: Hide, TimerText20
GuiControl, 2: Show, TimerText15
sleep, 500
GuiControl, 2: Hide, TimerText15
GuiControl, 2: Show, TimerText10
sleep, 400
GuiControl, 2: Hide, TimerText10
GuiControl, 2: Show, TimerText06
sleep, 300
GuiControl, 2: Hide, TimerText06
GuiControl, 2: Show, TimerText03
sleep, 100
GuiControl, 2: Hide, TimerText03
GuiControl, 2: Show, TimerText02
sleep, 100
GuiControl, 2: Hide, TimerText02
GuiControl, 2: Show, TimerText01
sleep, 100
GuiControl, 2: Hide, TimerText01
Gui, 2: Hide
time = 0
}
Return

Вот мой кусок кода, чей поток должен быть отделен от другого потока, либо иметь альтернативную паузу заместо sleep, не мешающей работать другим потокам (не останавливать работу других потоков).

Re: AHK: sleep в пределах одного блока

null@example.com (serzh82saratov) — Thu, 24 Jul 2014 09:19:29 +0000

Чего?

Re: AHK: sleep в пределах одного блока

null@example.com (Странникх) — Thu, 24 Jul 2014 09:16:51 +0000

Так, вроде бы понятно, но конкретной задачи это не решает. Он лишь под цифры.

А если скажем я захочу сделать перебор с gui типа:?

guicontrol, 1: show, text
sleep, 500
guicontrol, 2: Hide, text

Re: AHK: sleep в пределах одного блока

null@example.com (serzh82saratov) — Thu, 24 Jul 2014 08:50:21 +0000

А это уже глупый вопрос.
Простейшие параметры команды ToolTip описаны в справке.

X, Y
Х и Y позиция подсказка относительно активного окна (использовать CoordMode, подсказка, чтобы изменить экранные координаты). Если координаты опущены, подсказка будет показан рядом с курсором мыши. Х и Y могут быть выражениями.
WhichToolTip
Пропустите этот параметр, если вам не нужно несколько подсказок появляться одновременно. В противном случае, это число от 1 до 20, чтобы указать, какие подсказки окно для работы на. Если не указано, что число 1 (первый). Этот параметр может быть выражением.

Re: AHK: sleep в пределах одного блока

null@example.com (Странникх) — Thu, 24 Jul 2014 08:44:50 +0000

111, 111, 1

А вот это что такое после ToolTip % A_Index "|" A_TickCount?

Re: AHK: sleep в пределах одного блока

null@example.com (serzh82saratov) — Thu, 24 Jul 2014 08:22:20 +0000


Arr := [["9", 500], ["8", 500], ["7", 300], ["6", 100], ["5", 0]]  
N := 0

Loop
{
    ToolTip % A_Index "|" A_TickCount, 111, 111, 1
    If !N ; Если в данный момент массив неперебирается, то запускаем метку. Также есть возможность прерывать текущее выполнение, начиная сначала подпрограмму
        GoSub, LoopSend
}

LoopSend: 
    If !(N := ++N > Arr.MaxIndex() ? 0 : N) ; Плюсуем к N единицу, если достигли конца массива, то назначаем N в 0, и прекращаем выполнение
        Return
    SetTimer, LoopSend, % "-" . Arr[N, 2] ; Назначаем однократный таймер равный 2 параметру в N массиве 
    SendInput % Arr[N, 1] ; Нажимаем кнопку которая в 1 параметре текущего массива
    Return