Получить имя окна которое в фокусе

Option Explicit
Const TH32CS_SNAPHEAPLIST = &H1
Const TH32CS_SNAPPROCESS = &H2
Const TH32CS_SNAPTHREAD = &H4
Const TH32CS_SNAPMODULE = &H8
Const TH32CS_SNAPALL = (TH32CS_SNAPHEAPLIST Or TH32CS_SNAPPROCESS Or TH32CS_SNAPTHREAD Or TH32CS_SNAPMODULE)
Const TH32CS_INHERIT = &H80000000
Const MAX_PATH As Integer = 260

Private Type PROCESSENTRY32
dwSize As Long
cntUsage As Long
th32ProcessID As Long
th32DefaultHeapID As Long
th32ModuleID As Long
cntThreads As Long
th32ParentProcessID As Long
pcPriClassBase As Long
dwFlags As Long
szExeFile As String * MAX_PATH
End Type

Private Declare Function CreateToolhelp32Snapshot Lib "Kernel32" (ByVal lFlags As Long, ByVal lProcessID As Long) As Long
Private Declare Function Process32First Lib "Kernel32" (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Private Declare Function Process32Next Lib "Kernel32" (ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Private Declare Sub CloseHandle Lib "Kernel32" (ByVal hPass As Long)
Private Declare Function GetForegroundWindow Lib "user32" () As Long
Private Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hwnd As Long, lpdwProcessId As Long) As Long

Private Sub Timer1_Timer()
    Dim wnd As Long
    Dim pid As Long
    Dim nid As Long
    Dim hSnapShot As Long
    Dim uProcess As PROCESSENTRY32
    Dim r As Long
    
    'получаем hWnd активного окно
    wnd = GetForegroundWindow()
    'получаем ProcessId (PID) для активного окна
    nid = GetWindowThreadProcessId(wnd, pid)
    'Моментальный снимок процессов и кучи, модулей и потоков, используемых процессами
    hSnapShot = CreateToolhelp32Snapshot(TH32CS_SNAPALL, 0&)
    'установить длину наш ПроцессВвода типа
    uProcess.dwSize = Len(uProcess)
    'Получить информацию о первом процессе, встречающихся в нашей системе снимок
    r = Process32First(hSnapShot, uProcess)
    ' перебераем список всех процессов (PID)
    Do While r
        If uProcess.th32ProcessID = pid Then ' ищим PID активного окна
            ' нашли искомый процесс, получаем имя файла процесса
            Print Left$(uProcess.szExeFile, IIf(InStr(1, uProcess.szExeFile, Chr$(0)) > 0, InStr(1, uProcess.szExeFile, Chr$(0)) - 1, 0))
        End If
        ' переходим к следующему процессу
        r = Process32Next(hSnapShot, uProcess)
    Loop
    'закрыть снимок ручкой
    CloseHandle hSnapShot
End Sub