1

Тема: VBScript: кодирование по алгоритму base64

Кодирование base64 — это схема, по которой произвольная последовательность байтов преобразуется в последовательность печатаемых ASCII символов. Как правило, используются символы латинского алфавита в верхнем и нижнем регистре (A—Z, a—z), цифры (0—9), символы «+» и «/» и символ «=» в качестве специального суффикса. В некоторых реализациях base64 вместо символов «+», «/» и «=» используются другие символы. Base64 не является шифрованием и используется, в основном, для удобства транспортировки и хранения данных. Результирующие данные имеют длину, большую оригинальной в соотношении 4:3.

Пример ниже копирует существующий файл "C:\Temp\test.jpg", создавая файл "C:\Temp\test2.jpg". Исходный файл считывается и преобразуется в строку base64, затем полученная строка base64 преобразуется обратно в массив байтов и записывается на диск в виде файла. Используются объекты MSXml2.DOMDocument и ADODB.Stream.

Set objStream = CreateObject("ADODB.Stream")
objStream.Type = 1 ' TypeBinary
objStream.Open()
objStream.LoadFromFile("C:\Temp\test.jpg")
readBytes = objStream.Read()
Set objXML = CreateObject("MSXml2.DOMDocument")
objXML.loadXML "<Base64Data />"
Set objDocElem = objXML.documentElement
objDocElem.dataType = "bin.base64"
objDocElem.nodeTypedValue = readBytes
textBase64 = objDocElem.text

WScript.Echo textBase64

Set objXML = CreateObject("MSXml2.DOMDocument")
Set objDocElem = objXML.createElement("tmp")
objDocElem.DataType = "bin.base64"
objDocElem.text = textBase64
writeBytes = objDocElem.NodeTypedValue
Set objStream = CreateObject("ADODB.Stream")
objStream.Type = 1 ' TypeBinary
objStream.Open()
objStream.Write writeBytes
objStream.SaveToFile "C:\Temp\test2.jpg", 2
Предложения в русском языке начинаются с большой буквы и заканчиваются точкой.
В названии ветки всегда должен быть указан язык программирования или среда исполнения скрипта, если это возможно.

2

Re: VBScript: кодирование по алгоритму base64

Бесплатный COM-сервер Base64 Component позволяет закодировать/раскодировать строку или массив байтов по алгоритму base64. Компонент можно скачать здесь, ссылка на скачивание высылается на e-mail. Размер дистрибутива (архив) — порядка 35 Кб.

Пример работы со строками:

Const otSafeArray = 0
Const otString = 2
Set objBase64 = CreateObject("XStandard.Base64")
WScript.Echo objBase64.Encode("Hello World!", otString)
WScript.Echo objBase64.Decode("SGVsbG8gV29ybGQh", otString)

Копирование бинарного файла через преобразование его в строку base64: пример ниже копирует существующий файл "C:\Temp\test.jpg", создавая файл "C:\Temp\test2.jpg". Исходный файл считывается и преобразуется в строку base64, затем полученная строка base64 преобразуется обратно в массив байтов и записывается на диск в виде файла:

Const otSafeArray = 0
Const otString = 2
Set objBase64 = CreateObject("XStandard.Base64")

Set objStream = CreateObject("ADODB.Stream")
objStream.Type = 1 ' TypeBinary
objStream.Open()
objStream.LoadFromFile("C:\Temp\test.jpg")
readBytes = objStream.Read()
textBase64 = objBase64.Encode(readBytes, otString)

WScript.Echo textBase64

Set objStream = CreateObject("ADODB.Stream")
objStream.Type = 1 ' TypeBinary
objStream.Open()
writeBytes = objBase64.Decode(textBase64, otSafeArray)
objStream.Write writeBytes
objStream.SaveToFile "C:\Temp\test2.jpg", 2

Простой пример записи бинарного файла из строки base64:

Const otSafeArray = 0
Const otString = 2
Set objBase64 = CreateObject("XStandard.Base64")
strImage = "R0lGODlhEgASAKIAAMDAwICAgP8AAAAAAP///w" & _
"AAAAAAAAAAACH5BAAAAAAALAAAAAASABIAAAM8" & _
"SLrc/rCJSWdU1b4xAqZKwDWcR2iiSXZMGpUKfJ" & _
"XyRYisTQDcaPOD2AAQwTE4RIdxlVwsHUinD1LT" & _
"WSMJADs="
Set objStream = CreateObject("ADODB.Stream")
objStream.Type = 1 ' TypeBinary
objStream.Open()
writeBytes = objBase64.Decode(strImage, otSafeArray)
objStream.Write writeBytes
objStream.SaveToFile "C:\Temp\test.gif", 2
Предложения в русском языке начинаются с большой буквы и заканчиваются точкой.
В названии ветки всегда должен быть указан язык программирования или среда исполнения скрипта, если это возможно.

3

Re: VBScript: кодирование по алгоритму base64

Пример ниже копирует существующий файл "C:\Temp\test.jpg", создавая файл "C:\Temp\test1.jpg". Исходный файл считывается и преобразуется в строку base64, затем полученная строка base64 преобразуется обратно в массив байтов и записывается на диск в виде файла. На этот раз используется объект BinaryOps.

Set bin = CreateObject("JSBin.BinaryOps")
L = 0 ' чтение с начала файла
e = bin.BinaryRead("C:\Temp\test.jpg", 0, L, A) ' чтение файла в массив ByteArray
s = bin.BytesToBase64(A) ' конвертация в строку Base64

WScript.Echo s

e = bin.Base64ToBytes(s, A1) ' конвертация строки Base64 в массив ByteArray
e = bin.BinaryOpen("C:\Temp\test1.jpg", L) ' открытие (возможно) несуществующего файла на запись
e = bin.BinaryWrite(A1, 0) ' запись файла
e = bin.BinaryClose ' закрытие файла
Предложения в русском языке начинаются с большой буквы и заканчиваются точкой.
В названии ветки всегда должен быть указан язык программирования или среда исполнения скрипта, если это возможно.

4

Re: VBScript: кодирование по алгоритму base64

Компонент ChilkatUtil.dll, который содержит несколько полезных COM-серверов (в т.ч. CkData), устанавливается вместе с Chilkat Spider. Документацию по объекту CkData можно найти здесь.

Пример ниже копирует существующий файл "C:\Temp\test.jpg", создавая файл "C:\Temp\test1.jpg". Исходный файл считывается и преобразуется в строку base64, затем полученная строка base64 обратно загружается в объект и записывается на диск в виде файла.

Set oData = CreateObject("Chilkat.CkData")
oData.LoadFile "C:\Temp\test.jpg" ' открытие и загрузка двоичного файла
oData.Base64LineLength = 64 ' максимальная длина строки при преобразовании в Base64 (по умолчанию - 72)
txt = oData.GetBase64()
oData.LoadBase64 txt
oData.SaveToFile "C:\Temp\test1.jpg" ' сохранение данных в двоичный файл
Предложения в русском языке начинаются с большой буквы и заканчиваются точкой.
В названии ветки всегда должен быть указан язык программирования или среда исполнения скрипта, если это возможно.

5

Re: VBScript: кодирование по алгоритму base64

Кодировать строки в Base64 можно и с помощью библиотеки capicom.dll. Начиная с Windows XP, эта библиотека должна содержаться в поставке операционной системы.

Set capicom = CreateObject("CAPICOM.Utilities")
b64 = capicom.Base64Encode("Здравствуй, дедушка Мороз!")
WScript.Echo b64
what = capicom.Base64Decode(b64)
WScript.Echo what

Автор идеи — ingvar68.

Предложения в русском языке начинаются с большой буквы и заканчиваются точкой.
В названии ветки всегда должен быть указан язык программирования или среда исполнения скрипта, если это возможно.

6

Re: VBScript: кодирование по алгоритму base64

Бесплатный COM-сервер Buffer Component предназначен для чтения и записи бинарных файлов, вычисления контрольных сумм MD5 и преобразований Base64. Скачать компонент можно здесь (ссылка для скачивания высылается на e-mail). Дистрибутив (архив) имеет размер чуть более 35 Кб.

Пример:

Set oBuffer = CreateObject("XStandard.Buffer")
oBuffer.Write "Здравствуй, дедушка Мороз!"
oBuffer.SaveAs "C:\Temp\test.txt"
oBuffer.Reset()

oBuffer.Load "C:\Temp\test.txt"
WScript.Echo oBuffer.Base64String
oBuffer.Reset()

oBuffer.Write "Здравствуй, дедушка Мороз!"
WScript.Echo oBuffer.Base64String
Предложения в русском языке начинаются с большой буквы и заканчиваются точкой.
В названии ветки всегда должен быть указан язык программирования или среда исполнения скрипта, если это возможно.

7

Re: VBScript: кодирование по алгоритму base64

Еще один пример кодирования/декодирования встроенными средствами JS

/**
*
*  Base64 encode / decode
*  http://www.webtoolkit.info/
*
**/

var Base64 = {

    // private property
    _keyStr : "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/=",

    // public method for encoding
    encode : function (input) {
        var output = "";
        var chr1, chr2, chr3, enc1, enc2, enc3, enc4;
        var i = 0;

        input = Base64._utf8_encode(input);

        while (i < input.length) {

            chr1 = input.charCodeAt(i++);
            chr2 = input.charCodeAt(i++);
            chr3 = input.charCodeAt(i++);

            enc1 = chr1 >> 2;
            enc2 = ((chr1 & 3) << 4) | (chr2 >> 4);
            enc3 = ((chr2 & 15) << 2) | (chr3 >> 6);
            enc4 = chr3 & 63;

            if (isNaN(chr2)) {
                enc3 = enc4 = 64;
            } else if (isNaN(chr3)) {
                enc4 = 64;
            }

            output = output +
            this._keyStr.charAt(enc1) + this._keyStr.charAt(enc2) +
            this._keyStr.charAt(enc3) + this._keyStr.charAt(enc4);

        }

        return output;
    },

    // public method for decoding
    decode : function (input) {
        var output = "";
        var chr1, chr2, chr3;
        var enc1, enc2, enc3, enc4;
        var i = 0;

        input = input.replace(/[^A-Za-z0-9\+\/\=]/g, "");

        while (i < input.length) {

            enc1 = this._keyStr.indexOf(input.charAt(i++));
            enc2 = this._keyStr.indexOf(input.charAt(i++));
            enc3 = this._keyStr.indexOf(input.charAt(i++));
            enc4 = this._keyStr.indexOf(input.charAt(i++));

            chr1 = (enc1 << 2) | (enc2 >> 4);
            chr2 = ((enc2 & 15) << 4) | (enc3 >> 2);
            chr3 = ((enc3 & 3) << 6) | enc4;

            output = output + String.fromCharCode(chr1);

            if (enc3 != 64) {
                output = output + String.fromCharCode(chr2);
            }
            if (enc4 != 64) {
                output = output + String.fromCharCode(chr3);
            }

        }

        output = Base64._utf8_decode(output);

        return output;

    },

    // private method for UTF-8 encoding
    _utf8_encode : function (string) {
        string = string.replace(/\r\n/g,"\n");
        var utftext = "";

        for (var n = 0; n < string.length; n++) {

            var c = string.charCodeAt(n);

            if (c < 128) {
                utftext += String.fromCharCode(c);
            }
            else if((c > 127) && (c < 2048)) {
                utftext += String.fromCharCode((c >> 6) | 192);
                utftext += String.fromCharCode((c & 63) | 128);
            }
            else {
                utftext += String.fromCharCode((c >> 12) | 224);
                utftext += String.fromCharCode(((c >> 6) & 63) | 128);
                utftext += String.fromCharCode((c & 63) | 128);
            }

        }

        return utftext;
    },

    // private method for UTF-8 decoding
    _utf8_decode : function (utftext) {
        var string = "";
        var i = 0;
        var c = c1 = c2 = 0;

        while ( i < utftext.length ) {

            c = utftext.charCodeAt(i);

            if (c < 128) {
                string += String.fromCharCode(c);
                i++;
            }
            else if((c > 191) && (c < 224)) {
                c2 = utftext.charCodeAt(i+1);
                string += String.fromCharCode(((c & 31) << 6) | (c2 & 63));
                i += 2;
            }
            else {
                c2 = utftext.charCodeAt(i+1);
                c3 = utftext.charCodeAt(i+2);
                string += String.fromCharCode(((c & 15) << 12) | ((c2 & 63) << 6) | (c3 & 63));
                i += 3;
            }

        }

        return string;
    }

}

// ============================================================
// Пример использования:
WScript.Echo(Base64.encode("Текст, который мы хотим закодировать"));
WScript.Echo(Base64.decode("0Jgg0YfRgtC+INC40Lcg0Y3RgtC+0LPQviDQv9C+0LvRg9GH0LjQu9C+0YHRjA=="));

8 (изменено: mozers, 2012-03-28 22:57:01)

Re: VBScript: кодирование по алгоритму base64

Очень наглядное HTA приложение, позволяющее выбрать кодировку текста, алгоритм кодирования (hex или base64) а также версию Microsoft Core XML Services (MSXML) из числа установленных в системе для кодирования/декодирования текста. Исходный вариант (с использованием VBScript) опубликовал Xameleon в этой теме.
XMLCodeTester.hta

<html>
<head>
    <title>XML encode/decode Tester</title>
    <meta http-equiv=content-type content="text-html; charset=windows-1251">
    <meta http-equiv=MSThemeCompatible content=yes>
    <hta:application
        icon=keymgr.dll
        scroll=no
    >
    <style type="text/css">
        * {font-family:Verdana;font-size:12px;}
        textarea {font: 12px Courier New; width:100%; height:100%;}
    </style>
</head>
<body onload="MSXML_Init()">
    <table width=100% height=100%>
        <tr>
            <td colspan=4>
                &nbsp;<b>Кодировка:</b>
                <select id="selCharset">
                    <!--Доступные значения: HKEY_CLASSES_ROOT\MIME\Database\Charset -->
                    <option value="windows-1251">windows-1251</option>
                    <option value="cp866">cp866</option>
                    <option value="koi8-r">koi8-r</option>
                    <option value="utf-8">utf-8</option>
                    <option value="unicodeFFFE">utf-16le</option>
                </select>
                &nbsp;<b>Кодировщик:</b>
                <select id="selEncoder">
                    <option value="bin.base64">bin.base64</option>
                    <option value="bin.hex">bin.hex</option>
                </select>
                &nbsp;<b>ActiveX:</b> MSXML version <select id="msxml_version"></select>
                <hr>
            </td>
        </tr>
        <tr>
            <td><b>Исходные данные</b></td>
            <td><button id="btnEncode">Кодировать</button></td>
            <td><b>Закодированные данные</b></td>
            <td><button id="btnDecode">Декодировать</button></td>
        </tr>
        <tr height=100%>
            <td colspan=2 width=50%><textarea id="txtDecoded"></textarea></td>
            <td colspan=2><textarea id="txtEncoded"></textarea></td>
        </tr>
    </table>
</body>
<script type="text/javascript">
    btnEncode.onclick = function(){
        if (txtDecoded.value) {
            oXML = new ActiveXObject('Msxml2.DOMDocument.' + msxml_version.value);
            var bin = StrToBin(txtDecoded.value, selCharset.value);
            txtEncoded.value = Encode(bin, selEncoder.value);
        }
    };

    btnDecode.onclick = function(){
        if (txtEncoded.value) {
            oXML = new ActiveXObject('Msxml2.DOMDocument.' + msxml_version.value);
            var bin = Decode(txtEncoded.value, selEncoder.value);
            txtDecoded.value = BinToStr(bin, selCharset.value);
        }
    };

    function BinToStr(data, codepage){
        with (new ActiveXObject('ADODB.Stream')) {
            Type = 1; //adTypeBinary
            Open();
            Write(data);
            position = 0;
            Type = 2; //adTypeText
            charset = codepage;
            return readText();
        }
    }

    function StrToBin(text, codepage){
        with (new ActiveXObject('ADODB.Stream')) {
            Type = 2; //adTypeText
            charset = codepage;
            Open();
            WriteText(text);
            position = 0;
            Type = 1; //adTypeBinary
            return read();
        }
    }

    function Encode(data, encoder){
        with (oXML.createElement("tmp")){
            dataType = encoder;
            nodeTypedValue = data;
            return text;
        }
    }

    function Decode(data, encoder){
        with (oXML.createElement("tmp")){
            dataType = encoder;
            text = data;
            return nodeTypedValue;
        }
    }

    function MSXML_Init() {
        var vers = ['1.0', '2.0', '2.5', '2.6', '3.0', '4.0', '5.0', '6.0'];
        for (var i = 0; i < vers.length; i++) {
            try {
                oXML = new ActiveXObject('Msxml2.DOMDocument.'+vers[i]);
                var option = document.createElement("option");
                option.value = vers[i];
                option.text = vers[i];
                msxml_version.add(option);
            } catch (e) {}
        }
    }
</script>
</html>

9 (изменено: mozers, 2012-03-28 22:57:32)

Re: VBScript: кодирование по алгоритму base64

Еще одно HTA приложение осуществляющее кодирование и декодирование текста windows-1251 в base64 и обратно.
Всю работу выполняет объект XML и VBScript. Автор - Xameleon - обошелся без "ADODB.Stream" и без сложных математических вычислений.
Base64EncoderDecoder.hta

<html>
<head>
    <title>Base64 Encoder/Decoder</title>
    <meta http-equiv=content-type content="text-html; charset=windows-1251">
    <meta http-equiv=MSThemeCompatible content=yes>
    <hta:application
        icon=keymgr.dll
        scroll=no
    >
    <style type="text/css">
        * {font-family:Verdana;font-size:12px;}
        textarea {font: 12px Courier New; width:100%; height:100%;}
    </style>
</head>
<body>
    <table width=100% height=100%>
        <tr>
            <td><b>Исходные данные</b><br>(в кодировке windows-1251)</td>
            <td><button id="btnEncode">Кодировать в base64</button></td>
            <td><b>Закодированные данные</b></td>
            <td><button id="btnDecode">Декодировать из base64</button></td>
        </tr>
        <tr height=100%>
            <td colspan=2 width=50%><textarea id="txtDecoded"></textarea></td>
            <td colspan=2><textarea id="txtEncoded"></textarea></td>
        </tr>
    </table>
</body>
<script type="text/vbscript">
Option Explicit

Sub btnEncode_onclick()
    if txtDecoded.value <> "" Then txtEncoded.value = strTobase64(txtDecoded.value)
End Sub

Sub btnDecode_onclick()
    if txtEncoded.value <> "" Then txtDecoded.value = base64ToStr(txtEncoded.value)
End Sub

'Кодирование String в base64
Function strTobase64(data)
    With document.createElement("xml").createElement("t")
        .dataType = "bin.base64"
        .nodeTypedValue = strToBin(data)
        strTobase64 = .text
    End With
End Function

'Декодирование base64 в String
Function base64ToStr(data)
    With document.createElement("xml").createElement("t")
        .dataType = "bin.base64"
        .text = data
        base64ToStr = binToStr(.nodeTypedValue)
    End With
End Function

'Конвертация String в Byte()
Function strToBin(text)
    With document.createElement("xml").createElement("t")
        .dataType = "bin.hex"
        .text = strTohex(text)
        strToBin = .nodeTypedValue
    End With
End Function

'Конвертация Byte() в String
Function binToStr(data)
    With document.createElement("xml").createElement("t")
        .dataType = "bin.hex"
        .nodeTypedValue = data
        binToStr = hexToStr(.text)
    End With
End Function

'Кодирование строки в HEX
Function strTohex(text)
    Dim tmp, i
    For i = 1 To Len(text)
        tmp = tmp & Right("0" & Hex(Asc(Mid(text, i, 1))), 2)
    Next
    strTohex = tmp
End Function

'Декодирование строки из HEX
Function hexToStr(hexStr)
    Dim tmp, i
    For i = 1 To Len(hexStr) Step 2
        tmp = tmp & Chr("&H" & Mid(hexStr, i, 2))
    Next
    hexToStr = tmp
End Function
</script>
</html>