Серый форум — CMD/BAT: Удаление определенных папок

Re: CMD/BAT: Удаление определенных папок

null@example.com (Yury) — Mon, 13 Jan 2014 07:01:14 +0000

На всякий случай ещё два варианта:

@echo off
set Directory_for_Cleanup=D:\TEST
for /f "tokens=*" %%i in ('dir /b /ad "%Directory_for_Cleanup%"') do (
 for /f %%j in ('^(type "%~f0"^|more +10^&dir /b /a:d "%Directory_for_Cleanup%"^)^|findstr /i /x %%i^|find /c /i /v ""') do (
  if %%j==1 rd /s /q "%Directory_for_Cleanup%\%%i"
))
echo Cleanup completed.
pause>nul
exit

test5
test6

@echo off
set Directory_for_Cleanup=D:\TEST
for /f "tokens=*" %%i in ('dir /a:d /b "%Directory_for_Cleanup%"') do type "%~f0"|more +7|findstr /i /x "%%i">nul||rd /s /q "%Directory_for_Cleanup%\%%i"
echo Cleanup completed.
pause>nul
exit

test5
test6

Re: CMD/BAT: Удаление определенных папок

null@example.com (aksenov_ivan) — Mon, 13 Jan 2014 06:24:11 +0000

Yury.

Большое вам спасибо. все работает как надо.

Re: CMD/BAT: Удаление определенных папок

null@example.com (Yury) — Fri, 10 Jan 2014 18:26:15 +0000

Ещё один вариант ("экзотический"):

@set Directory_for_Cleanup=D:\TEST

@echo off
set temp_folder=%temp%\%random%
Robocopy "%Directory_for_Cleanup%" "%temp_folder%" /E /MOVE /XD test5 test6 >nul
rd /s /q "%temp_folder%"
echo Cleanup completed.
pause>nul

Re: CMD/BAT: Удаление определенных папок

null@example.com (Yury) — Fri, 10 Jan 2014 17:17:21 +0000

Ниже приведён один из способов (о его существовании говорил и Smitis).

@set Directory_for_Cleanup=D:\TEST
@for /f "usebackq eol=@ tokens=*" %%i in ("%~f0") do @attrib +h "%Directory_for_Cleanup%\%%i"
@for /d %%i in ("%Directory_for_Cleanup%\*") do @rd /s /q "%%~i"
@for /f "usebackq eol=@ tokens=*" %%i in ("%~f0") do @attrib -h "%Directory_for_Cleanup%\%%i"
@echo Cleanup completed.
@pause>nul
@exit

test5
test6

Только будьте крайне осторожны с командой "rd", тестируйте код, заменяя в нём "rd" на "echo".

Re: CMD/BAT: Удаление определенных папок

null@example.com (shiz) — Fri, 10 Jan 2014 16:50:27 +0000

В чём разница?

Re: CMD/BAT: Удаление определенных папок

null@example.com (aksenov_ivan) — Fri, 10 Jan 2014 15:22:42 +0000

как игнорировать файлы я тоже понял, а как игнорировать папки???????

Re: CMD/BAT: Удаление определенных папок

null@example.com (shiz) — Fri, 10 Jan 2014 15:14:58 +0000

CMD/BAT: Как игнорировать файлы при удалении?

CMD/BAT: Удаление определенных папок

null@example.com (aksenov_ivan) — Fri, 10 Jan 2014 11:30:43 +0000

Привет форумчане. Задача такова: На диске D есть расшаренная папка TEST, в ней куча подпапок (test1, test2 и т.д), так вот нужно удалить всё из папки TEST, но не удалять некоторые подпапки и их содержимое (например test5 и test6).

как удалить всё я разобрался, а вот как оставить некоторые подпапки и их содержимое, до меня не доходит.
удаляю так:

for %%i in ("D:\TEST") do (

    pushd %%i && 2>nul rd /s /q .
    popd
)

что и куда надо прописать. заранее спасибо